Como expandir automaticamente todas as pastas ao iniciar o Outlook?

Normalmente, ao expandir ou recolher uma pasta na Navegação do Outlook e depois fechar o programa, a pasta mantém esse estado — expandida ou recolhida — quando reabre o Outlook. Mas e se quiser que todas as pastas sejam automaticamente expandidas sempre que inicia o Outlook? Este artigo apresenta uma solução VBA que faz exatamente isso.

Expandir automaticamente Expandir todas as pastas ao iniciar o Outlook com VBA

---

Expandir automaticamente Expandir todas as pastas ao iniciar o Outlook com VBA

Este guia mostra como utilizar um script VBA para expandir automaticamente todas as pastas na Navegação sempre que o Outlook for iniciado. Siga estes passos para implementar o script VBA:

1. Prima simultaneamente as teclas Alt + F11 para abrir a janela do Microsoft Visual Basic for Applications.
2. Expanda o Projeto 1e Objetos do Microsoft Outlookno painel Projeto, faça duplo clique para abrir a janela ThisOutlookSession, e cole em seguida o código VBA abaixo na mesma.

   

   VBA: Expandir automaticamente Expandir todas as pastas no Outlook

   Public WithEvents GEx As Explorer
   Public GFlag As Boolean
   Private Sub Application_Startup()
     'Update by ExtendOffice 2023/12/08
     Set GEx = Application.ActiveExplorer
     GFlag = False
   End Sub
   
   Private Sub GEx_SelectionChange()
     If GFlag = False Then
       ExpandAllFolders
     End If
     GFlag = True
   End Sub
   
   Public Sub ExpandAllFolders()
     Dim xNameSpace As Outlook.NameSpace
     Dim xFlds As Outlook.Folders
     Dim xCurrFld As Outlook.MAPIFolder
     Dim xFld As Outlook.MAPIFolder
     Dim xExpandDefaultStoreOnly As Boolean
     Dim xModule As NavigationModule
     On Error Resume Next
     xExpandDefaultStoreOnly = False
     Set xNameSpace = Application.Session
     Set xModule = Application.ActiveExplorer.NavigationPane.CurrentModule
     Set xCurrFld = Application.ActiveExplorer.CurrentFolder
     If xExpandDefaultStoreOnly = True Then
       Set xFld = xNameSpace.GetDefaultFolder(olFolderInbox)
       Set xFld = xFld.Parent
       Set xFlds = xFld.Folders
       LoopFolders xFlds, True
     Else
       LoopFolders xNameSpace.Folders, True
       LoopFolders xNameSpace.Folders, False
     End If
     DoEvents
     Set Application.ActiveExplorer.NavigationPane.CurrentModule = xModule
     Set Application.ActiveExplorer.CurrentFolder = xCurrFld
     Set xNameSpace = Nothing
     Set xModule = Nothing
     Set xCurrFld = Nothing
   End Sub
   
   Private Sub LoopFolders(Flds As Outlook.Folders, ByVal All As Boolean)
     Dim xFld As Outlook.MAPIFolder
     On Error Resume Next
     For Each xFld In Flds
       Select Case All
         Case True
           If xFld.DefaultItemType = olMailItem Then
             Set Application.ActiveExplorer.CurrentFolder = xFld
             DoEvents
             If xFld.Folders.Count > 0 Then
               LoopFolders xFld.Folders, All
             End If
           End If
         Case False
           Set Application.ActiveExplorer.CurrentFolder = xFld
           DoEvents
           If xFld.Folders.Count > 0 Then
             LoopFolders xFld.Folders, All
           End If
       End Select
     Next
   End Sub

3. Guarde o código e feche a janela do Microsoft Visual Basic for Applications.

A partir de agora, ao reiniciar o Outlook, todas as pastas serão automaticamente expandidas.

---

Artigos Relacionados