Como aceitar automaticamente a solicitação de reunião de uma pessoa específica no Outlook?

Ao receber convites de reunião no Outlook, você precisa aceitar manualmente a solicitação de reunião e enviar a resposta ao remetente. Existe alguma maneira fácil de aceitá-lo automaticamente de uma pessoa específica no Outlook? O método neste artigo lhe fará um favor.

Aceita automaticamente a solicitação de reunião de uma pessoa específica com o código VBA

Aceita automaticamente a solicitação de reunião de uma pessoa específica com o código VBA

O código VBA abaixo pode ajudá-lo a aceitar automaticamente a solicitação de reunião enviada de uma pessoa específica no Outlook. Faça o seguinte.

1. aperte o outro + F11 chaves para abrir o Microsoft Visual Basic para Aplicações janela.

2. No Microsoft Visual Basic para Aplicações janela, clique duplo Esta sessão do Outlook no painel esquerdo para abrir a janela Código e, em seguida, copie o código VBA abaixo para a janela. Veja a imagem:

Código VBA: aceitar automaticamente a solicitação de reunião de uma pessoa específica no Outlook

Public WithEvents GItems As Outlook.Items
'Updated by ExtendOffice 20180814
Private Sub Application_Startup()
    Set GItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub
Private Sub GItems_ItemAdd(ByVal Item As Object)
Dim xMtRequest As MeetingItem
Dim xAppointmentItem As AppointmentItem
Dim xMtResponse As MeetingItem
If Item.Class = olMeetingRequest Then
    Set xMtRequest = Item
    Set xAppointmentItem = xMtRequest.GetAssociatedAppointment(True)
    If xAppointmentItem.GetOrganizer.Name = "Sender Name" Then
        With xAppointmentItem
            .ReminderMinutesBeforeStart = 45
            .Categories = "Orange Category"
            .Save
        End With
        Set xMtResponse = xAppointmentItem.Respond(olMeetingAccepted)
        xMtResponse.Send
        xMtRequest.Delete
    End If
End If
End Sub

Anote os: No código, substitua o “Nome do remetente”Com o nome de exibição do remetente.

3. Salve o código e pressione o botão outro + Q chaves para fechar o Microsoft Visual Basic para Aplicações janela.

4. Reinicie o Outlook para que este código tenha efeito.

A partir de agora, ao receber solicitações de reunião enviadas pela pessoa que você especificou no código, a reunião será aceita automaticamente e o remetente receberá um e-mail de resposta.

Anote os: A conta de e-mail que recebe a solicitação de reunião deve ser a conta padrão em seu Outlook.

Artigos relacionados:

• Como recusar um convite de reunião, mas ainda deixá-lo em sua agenda no Outlook?
• Como recusar todas as reuniões de ocorrências futuras no Outlook?