Como exportar e imprimir a lista de todas as pastas e subpastas no Outlook?

De um modo geral, pode premir as teclas **Ctrl + 6** para visualizar a lista de todas as pastas na Navegação do Outlook. Contudo, não é possível imprimir diretamente essa lista. Este artigo apresenta dois scripts VBA que permitem exportar e imprimir a lista completa de pastas e respetivas subpastas no Outlook.

• Exporte e imprima a lista de todas as pastas do Outlook e respetivas subpastas no Novo Email
• Exporte e imprima a lista de todas as pastas do Outlook e respetivas subpastas no Bloco de Notas

---

Exporte e imprima a lista de todas as pastas do Outlook e respetivas subpastas no Novo Email

Este método disponibiliza um script VBA que exporta a lista de todas as pastas e respetivas subpastas de uma conta de e-mail especificada diretamente para um Novo Email no Outlook, permitindo-lhe imprimir facilmente a lista de pastas.

1. Prima «Alt» + "F11" para abrir a janela do Microsoft Visual Basic for Applications.

2. Clique em «Inserir» > «Módulo» e cole o seguinte código VBA na nova janela do módulo.

VBA: Exporte a lista de pastas e subpastas numa Novo Email no Outlook

Public gFolders As String

Public Sub GetFolderNames()
Dim oSession As Outlook.NameSpace
Dim oFolder As Outlook.MAPIFolder
Dim oNewMail As Outlook.MailItem

Set oSession = Outlook.Application.GetNamespace("MAPI")
Set oFolder = oSession.PickFolder

If (oFolder Is Nothing) Then Exit Sub

ProcessFolder oFolder

Set oNewMail = Application.CreateItem(olMailItem)
oNewMail.Body = gFolders
oNewMail.Display

gFolders = ""
End Sub

Sub ProcessFolder(CurrentFolder As Outlook.MAPIFolder)
Dim i As Long
Dim oSubFolder As Outlook.MAPIFolder
Dim oFolder As Outlook.MAPIFolder
Dim sFolderPaths As String

For i = CurrentFolder.Folders.Count To 1 Step -1
    Set oFolder = CurrentFolder.Folders(i)
    sFolderPaths = oFolder.FolderPath
    gFolders = gFolders & vbCrLf & sFolderPaths & " " & oFolder.Items.Count
Next

For Each oSubFolder In CurrentFolder.Folders
    If oSubFolder.Name <> "Deleted Items" Then
        ProcessFolder oSubFolder
    End If
Next
End Sub

3. Prima "F5" para executar o código VBA.

4. Na caixa de diálogo «Selecionar Pasta» que surge, selecione a conta de e-mail cuja lista de pastas pretende imprimir e clique em «OK».

5. A lista de pastas da conta selecionada será copiada para um Novo Email, conforme ilustrado abaixo. Clique em «Ficheiro» > «Imprimir» para imprimir essa lista de pastas.

6. Após imprimir, feche o Novo Email sem guardar.

---

Exporte e imprima a lista de todas as pastas do Outlook e respetivas subpastas no Bloco de Notas

Este método fornece um script VBA que exporta a lista de todas as pastas e respetivas subpastas de uma conta de e-mail especificada no Outlook diretamente para o Bloco de Notas, permitindo-lhe imprimir facilmente a lista de pastas.

1. Prima «Alt» + "F11" para abrir a janela do Microsoft Visual Basic for Applications.

2. Clique em «Inserir» > «Módulo» e, em seguida, cole o seguinte código VBA na nova janela do módulo.

VBA: Exporte a lista de todas as pastas e subpastas do Outlook para o Bloco de Notas

Dim gFileName, gCreateTree, gBase

Public Sub ExportFolderTree()
Dim objOutlook
Dim F, Folders
Dim Result

Set objOutlook = CreateObject("Outlook.Application")
Set F = objOutlook.Session.PickFolder

If Not F Is Nothing Then
    Set Folders = F.Folders
    Result = MsgBox("Do you want to create tree?", vbYesNo + vbDefaultButton2 + vbApplicationModal, "Output Folder Tree")
    If Result = 6 Then
        gCreateTree = True
    Else
        gCreateTree = False
    End If

    gFileName = GetDesktopFolder() & "\Outlook-Folders.txt"
    gBase = Len(F.FolderPath) - Len(Replace(F.FolderPath, "\", "")) + 1

    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders Folders

    Set F = Nothing
    Set Folders = Nothing
    Set objOutlook = Nothing
End If
End Sub

Private Function GetDesktopFolder()
Dim objShell
Set objShell = CreateObject("WScript.Shell")
GetDesktopFolder = objShell.SpecialFolders("Desktop")
Set objShell = Nothing
End Function

Private Sub LoopFolders(Folders)
Dim F
For Each F In Folders
    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders F.Folders
Next
End Sub

Private Sub WriteToATextFile(OLKfoldername)
Dim objFSO, objTextFile
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile(gFileName, 8, True)
objTextFile.WriteLine (OLKfoldername)
objTextFile.Close
Set objFSO = Nothing
Set objTextFile = Nothing
End Sub

Private Function CreateFolderTree(OLKfolderpath, OLKfoldername)
If gCreateTree = False Then
    CreateFolderTree = Mid(OLKfolderpath, 3)
Else
    Dim i, x, OLKprefix
    i = Len(OLKfolderpath) - Len(Replace(OLKfolderpath, "\", ""))
    For x = gBase To i
        OLKprefix = OLKprefix & "-"
    Next
    CreateFolderTree = OLKprefix & OLKfoldername
End If
End Function

3. Prima "F5" para executar o VBA. Na caixa de diálogo «Selecionar Pasta» que surge, escolha a conta de e-mail cuja lista de pastas pretende exportar e imprimir e, em seguida, clique em «OK».

4. Aparecerá a caixa de diálogo «Árvore de Pastas de Saída». Clique em «Sim» ou «Não», conforme deseje incluir a indentação em árvore.

Agora, é criado e guardado no seu ambiente de trabalho um Arquivo de Texto com o nome «Outlook-Folders», conforme ilustrado abaixo:

5. Faça duplo clique para abrir o novo ficheiro de texto e, em seguida, selecione «Ficheiro» > «Imprimir» para imprimir a lista exportada das pastas do Outlook.

Artigos Relacionados

Mostrar ou ocultar a vista da lista de pastas no Outlook