Como mover automaticamente diferentes tipos de itens excluídos para pastas distintas no Outlook?

No Outlook, todos os tipos de itens excluídos — como mensagens, tarefas, contactos, entre outros — são movidos automaticamente para a pasta Itens Excluídos. Se pretender organizar esses itens em pastas diferentes com base no respetivo tipo, tal como ilustrado na imagem seguinte, como pode fazê-lo no Outlook?

---

Mover automaticamente diferentes tipos de Itens Excluídos para pastas distintas com código VBA

O seguinte código VBA pode ajudá-lo a mover automaticamente os Itens Excluídos para pastas diferentes. Siga estes passos:

1. Inicie o Outlook e, em seguida, mantenha premidas as teclas ALT + F11 para abrir a janela do Microsoft Visual Basic for Applications.

2. Em seguida, faça duplo clique em ThisOutlookSession no painel Project-Project1 e, depois, copie e cole o código seguinte na janela de código em branco:

Código VBA: Mover automaticamente diferentes tipos de Itens Excluídos para pastas distintas

Public WithEvents GDeletedFolder As Outlook.Folder
Public WithEvents GDeletedItems As Outlook.Items
Private Sub Application_Startup()
  Set GDeletedFolder = Application.Session.GetDefaultFolder(olFolderDeletedItems)
  Set GDeletedItems = GDeletedFolder.Items
End Sub
Private Sub GDeletedItems_ItemAdd(ByVal Item As Object)
'Updateby ExtendOffice
Dim xTargetFolder As Outlook.Folder
On Error Resume Next
Select Case TypeName(Item)
  Case "MailItem", "PostItem", "ReportItem", "MeetingItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Mails")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Mails", olFolderInbox)
    End If
  Case "AppointmentItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Appointments")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Appointments", olFolderCalendar)
    End If
  Case "ContactItem", "DistListItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Contacts")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Contacts", olFolderContacts)
    End If
  Case "TaskItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Tasks")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Tasks", olFolderTasks)
    End If
  Case "JournalItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Journals")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Journals", olFolderJournal)
    End If
  Case "NoteItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Notess")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Notess", olFolderNotes)
    End If
End Select
If xTargetFolder Is Nothing Then Exit Sub
Item.Move xTargetFolder
Set xTargetFolder = Nothing
End Sub

3. Em seguida, guarde este código e reinicie o Outlook para ativar a funcionalidade.

4. A partir de agora, sempre que eliminar um item, este será automaticamente movido para a pasta correspondente ao respetivo tipo, dentro da pasta Itens Excluídos.

5. Para visualizar o resultado, clique no ícone na parte inferior do painel de pastas e, em seguida, clique em Pastas para aceder a «Expandir todas as pastas» no painel. Veja as imagens seguintes: