Como responder normalmente a partir da pasta Itens Enviados do Outlook?

Normalmente, quando clica na funcionalidade Responder na pasta Itens Enviados para enviar outra mensagem adicional às pessoas a quem já enviou, o seu próprio endereço Endereço de Email será apresentado no campo Para, tal como mostrado na seguinte captura de ecrã. Isto poderá ser incómodo, obrigando-o a alterar o endereço cada vez que responde. Como pode fazer com que o Outlook utilize o endereço do destinatário original, em vez do seu?

Responder normalmente na pasta Itens Enviados do Outlook com a funcionalidade Responder a Todos

Responder normalmente na pasta Itens Enviados do Outlook com código VBA

---

Responder normalmente na pasta Itens Enviados do Outlook com a funcionalidade Responder a Todos

No Outlook, a funcionalidade Responder a Todos pode ajudá-lo a resolver este problema. Siga estes passos:

Quando precisar de responder ao e-mail enviado para reenviá-lo mantendo o endereço do destinatário original, clique no botão Responder a Todos, e o endereço do destinatário original aparecerá no campo Para, tal como ilustrado na seguinte captura de ecrã:

---

Responder normalmente na pasta Itens Enviados do Outlook com código VBA

Por vezes, pode esquecer-se de utilizar a funcionalidade Responder a Todos ao responder a uma mensagem enviada. Nesse caso, o código VBA abaixo ajuda-o a responder normalmente na pasta Itens Enviados, recorrendo à funcionalidade Responder. Siga os passos seguintes:

1. Prima as teclas ALT + F11 para abrir a janela Microsoft Visual Basic for Applications.

2. Na janela Microsoft Visual Basic for Applications, faça duplo clique em ThisOutlookSession no painel Project1 (VbaProject.OTM) para abrir o módulo e, em seguida, copie e cole o código seguinte no módulo vazio.

Código VBA: Responder normalmente na pasta Itens Enviados do Outlook:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. Em seguida, guarde o código e reinicie o Outlook para que as alterações entrem em vigor. Agora, ao clicar em Responder para reenviar um e-mail na pasta Itens Enviados, o endereço do destinatário original será apresentado no campo Para, conforme pretendido.