Como localizar e substituir o texto do assunto em mensagens ou tarefas no Outlook?

No Outlook, se houver várias mensagens ou tarefas cujos assuntos precise de substituir pelo texto que especificar, é claro que pode alterá-los um a um — mas será que existe uma forma rápida de concluir esta tarefa de uma só vez no Outlook?

Localizar e Substituir o texto do assunto em várias mensagens utilizando código VBA

Localizar e Substituir o texto do assunto em várias tarefas utilizando código VBA

---

Localizar e Substituir o texto do assunto em várias mensagens utilizando código VBA

Localize um texto específico e substitua-o por outro em vários assuntos de mensagens. O código VBA abaixo pode ajudá-lo — basta seguir os passos seguintes:

1. Selecione as mensagens cujo texto do assunto pretende localizar e substituir e, em seguida, prima simultaneamente as teclas «ALT + F11» para abrir a janela «Microsoft Visual Basic for Applications».

2. Em seguida, clique em «Inserir» > «Módulo», copie e cole o código abaixo no módulo em branco que se abre, conforme ilustrado na captura de ecrã:

Código VBA: Localizar e Substituir o texto do assunto em várias mensagens:

Option Explicit
Sub FindAndReplaceInSubject()
Dim xItem As Object
Dim xNewSubject As String
Dim xMailItem As MailItem
Dim xExplorer As Explorer
Dim i As Integer
On Error Resume Next
Set xExplorer = Outlook.Application.ActiveExplorer
For i = xExplorer.Selection.Count To 1 Step -1
    Set xItem = xExplorer.Selection.Item(i)
    If xItem.Class = olMail Then
        Set xMailItem = xItem
        With xMailItem
            xNewSubject = Replace(.Subject, "kte", "Kutools for Excel")
            .Subject = xNewSubject
            .Save
        End With
    End If
Next
End Sub

Notas: No código acima, `xNewSubject = Replace(.Subject, «kte», "[[PH_8]]")`, «kte» é o Texto Antigo que pretende localizar e «Kutools para Excel» é o Texto Novo pelo qual pretende substituí-lo. Ajuste-os conforme as suas necessidades.

3. Depois, prima a tecla «F5» para executar este código e o texto específico nos assuntos das mensagens será substituído pelo Texto Novo pretendido, conforme ilustrado na captura de ecrã:

---

Localizar e Substituir o texto do assunto em várias tarefas utilizando código VBA

Se precisar de localizar e substituir o texto do assunto nas tarefas, o código VBA seguinte também poderá ajudá-lo.

1. Prima simultaneamente as teclas «ALT + F11» para abrir a janela do Microsoft Visual Basic for Applications.

2. Em seguida, clique em «Inserir» > «Módulo», copie e cole o código abaixo no módulo em branco que se abre, conforme ilustrado na captura de ecrã:

Código VBA: Localizar e Substituir o texto do assunto em todas as tarefas:

Option Explicit
Sub FindReplaceTextsInAllTaskSubjects()
Dim xPane As NavigationPane
Dim xModule As TasksModule
Dim xGroup As NavigationGroup
Dim xNavFolder As NavigationFolder
Dim xTaskItem As Outlook.TaskItem
Dim i, k As Integer
Dim xFindStr, xReplaceStr As String
Dim xTotalCount As Long
On Error Resume Next
xFindStr = InputBox("Type the words to find:", "Kutools for Outlook", xFindStr)
If Len(Trim(xFindStr)) = 0 Then Exit Sub
xReplaceStr = InputBox("Type the words to replace:", "Kutools for Outlook", xReplaceStr)
If Len(Trim(xReplaceStr)) = 0 Then Exit Sub
xTotalCount = 0
Set xPane = Outlook.Application.ActiveExplorer.NavigationPane
Set xModule = xPane.Modules.GetNavigationModule(olModuleTasks)
Set xGroup = xModule.NavigationGroups.Item(1)
For i = xGroup.NavigationFolders.Count To 1 Step -1
    Set xNavFolder = xGroup.NavigationFolders.Item(i)
    For k = xNavFolder.Folder.Items.Count To 1 Step -1
        Set xTaskItem = xNavFolder.Folder.Items(k)
        If InStr(xTaskItem.Subject, xFindStr) > 0 Then
            xTaskItem.Subject = Replace(xTaskItem.Subject, xFindStr, xReplaceStr)
            xTaskItem.Save
            xTotalCount = xTotalCount + 1
        End If
    Next
Next
MsgBox xTotalCount & " task subjects have been changed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub

3. Em seguida, prima a tecla «F5» para executar este código e surgirá uma caixa de diálogo; introduza o texto que pretende localizar nos assuntos das tarefas, conforme ilustrado na captura de ecrã:

4. Clique em «OK» e surgirá outra caixa de diálogo; introduza o novo texto pelo qual pretende substituir, conforme ilustrado na captura de ecrã:

5. Depois, clique em «OK» e surgirá uma caixa de diálogo a indicar quantos assuntos foram alterados, conforme ilustrado na captura de ecrã:

6. Clique em «OK» e o texto antigo nos assuntos das tarefas será substituído pelos novos, conforme ilustrado na captura de ecrã: