Como ocultar o número de fax na lista «Selecionar Nomes» do Outlook?

No Outlook, poderá ter reparado que, na lista «Selecionar Nomes» ou no Catálogo de Endereços, a coluna Endereço de Email inclui não só endereços de e-mail, mas também entradas de fax — o que pode ser incómodo. Neste artigo, mostro-lhe algumas formas de ocultar o número de fax.

Ocultar número de fax em Selecionar Lista de nomes com VBA

---

Ocultar número de fax em Selecionar Lista de nomes com VBA

Se pretender ocultar os números de fax existentes em Selecionar Lista de nomes, proceda da seguinte forma:

1. Prima as teclas Alt + F11 para abrir a janela do Microsoft Visual Basic for Applications.

2. Clique em Inserir > Módulo para inserir um novo módulo em branco e copie e cole o código abaixo no script.

VBA: Ocultar números de fax existentes em Selecionar Nomes

Sub HideFaxNumbers_ExistingContacts()
'UpdatebyExtendoffice2018-5-23
Dim xStores As Outlook.Stores
Dim xStore As Outlook.Store
Dim xRootFolder As Outlook.Folder
Dim xFolder As Folder
On Error Resume Next
Set xStores = Outlook.Application.Session.Stores
For Each xStore In xStores
    Set xRootFolder = xStore.GetRootFolder
    For Each xFolder In xRootFolder.Folders
        Call ProcessFolders(xFolder)
    Next
Next
End Sub
Sub ProcessFolders(ByVal CurrentFolder As Outlook.Folder)
Dim xContactItem As Outlook.ContactItem
Dim xSubFolder As Outlook.Folder
Dim xFax As String
Dim I As Integer
On Error Resume Next
If CurrentFolder.DefaultItemType <> olContactItem Then Exit Sub
xFax = "Fax: "
For I = CurrentFolder.Items.Count To 1 Step -1
    Set xContactItem = CurrentFolder.Items.Item(I)
    With xContactItem
        If (Len(.BusinessFaxNumber) <> 0) And InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
            .BusinessFaxNumber = xFax & .BusinessFaxNumber
        End If
        If (Len(.HomeFaxNumber) <> 0) And InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
            .HomeFaxNumber = xFax & .HomeFaxNumber
        End If
        If (Len(.OtherFaxNumber) <> 0) And InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
            .OtherFaxNumber = xFax & .OtherFaxNumber
        End If
        .Save
    End With
Next I
If CurrentFolder.Folders.Count <> 0 Then
    For I = CurrentFolder.Folders.Count To 1 Step -1
        Set xSubFolder = CurrentFolder.Folders.Item(I)
        Call ProcessFolders(xSubFolder)
    Next I
End If
End Sub

3. Prima a tecla F5 para executar o código; os números de fax já se encontram ocultos.

Se pretender ocultar o número de fax em Contato, proceda da seguinte forma:

1. Prima Alt + F11 para abrir a janela do Microsoft Visual Basic for Applications.

2. Faça duplo clique em ThisOutlookSession em Projeto-1 e copie e cole o código abaixo no script.

VBA: Ocultar número de fax em novos Adicionar contato

Public WithEvents xInspectors As Outlook.Inspectors
Public WithEvents xContactItem As Outlook.ContactItem
Private Sub Application_Startup()
'UpdatebyExtendoffice2018-5-23
    Set xInspectors = Outlook.Application.Inspectors
End Sub
Private Sub xInspectors_NewInspector(ByVal Inspector As Inspector)
If TypeName(Inspector.CurrentItem) = "ContactItem" Then
    Set xContactItem = Inspector.CurrentItem
End If
End Sub
Private Sub xContactItem_PropertyChange(ByVal Name As String)
Dim xArr() As Variant
Dim xFax As String
On Error Resume Next
xArr = Array("BusinessFaxNumber", "HomeFaxNumber", "OtherFaxNumber")
xFax = "Fax: "
With xContactItem
    Select Case Name
        Case xArr(0)
            If InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
                .BusinessFaxNumber = xFax & .BusinessFaxNumber
            End If
        Case xArr(1)
            If InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
                .HomeFaxNumber = xFax & .HomeFaxNumber
            End If
        Case xArr(2)
            If InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
                .OtherFaxNumber = xFax & .OtherFaxNumber
            End If
    End Select
End With
End Sub

3. Guarde o código e reinicie o Outlook para que as alterações tenham efeito.

A partir de agora, todos os números de fax dos novos contactos criados serão ocultos na janela Selecionar Nomes: Contactos.