Como gerar ou listar todas as permutações possíveis no Excel?

Por exemplo, tenho três caracteres XYZ e agora quero listar todas as permutações possíveis com base nesses três caracteres para obter seis resultados diferentes, como este: XYZ, XZY, YXZ, YZX, ZXY e ZYX. No Excel, como você poderia gerar ou listar rapidamente todas as permutações com base em um número diferente de caracteres?

Gerar ou listar todas as permutações possíveis com base em caracteres usando código VBA

Gerar ou listar todas as permutações possíveis com base em caracteres usando código VBA

O seguinte código VBA pode ajudá-lo a listar todas as permutações com base no número específico de letras que você possui; por favor, faça o seguinte:

1. Pressione e segure as teclas ALT + F11 para abrir a janela do Microsoft Visual Basic for Applications.

2. Clique em Inserir > Módulo e cole o seguinte código na Janela do Módulo.

Código VBA: Liste todas as permutações possíveis no Excel

Sub GetString()
'Updateby Extendoffice
    Dim xStr As String
    Dim FRow As Long
    Dim xScreen As Boolean
    xScreen = Application.ScreenUpdating
    Application.ScreenUpdating = False
    xStr = Application.InputBox("Enter text to permute:", "Kutools for Excel", , , , , , 2)
    If Len(xStr) < 2 Then Exit Sub
    If Len(xStr) >= 8 Then
        MsgBox "Too many permutations!", vbInformation, "Kutools for Excel"
        Exit Sub
    Else
        ActiveSheet.Columns(1).Clear
        FRow = 1
        Call GetPermutation("", xStr, FRow)
    End If
    Application.ScreenUpdating = xScreen
End Sub
Sub GetPermutation(Str1 As String, Str2 As String, ByRef xRow As Long)
    Dim i As Integer, xLen As Integer
    xLen = Len(Str2)
    If xLen < 2 Then
        Range("A" & xRow) = Str1 & Str2
        xRow = xRow + 1
    Else
        For i = 1 To xLen
            Call GetPermutation(Str1 + Mid(Str2, i, 1), Left(Str2, i - 1) + Right(Str2, xLen - i), xRow)
        Next
    End If
End Sub

3. Em seguida, pressione a tecla F5 para executar este código, e uma caixa de aviso será exibida para lembrá-lo de inserir os caracteres que deseja listar todas as permutações; veja a captura de tela:

4. Após inserir os caracteres e clicar no botão OK, todas as permutações possíveis serão exibidas na coluna A da planilha ativa. Veja a captura de tela:

Observação: Se o comprimento dos caracteres inseridos for igual ou maior que 8 caracteres, esse código não funcionará porque há muitas permutações.