Divida um documento do Word em múltiplos ficheiros por Cabeçalho 1 (guia passo a passo)

Ao trabalhar com documentos longos do Word — como relatórios, manuais escolares, manuais técnicos ou documentos de projeto — poderá precisar de dividir o ficheiro em partes mais pequenas, por exemplo, um capítulo por ficheiro. Se o seu documento já utilizar o estilo Cabeçalho 1 para os títulos principais das secções, essa divisão torna-se muito mais simples. Eis um guia abrangente sobre como fazê-lo de forma eficiente.

• Prepare o seu documento do Word
• Método 1: Dividir um documento do Word por Cabeçalho 1 com a funcionalidade Estrutura de Tópicos
• Método 2: Dividir um documento do Word por Cabeçalho 1 com código VBA
• Método 3: Dividir um documento do Word por Cabeçalho 1 com Kutools para Word
• Conclusão

Prepare o seu documento do Word

Antes de aplicar qualquer método, certifique-se de que o seu documento está devidamente estruturado — o Word só reconhece os pontos de divisão se o estilo Cabeçalho 1 for aplicado corretamente.

Aplicar estilos:

Aplique estilos de cabeçalho de forma consistente: os cabeçalhos de Nível 1 devem utilizar o estilo Cabeçalho 1, os de Nível 2 o estilo Cabeçalho 2 e assim sucessivamente.

Selecione o seu título → aceda ao separador Base e clique em Cabeçalho 1 na galeria de Estilos.

Faça cópia de segurança do seu ficheiro:

Guarde sempre uma cópia do seu documento original antes de o dividir, pois alguns métodos — como a vista Estrutura de Tópicos — podem ser difíceis de reverter.

Método 1: Divida um documento do Word por Cabeçalho 1 com a funcionalidade Estrutura de tópicos

Na verdade, a vista Estrutura de Tópicos integrada no Word torna esta tarefa incrivelmente fácil: deteta automaticamente as secções com estilo Cabeçalho 1, permitindo-lhe organizar a estrutura do documento e exportar cada capítulo como um ficheiro separado — sem extras, sem passos complicados.

1. Abra o documento do Word, aceda ao separador Vere clique em Estrutura de tópicos, veja a captura de ecrã:
   
2. No separador Estrutura de tópicos que aparece, defina a lista suspensa Mostrar nível como Nível 1. Isto contrai tudo, exceto os seus títulos de Cabeçalho 1.
   
3. Em seguida, prima Ctrl + A para selecionar todo o texto. Depois, clique em Mostrar documento no grupo Documento mestre.
   
4. Continue a clicar no botão Criar. O Word irá agora envolver cada secção numa caixa fina.
   
5. Aceda a Ficheiro > Guardar como. Escolha uma nova pasta. O Word irá gerar automaticamente ficheiros separados .docx para cada Cabeçalho 1, utilizando o texto do cabeçalho como nome do ficheiro. Será também criado um documento de índice separado, com hiperligações para todos os ficheiros divididos, permitindo-lhe abrir qualquer documento com apenas um clique.
   

Método 2: Divida um documento do Word por Cabeçalho 1 com código VBA

Se tiver um documento muito longo, o método da Estrutura de Tópicos pode, por vezes, causar problemas de formatação. Utilizar um script VBA é uma solução muito mais limpa e rápida.

1. Prima Alt + F11 para abrir a janela do Visual Basic para Aplicações.
2. Clique em Inserir>Módulo. Copie e cole o seguinte código no módulo em branco:
   

   Sub SplitDocByHeading1()
       Dim StrTmplt As String
       Dim StrPath As String
       Dim StrFlNm As String
       Dim Rng As Range
       Dim i As Long
       Dim Doc As Document
       Dim fDialog As FileDialog
       Const StrNoChr As String = """*./\:?|"
       Application.ScreenUpdating = False
       Set fDialog = Application.FileDialog(msoFileDialogFolderPicker)
       With fDialog
           .Title = "Select a folder to save the split documents"
           .AllowMultiSelect = False
           If .Show <> -1 Then
               MsgBox "Operation cancelled.", vbInformation, "Split by Heading 1"
               Application.ScreenUpdating = True
               Exit Sub
           End If
           StrPath = .SelectedItems(1)
       End With
       If Right(StrPath, 1) <> "\" Then
           StrPath = StrPath & "\"
       End If
       With ActiveDocument
           StrTmplt = .AttachedTemplate.FullName
           With .Range
               With .Find
                   .ClearFormatting
                   .Replacement.ClearFormatting
                   .Text = ""
                   .Replacement.Text = ""
                   .Style = wdStyleHeading1
                   .Format = True
                   .Forward = True
                   .Wrap = wdFindStop
                   .Execute
               End With
               Do While .Find.Found
                   Set Rng = .Duplicate
                   StrFlNm = Split(Rng.Paragraphs(1).Range.Text, vbCr)(0)
                   For i = 1 To Len(StrNoChr)
                       StrFlNm = Replace(StrFlNm, Mid(StrNoChr, i, 1), "_")
                   Next i
                   StrFlNm = StrFlNm & ".docx"
                   Set Rng = Rng.GoTo(What:=wdGoToBookmark, Name:="\HeadingLevel")
                   Set Doc = Documents.Add(Template:=StrTmplt, Visible:=False)
                   With Doc
                       .Range.FormattedText = Rng.FormattedText
                       .SaveAs2 FileName:=StrPath & StrFlNm, _
                                FileFormat:=wdFormatXMLDocument, _
                                AddToRecentFiles:=False
                       .Close SaveChanges:=False
                   End With
                   .Collapse wdCollapseEnd
                   .Find.Execute
               Loop
           End With
       End With
       Set Doc = Nothing
       Set Rng = Nothing
       Application.ScreenUpdating = True
       MsgBox "Split completed successfully.", vbInformation, "Split by Heading 1"
   End Sub
   

3. Prima F5 ou clique em Executar para executar o código. Irá aparecer uma janela a solicitar que selecione uma pasta para guardar os ficheiros divididos. Veja a captura de ecrã:
   
4. Clique em OK e o Word criará imediatamente um ficheiro .docx para cada secção de Cabeçalho 1. Abra a pasta para ver o resultado.
   

Método 3: Divida um documento do Word por Cabeçalho 1 com o Kutools para Word

Embora as ferramentas integradas do Word e o VBA permitam dividir documentos, exigem múltiplos passos, conhecimentos técnicos e podem até comprometer a formatação. O Kutools para Word oferece uma solução mais limpa e eficiente: com a funcionalidade **Dividir Documento**, basta um único clique para separar um ficheiro por Cabeçalho 1, Quebra de Página, Quebra de Secção, página ou outros critérios — sem programação, sem trabalho manual e sem perda de formatação. O Kutools preserva estilos, esquema, imagens, cabeçalhos e rodapés, tornando-se a ferramenta ideal para quem lida com documentos extensos.

Após transferir e instalar o Kutools para Word, siga os passos seguintes:

1. Aceda a KUTOOLS PLUS > Dividir.
   
2. Na caixa de diálogo Dividir Documento, especifique as seguintes opções:

   2,1 Escolha Cabeçalho 1 no menu pendente Dividir por. (Também pode selecionar outras regras de divisão, como Quebra de Página, Quebra de Seção, página, A cada n páginas, entre outras.)

   2,2 Especifique uma pasta para guardar os novos ficheiros resultantes da divisão.

   2,3 Clique no botão OK.

   Dica: Pode também adicionar um prefixo ao título de cada ficheiro dividido, bastando introduzir o texto pretendido na caixa Prefixo do Documento.

   
   

Resultado:
O Kutools gera instantaneamente múltiplos ficheiros do Word com base na sua estrutura de Cabeçalho 1, preservando integralmente todos os cabeçalhos e rodapés.

Conclusão

Artigos relacionados: