Divida as dimensões em comprimento, altura e largura individuais
Este artigo explica como dividir as dimensões em uma célula em três partes (dimensões individuais que incluem comprimento, altura e largura).
Como dividir as dimensões em três partes?
Para dividir as dimensões em comprimento, altura e largura individuais, você precisa aplicar três fórmulas diferentes separadamente.
Fórmula genérica de extração da primeira dimensão
=LEFT(text,FIND("char",text)-1)
Fórmula genérica de extração da segunda dimensão
=MID(text,FIND("char",text)+1,FIND("@",SUBSTITUTE(text,"char","@",2))-(FIND("char",text)+1))
Fórmula genérica de extração da terceira dimensão
=RIGHT(text,LEN(text)-FIND("@",SUBSTITUTE(text,"char","@",2)))
Argumentos das fórmulas acima
Texto: A string da qual você deseja extrair o número determinado de caracteres. Pode ser:
- 1. O texto colocado entre aspas;
- 2. Ou uma referência a uma célula que contém o texto.
Caracteres: O personagem no qual você dividirá as dimensões.
Como usar essas fórmulas?
Em primeiro lugar, precisamos obter a primeira dimensão.
1. Selecione uma célula em branco para gerar a primeira dimensão.
2. Insira a fórmula abaixo e pressione o botão Entrar chave. Selecione a célula de resultado e arraste a alça de preenchimento para aplicar a fórmula a outras células conforme necessário.
=LEFT(B5,FIND("x",B5)-1)
Então, vamos dividir a segunda dimensão da seguinte maneira.
1. Selecione uma célula em branco para gerar a segunda dimensão.
2. Insira a fórmula abaixo e pressione o botão Entrar chave. Selecione a célula de resultado e arraste a alça de preenchimento para aplicar a fórmula a outras células conforme necessário.
=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))
Finalmente, pegue a última dimensão
1. Selecione uma célula em branco para produzir a última dimensão.
2. Insira a fórmula abaixo e pressione o botão Entrar chave. Selecione a célula de resultado e arraste a alça de preenchimento para aplicar a fórmula a outras células conforme necessário.
=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))
Como essas fórmulas funcionam?
=LEFT(B5,FIND("x",B5)-1)
1. FIND("x",B5)-1: A função FIND obtém a posição do primeiro "x" em B5. Para obter a primeira dimensão sem o primeiro "x", você precisa subtrair 1. Então, o resultado é 4-1 = 3.
2. LEFT(B5,3): A função LEFT extrai 3 caracteres começando do lado esquerdo de B5 e retorna o resultado como 100.
=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))
1. FIND("x",B5)+1: A função FIND localiza o primeiro "x" de B5. Como você precisa obter a segunda dimensão após o primeiro "x", aqui é necessário adicionar 1. Então, o resultado é 4 + 1 = 5.
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):
- SUBSTITUTE(B5,"x","@",2): A função SUBSTITUTE substitui o segundo "x" em B5 por "@" e retorna o resultado como 100x50 @ 300;
- FIND("@",100x50@300): A função FIND obtém a posição do caractere "@" no texto 100x50 @ 300 e retorna o resultado como 7.
3. (FIND("x",B5)+1): Como mencionado na etapa 1 acima, aqui a função FIND localiza o primeiro "x" de B5 e adiciona 1 para retornar o resultado como 5.
4. MID(B5,5,7-(5)): A função MID extrai dois caracteres (7-5 = 2) começando no quinto caractere do texto em B5. E retorne o resultado final como 50.
=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))
1. LEN(B5): A função LEN calcula o comprimento total da string em B5 e retorna o resultado como 10;
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):
- SUBSTITUTE(B5,"x","@",2): A função SUBSTITUTE substitui o segundo "x" em B5 por "@" e retorna o resultado como 100x50 @ 300;
- FIND("@",100x50@300): A função FIND aqui localiza o "@" no texto 100x50 @ 300 e retorna o resultado como 7.
3. LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)): (10-7) O comprimento total da sequência de texto na célula B5 subtrai os primeiros 7 caracteres e retorna o resultado como 3.
4. RIGHT(B5,3): E então a função RIGHT extrai 3 caracteres começando do lado direito de B5 e retorna a terceira dimensão como 300.
Funções relacionadas
Função Excel LEFT
A função LEFT extrai o número fornecido de caracteres do lado esquerdo de uma string fornecida.
Função Excel MID
A função MID é usada para encontrar e retornar um número específico de caracteres do meio de uma determinada sequência de texto.
Função Excel RIGHT
A função RIGHT extrai um número específico de caracteres do lado direito da string de texto.
Função FIND do Excel
A função FIND é usada para encontrar uma string dentro de outra string e retorna a posição inicial da string dentro de outra.
Função LEN do Excel
A função LEN retorna o número de caracteres em uma string de texto.
Função SUBSTITUTE Excel
A função SUBSTITUTE do Microsoft Excel substitui o texto ou caracteres em uma seqüência de caracteres por outro texto ou caracteres.
Fórmulas Relacionadas
Divida as dimensões em duas partes no Excel
Este artigo explica como usar a fórmula para dividir as dimensões em uma célula em duas partes sem unidades (comprimento e largura individuais).
Separe os números das unidades de medida
Este artigo explica como usar a fórmula para separar números de unidades de medida.
As melhores ferramentas de produtividade para escritório
Kutools para Excel - ajuda você a se destacar na multidão
Kutools para Excel possui mais de 300 recursos, Garantindo que o que você precisa está a apenas um clique de distância...
Guia Office - Habilite leitura e edição com guias no Microsoft Office (inclui Excel)
- Um segundo para alternar entre dezenas de documentos abertos!
- Reduza centenas de cliques do mouse para você todos os dias, diga adeus à mão do mouse.
- Aumenta sua produtividade em 50% ao visualizar e editar vários documentos.
- Traz guias eficientes para o Office (inclui Excel), assim como Chrome, Edge e Firefox.