sobressair CHOOSE função

Descrição

Sintaxe e Argumentos

Uso e exemplos

• Ex1 - Uso básico: usando CHOOSE função sozinha para escolher o valor do argumento da lista
• Ex2 - Retorna resultados diferentes com base em várias condições
• Ex3 - Retorna diferentes resultados calculados com base nas condições
• Ex4 - Escolha aleatório da lista
• Ex5 - Combine CHOOSE e VLOOKUP funções para retornar o valor na coluna da esquerda
• Ex6 - Retorna o dia da semana ou mês com base em determinada data
• Ex7 - Retornar para o próximo dia de trabalho / fim de semana com base em hoje

---

Descrição

A CHOOSE função retorna um valor da lista de argumentos de valor com base no número de índice fornecido. Por exemplo, CHOOSE(3,”Apple”,”Peach”,”Orange”) retorna Laranja, o número do índice é 3 e Laranja é o terceiro valor após o número do índice na função.

sintaxe e argumentos

Sintaxe da fórmula

CHOOSE(index_num, value1, [value2], …)

Argumentos

Index_num: Requeridos. Um valor numérico entre 1-254 a indireto, cujo valor de argumento será selecionado. se index_num estiver fora da escala entre 1-254, CHOOSE retorna o #VALUE! valor de erro. Se index_num for um valor decimal, ele será arredondado para um número inteiro antes da fórmula ser usada. Value1: Requeridos. O primeiro valor da fórmula que pode ser escolhido. Value2: Opcional. O segundo e até o 254º valor para escolher.

Value1, value2… Podem ser números, textos, fórmulas, referências de células ou nome definido.

Valor de retorno

A CHOOSE função retorna um valor de uma lista com base na posição fornecida.

Uso e exemplos

Nesta parte, listo alguns exemplos simples, mas representativos, para explicar o uso do CHOOSE função.

Ex1 - Uso básico: usando CHOOSE função sozinha para escolher o valor do argumento da lista

Fórmula 1:

=CHOOSE(3,"a","b","c","d")

Retorno: c, que é o terceiro argumento após o index_num de 3 no CHOOSE função.

Observação: use aspas duplas ao redor do valor se for texto.

Fórmula 2:

=CHOOSE(2,A1,A2,A3,A4)

Retorno: Kate, o valor de A2. Uma vez que o index_num é 2, e A2 é o segundo valor no CHOOSE função.

Fórmula 3:

=CHOOSE(4,8,9,7,6)

Retorno: 6, o quarto argumento da lista na função.

---

Ex2 - Retorna resultados diferentes com base em várias condições

Suponha que você tenha uma lista de desvios para cada produto que precisa ser rotulado com base nas condições, conforme a captura de tela abaixo.

Normalmente, você pode usar a função IF para manipular, mas aqui apresento como usar o CHOOSE função para resolver este problema facilmente

Fórmula:

=CHOOSE((B7>0)+(B7>1)+(B7>5),"Top","Middle","Bottom")

Explicar:

(B7>0)+(B7>1)+(B7>5): o index_num, B7 é 2, que é maior que 0 e 1, mas menor que 5, então obtemos o resultado intermediário:

=CHOOSE(True+Ture+False,"Top","Middle","Bottom")

Como sabemos, True = 1, False = 0, então a fórmula pode ser vista como:

=CHOOSE(1+1+0,"Top","Middle","Bottom")

então

=CHOOSE(2,"Top","Middle","Bottom")

Resultado: meio

---

Ex3 - Retorna diferentes resultados calculados com base nas condições

Supondo que você precise calcular os descontos para cada produto com base na quantidade e no preço, conforme a captura de tela abaixo:

Fórmula:

=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

Explicar:

(B8>0)+(B8>100)+(B8>200)+(B8>300): index_number, B8 é 102, que é maior que 100, mas menor que 201, portanto, nesta parte, ele retorna o resultado mostrado como:

=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

então

=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5: os valores dentre os quais escolher, o desconto é igual ao preço * valor * porcentagem do desconto, já que aqui index_num é 2, ele escolhe B8 * C8 * 0.2

Retorna: 102 * 2 * 0.2 = 40.8

---

Ex4 - Escolha aleatório da lista

No Excel, às vezes, você pode precisar escolher aleatoriamente um valor de uma determinada lista, o CHOOSE função pode resolver este trabalho.

Escolha aleatoriamente um valor de uma lista:

Fórmula:

=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)

Explicar:

RANDBETWEEN(1,5): index_num, obter aleatoriamente um número entre 1 a 5

$D$2,$D$3,$D$4,$D$5,$D$6: a lista de valores para escolher

---

Ex5 - Combine CHOOSE e VLOOKUP funções para retornar o valor na coluna da esquerda

Geralmente, usamos a função VLOOKUP =VLOOKUP (value, table, col_index, [range_lookup]) para retornar um valor com base em um determinado valor de um intervalo de tabela. Mas com o VLOOKUP função, ele retornará um valor de erro enquanto a coluna de retorno está à esquerda da coluna de pesquisa, conforme mostrado abaixo:

Neste caso, você pode combinar o CHOOSE função com função VLOOKUP para resolver o problema.

Fórmula:

=VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)

Explicar:

CHOOSE({1,2},B1:B7,A1:A7): como argumento intervalo_de_tabela na função VLOOKUP. {1,2} significa exibir 1 ou 2 como argumento index_num com base no argumento col_num na função VLOOKUP. Aqui, o col_num na função VLOOKUP é 2, então o CHOOSE exibição de função como CHOOSE(2, B1:B7,A1:A7), significa escolher o valor de A1: A7.

---

Ex6 - Retorna o dia da semana ou mês com base em determinada data

Com o CHOOSE , você também pode retornar o dia da semana e o mês relativos com base em uma determinada data.

Fórmula 1: voltar dia da semana por uma data

=CHOOSE(WEEKDAY(),"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")

Explicar:

WEEKDAY(): o argumento index_num, para obter o número do dia da semana da data fornecida, por exemplo, WEEKDAY (A5) retorna 6, então o argumento index_num é 6.

"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday": argumentos da lista de valores, comece com “Domingo” porque o número do dia da semana “1” indica “Domingo”.

Fórmula 2: retornar mês por uma data

=CHOOSE(MONTH(),"Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Explicar:

MONTH(): argumento index_num, que obtém o número do mês a partir da data fornecida, por exemplo, MONTH (A5) retorna 3.

---

Ex7 - Retornar para o próximo dia de trabalho / fim de semana com base em hoje

No trabalho diário, você pode desejar calcular o próximo dia útil ou fim de semana com base no dia de hoje. Aqui o CHOOSE função também pode lhe fazer um favor.

Por exemplo, hoje é 12/20/2018, quinta-feira, agora você precisa obter o próximo dia útil e final de semana.

Fórmula 1: pegue a data de hoje

=TODAY()

Resultado: 12/20/2018

Fórmula 2: pegue o número do dia da semana de hoje

=WEEKDAY(TODAY())

Resultado: 5 (enquanto hoje é 12/20/2018)

A lista de números dos dias da semana conforme a captura de tela abaixo:

Fórmula 3: pegue o próximo dia de trabalho

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Explicar:

Today(): retornar a data atual

WEEKDAY(TODAY()): argumento index_num no CHOOSE função, obtenha o número do dia da semana de hoje, por exemplo, domingo é 1, segunda-feira é 2 ...

1,1,1,1,1,3,2: argumento da lista de valores no CHOOSE função. Por exemplo, se o dia da semana (hoje ()) retornar 1 (domingo), ele escolhe 1 da lista de valores, então toda a fórmula muda para = Hoje () + 1, o que significa adicionar 1 dia para retornar na próxima segunda-feira. Se o dia da semana (hoje ()) retornar 6 (sexta-feira), ele escolhe 3 na lista de valores, pois sexta-feira está a 3 dias da próxima segunda-feira.

Resultado (enquanto hoje é 12/20/2018):

=12/20/2018+CHOOSE(5,1,1,1,1,1,3,2)

= 12/20/2018 + 1

= 12/21/2018

Fórmula 4: pegue o próximo dia de fim de semana

=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1)

Explicar:

6,5,4,3,2,1,1: argumento da lista de valores no CHOOSE função. Por exemplo, se o dia da semana (hoje ()) retornar 1 (domingo), ele escolherá 6 na lista de valores, então toda a fórmula mudará para = Hoje () + 6, o que significa adicionar 6 dias e retornar no próximo sábado.

Resultado:

=12/20/2018+CHOOSE(5,6,5,4,3,2,1,1)

= 12/20/2018 + 2

= 12/22/2018

---

Arquivo de exemplo