KutoolsforOffice — Uma solução, cinco ferramentas poderosas.Fazer mais com menos esforço.

Somar valores por número da semana ou dia da semana no Excel

AutorSiluvia Data de Modificação

Este tutorial apresenta, passo a passo, fórmulas que o ajudam a somar valores num determinado intervalo com base no número da semana ou no dia da semana especificado no Excel.

Como somar valores por Número da semana no Excel?
Como somar valores por dia da semana no Excel?

Como somar valores por número de semana no Excel?

Conforme ilustrado na imagem abaixo, disponibilizamos duas fórmulas para somar os valores da coluna Montante com base nas datas em que determinado número da semana ocorre.

doc-sum-by-week-number-weekday-1

Fórmulas genéricas

=SUMIFS( value_range, helper_column_range, week_number)

=SUMPRODUCT(--(WEEKNUM(date_range+0,1)=week_number),value_range)

Argumentos

Intervalo_valores: O intervalo de valores que pretende somar com base no Número da semana;
Intervalo_coluna_auxiliar: O intervalo de Número da semana extraídos da data;
Número_semana: O Número da semana utilizado como critério para somar valores.

Como utilizar esta fórmula?

Utilização da fórmula SOMASES e de uma coluna auxiliar

Para utilizar a fórmula SOMASES, primeiro tem de aplicar a função WEEKNUM para criar uma coluna auxiliar que calcule o número da semana correspondente às datas na coluna Data.

=WEEKNUM (serial_num, [return_type])

A função WEEKNUM devolve o número da semana correspondente à data indicada num determinado ano.

1. Neste caso, seleciono uma célula (F5) junto ao primeiro valor na coluna Montante.

2. Introduza a fórmula abaixo na mesma célula e prima a tecla Enter para obter o número da semana da primeira data. Selecione a célula com o resultado e arraste a alça de preenchimento automático para baixo para obter os restantes números da semana. Veja a imagem:

=WEEKNUM(C5)

doc-sum-by-week-number-weekday-2

3. Selecione uma célula para apresentar o montante total, introduza a fórmula abaixo e prima a tecla Enter. Em seguida, selecione a célula com o resultado e arraste a sua Alça de Preenchimento Automático para baixo para obter os restantes resultados.

=SUMIFS($E$5:$E$14, $F$5:$F$14, H6)

doc-sum-by-week-number-weekday-3

Utilização da fórmula SOMARPRODUTO

Não precisa de criar uma coluna auxiliar ao usar a fórmula SOMARPRODUTO para resolver este problema.

1. Selecione uma célula vazia, introduza a fórmula abaixo na mesma e prima a tecla Enter.

=SUMPRODUCT(--(WEEKNUM($C$5:$C$14+0,1)=G6),$E$5:$E$14)

2. Selecione a célula com o resultado e arraste-a Alça de Preenchimento Automático para baixo para obter os restantes resultados conforme as suas necessidades.

doc-sum-by-week-number-weekday-4

Explicação da fórmula

=SUMIFS($E$5:$E$14, $F$5:$F$14, H6)

Após calcular o Número da semana com a função WEEKNUM, a função SOMASES soma os valores no intervalo E5:E14 se os Número da semana na coluna auxiliar F5:F14 corresponderem à semana indicada em H6.

=SUMPRODUCT(--(WEEKNUM($C$5:$C$14+0,1)=G6),$E$5:$E$14)

WEEKNUM($C$5:$C$14+0,1): A função WEEKNUM calcula cada Número da semana das datas no intervalo C5:C14 e devolve uma matriz como esta: {1;1;5;6;6;9;11;11;13;14};
{1;1;5;6;6;9;11;11;13;14}=G6: Aqui compara-se cada Número da semana da matriz com o Número da semana indicado em G6 e obtém-se uma nova matriz: {VERDADEIRO;VERDADEIRO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO};
--{VERDADEIRO;VERDADEIRO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO}: Estes dois sinais menos convertem os valores «VERDADEIRO» e «FALSO» em 1 e 0. Aqui obterá uma nova matriz como {1;1;0;0;0;0;0;0;0;0};
{1;1;0;0;0;0;0;0;0;0},{1428;2010;2288;1831;2069;1728;1325;1469;1023;1100}: Cada par de elementos nas matrizes é multiplicado entre si e devolve {1428;2010;0;0;0;0;0;0;0;0};
SUMPRODUCT({1428;2010;0;0;0;0;0;0;0;0}): A função SOMARPRODUTO soma todos os números da matriz e devolve o resultado final 1428+2010=3438.

Como somar valores por dia da semana no Excel?

Conforme ilustrado na imagem abaixo, para somar os valores da coluna Montante correspondentes a um determinado dia da semana no Excel, utilize a função SOMARPRODUTO em conjunto com a função DIA.SEMANA.

Neste caso, dado que precisamos de somar o montante total para cada dia da semana, antes de aplicar a fórmula, criamos uma coluna auxiliar com os números 1 a 7 para indicar separadamente segunda-feira a domingo.

doc-sum-by-week-number-weekday-6

Fórmula genérica

=SUMPRODUCT((WEEKDAY(date_range,2)=weekday_number)*value_range)

Argumentos

Intervalo_datas: O Intervalo de Datas onde pretende avaliar os dias da semana indicados;
Intervalo_valores: O intervalo de valores que pretende somar com base no dia da semana;
2: O número 2 representa os números 1 (segunda-feira) a 7 (domingo);
Número_dia_semana: O número do dia da semana utilizado como critério para somar valores. Pode ser Uma referência de célula ou um número de 1 a 7.

Como utilizar esta fórmula?

1. Selecione uma célula adjacente à que contém o número 1 — neste caso, escolhi a I6.

2. Copie ou introduza a fórmula abaixo na mesma célula e prima a tecla Enter. Selecione a célula com o resultado e, em seguida, arraste a sua alça de preenchimento automático para baixo para obter os resultados dos restantes dias da semana.

=SUMPRODUCT((WEEKDAY($C$5:$C$14,2)=H6)*$E$5:$E$14)

doc-sum-by-week-number-weekday-7

Nota: Se precisar apenas de somar valores com base num determinado dia da semana, como sexta-feira, pode introduzir diretamente o número 5 na fórmula da seguinte forma.

=SUMPRODUCT((WEEKDAY($C$5:$C$14,2)=5)*$E$5:$E$14)

Explicação da fórmula

=SUMPRODUCT((WEEKDAY($C$5:$C$14,2)=H6)*$E$5:$E$14)

WEEKDAY($C$5:$C$14,2): A função DIA.SEMANA devolve números inteiros de 1 a 7 para representar o Semana de segunda-feira a domingo no intervalo C5:C14: {5;7;1;3;6;7;1;5;5;6};
{5;7;1;3;6;7;1;5;5;6}=H6: Aqui compara-se cada Semana da matriz com o número do dia da semana indicado em H6 e obtém-se uma nova matriz: {FALSO;FALSO;VERDADEIRO;FALSO;FALSO;FALSO;VERDADEIRO;FALSO;FALSO;FALSO};
{FALSO;FALSO;VERDADEIRO;FALSO;FALSO;FALSO;VERDADEIRO;FALSO;FALSO;FALSO}*$E$5:$E$14: Aqui os valores VERDADEIRO e FALSO são convertidos em 1 e 0 e, em seguida, multiplicados pelos valores em E5:E14 para devolver a matriz: {0;0;2288;0;0;0;1325;0;0;0};
SOMARPRODUTO{0;0;2288;0;0;0;1325;0;0;0}: A função SOMARPRODUTO soma todos os números da matriz e devolve o resultado final 2288+1325=3613.

Funções relacionadas

Função WEEKNUM do Excel
A função WEEKNUM do Excel devolve o número da semana correspondente à data indicada num determinado ano, começando a contagem das semanas a 1 de janeiro.

Função SOMARPRODUTO do Excel
A função SOMARPRODUTO do Excel permite multiplicar duas ou mais colunas ou matrizes e, de seguida, somar os produtos obtidos.

Função DIA.SEMANA do Excel
A função DIA.SEMANA do Excel devolve um número inteiro de 1 a 7 para representar o dia da semana de uma determinada data no Excel.

Fórmulas relacionadas

Some valores por mês (com ou sem ano)
Este tutorial demonstra, passo a passo, duas fórmulas para somar valores num determinado mês e ano — ou apenas num determinado mês, ignorando o ano — no Excel.

Somar valores pela semana de uma determinada data
Este tutorial explica como somar valores pela semana em que uma determinada data ocorre

Somar cada n linhas ou colunas num intervalo
Este tutorial apresenta duas fórmulas, com base nas funções SOMA e DESLOC, para somar cada n linhas ou colunas num intervalo limitado no Excel.

Somar cada enésima linha ou coluna num intervalo
Este tutorial mostra-lhe como criar uma fórmula com base nas funções SOMARPRODUTO, MOD e COL para somar cada enésima linha ou coluna num intervalo no Excel.

As Melhores Ferramentas de Produtividade para o Office

Kutools for Excel – Ajuda-o a destacar-se da multidão

🤖KUTOOLS AI Assistente: Revolucione o Análise de Dados com base em:Execução Inteligente   |  Gerar Código|  Criar fórmulas personalizadas  |  Analisar Dados e Gerar Gráficos|  Invocar Funções Aprimoradas…
Funcionalidades Populares:Localizar, Destacar ou Marcar Duplicatas  |  Excluir linhas em branco  |  Combinar Colunas ou Células sem Perder Dados  |  Arredondamento sem usar fórmula…
Super VLookup:Múltiplos Critérios  |  Múltiplos Valores  |  Entre Múltiplas Folhas  |  Correspondência Fuzzy…
Avanç. Lista suspensa:Lista de Opções Simples  |  Lista de Opções Dependente  |  Lista de Opções com Seleção Múltipla…
Gestor de Colunas:Adicionar um Número Específico de Colunas  |  Mover Colunas  |  Alternar Estado de Visibilidade de Colunas Ocultas  |Comparar Colunas para Selecionar Células Iguais/Diferentes…
Funcionalidades em Destaque:Grade de foco  |  Visualização de Design  |  Barra de fórmulas aprimorada  |  Gestor de Pastas de Trabalho e Folhas|Biblioteca de Recursos(Texto Automático)|  Seleção de Data  |  Consolidar Planilhas  |  Encriptar/Descriptografar Células  |  Enviar Emails por Lista  |  Super Filtro  |  Filtro Especial(Filtrar Células com Fonte em Negrito/itálico/rasurado…) …
Principais Conjuntos de Ferramentas 15:12 Ferramentasde Texto(Adicionar Texto,Excluir Caracteres Específicos…)|  50+Tiposde Gráfico(Gráfico de Gantt…)|  40+ Fórmulas Práticas(Calcular a idade com base na data de nascimento…)|  19 Ferramentasde Inserção(Inserir QR Code,Inserir Imagem a Partir do Caminho…)|  12 Ferramentasde Conversão(Converter em Palavras,Conversão de moeda…)|  7 Ferramentasde Mesclar e Dividir(Mesclar Linhas Avançado,Dividir Células do Excel…)|… e muito mais
Utilize o Kutools na sua língua preferida – suporta inglês, espanhol, alemão, francês, chinês e mais 40+ idiomas!

Kutools for Excel Oferece mais de 300 funcionalidades,garantindo que tudo o que precisa está a apenas um clique…

Office Tab – Ative a leitura e edição com separadores no Microsoft Office (incluindo o Excel)

  • Um segundo para alternar entre dezenas de documentos abertos!
  • Reduza centenas de cliques diários e diga adeus à tendinite do rato.
  • Aumente a sua produtividade em 50 % ao visualizar e editar vários documentos simultaneamente.
  • Traz uma navegação eficiente com separadores ao Office (incluindo o Excel), tal como no Chrome, Edge e Firefox.