Dividir cadeia de texto num carácter específico numa célula no Excel

Este tutorial explica como dividir cadeias de texto num carácter específico em colunas separadas utilizando uma fórmula no Excel.

Como dividir uma cadeia de texto num caractere específico numa célula no Excel?

Suponha que tem uma lista de cadeias de texto na coluna B, como ilustrado abaixo, e pretende dividir cada texto no carácter «-», distribuindo os segmentos por três colunas distintas. Neste caso, as fórmulas seguintes serão extremamente úteis.

Fórmulas genéricas

Fórmula genérica para dividir o texto à esquerda

=LEFT(text_string,FIND("Char", text_string)-1)

Fórmula genérica para dividir o texto intermédio

=MID(text_string, FIND("Char", text_string) + 1, FIND("Char", text_string,FIND("Char", text_string)+1) - FIND("Char", text_string) - 1)

Fórmula genérica para dividir o texto à direita

=RIGHT(text_string,LEN(text_string) - FIND("Char", text_string, FIND("Char", text_string) + 1))

Argumentos das fórmulas acima

Como utilizar estas fórmulas?

Em primeiro lugar, divida a primeira cadeia de texto com base num carácter específico

1. Selecione uma célula vazia para exibir o resultado — aqui, escolhi a C3.

2. Introduza a fórmula seguinte e prima a tecla Enter. Em seguida, arraste a célula com a sua fórmula para a esquerda até ao fim, de modo a aplicá-la às restantes células.

=LEFT(B3,FIND("-",B3)-1)

Em segundo lugar, divida a cadeia de texto intermédia com base num carácter específico

1. Selecione uma célula vazia, como a D3, para exibir o resultado.

2. Introduza a fórmula seguinte e prima a tecla Enter. Em seguida, selecione a célula com o resultado e arraste a alça de preenchimento para baixo para aplicar a fórmula às restantes células.

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

Por fim, divida a última cadeia de texto com base num carácter específico

1. Selecione uma célula vazia, como a E3, para exibir o resultado.

2. Introduza a fórmula seguinte e prima a tecla Enter. Selecione a célula com o resultado e arraste a alça de preenchimento para baixo para aplicar a fórmula às outras células.

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

Agora, a cadeia de texto em cada célula da coluna B foi dividida em três partes.

Dicas: Se pretender dividir a cadeia de texto em apenas duas partes com base num carácter específico, depois de extrair a primeira parte com a fórmula ESQUERDA acima, pode utilizar a seguinte fórmula DIREITA para obter a segunda parte, conforme ilustrado na imagem abaixo.

=RIGHT(B3,LEN(B3)-FIND("-",B3))

Como funcionam estas fórmulas?

=LEFT(B3,FIND("-",B3)-1)

• FIND("-",B3)A função PROCURAR devolve a posição inicial do carácter «-» na cadeia de texto «KTE-Jan-359», sendo o resultado 4.
• LEFT(B3,4-1): A função ESQUERDA extrai 3 caracteres (4−1=3) do início da cadeia de texto KTE-Jan-359. Neste caso, o resultado é KTE.
  Nota: Como o primeiro carácter «-» se encontra na 4.ª posição da cadeia de texto, tem de subtrair 1 para o excluir da extração.

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

• FIND("-",B3) + 1: A função PROCURAR devolve a posição inicial do carácter «-» na cadeia de texto KTE-Jan-359. Neste caso, o resultado é 4.
  Nota: Como o primeiro carácter «-» está na 4.ª posição da cadeia de texto, é necessário adicionar 1 a esse valor para extrair o texto após ele, obtendo-se assim 4 + 1 = 5.
• FIND("-",B3,FIND("-",B3)+1)Aqui é apresentado como PROCURAR("-"; "KTE-Jan-359"; 4+1): a função PROCURAR localiza a posição do caráter «-» a partir do 5.º caráter em "KTE-Jan-359" e devolve o resultado 8.
• MID(B3, 5, 8 - 4 - 1): MID(KTE-Jan-359;5;3), o que significa que a função EXT.TEXTO extrai 3 caracteres a partir do 5.º caractere da cadeia de texto "KTE-Jan-359", obtendo como resultado «Jan».

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

• LEN(B3)A função NÚM.CARACT calcula o comprimento total da cadeia de texto "KTE-Jan-359" e devolve o resultado 11.
• FIND("-",B3,FIND("-",B3)+1)A função PROCURAR localiza a posição do caráter «-» a partir do 5.º caráter em "KTE-Jan-359" e devolve o resultado 8.
• RIGHT(B3,11 - 8))A função DIREITA extrai 3 caracteres (11–8) do lado direito de "KTE-Jan-359", resultando em "359".

Funções relacionadas

Fórmulas relacionadas