Ir para o conteúdo principal

Octetos separados de endereço IP no Excel

Você já tentou dividir os endereços IP em colunas separadas na planilha do Excel? Talvez o recurso Texto para coluna possa ajudá-lo a resolver esse trabalho rapidamente, mas, neste artigo, falarei sobre algumas fórmulas para realizar essa tarefa no Excel.


Divida octetos de endereços IP em colunas separadas no Excel

Normalmente, no Excel, as funções LEFT, MID, LEN e FIND podem ajudá-lo a extrair cada octeto do endereço IP em colunas diferentes. Execute as seguintes etapas:

Divida o primeiro octeto dos endereços IP:

Para extrair o primeiro octeto do endereço IP, aplique a fórmula abaixo em uma célula em branco:

=LEFT(A2,FIND(".",A2)-1)

Em seguida, arraste a alça de preenchimento para baixo até as células às quais deseja aplicar esta fórmula, e todos os primeiros octetos dos endereços IP foram extraídos, consulte a captura de tela:

Explicação da fórmula:

ENCONTRAR (".", A2) -1: Esta função FIND retorna a posição do primeiro ponto da célula A2, subtrai 1 significa excluir o ponto em si, você obterá o resultado 2.

LEFT(A2,FIND(".",A2)-1)=LEFT(A2, 2):A função LEFT é usada para extrair 2 caracteres do lado esquerdo da string na célula A2.


Divida o segundo octeto dos endereços IP:

Para obter o segundo octeto dos endereços IP, copie ou insira a seguinte fórmula em uma célula em branco:

=MID(A2,FIND(".",A2)+1,FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1)

Em seguida, arraste a alça de preenchimento para baixo até as células para preencher esta fórmula, e você obterá o resultado conforme necessário, veja a captura de tela:

Explicação da fórmula:

1. ENCONTRAR (".", A2) +1: Esta função FIND retorna a posição do primeiro ponto da célula A2, adiciona 1 meio à extração do próximo caractere, você obterá o resultado o número 4. Esta parte da fórmula é reconhecida como o argumento start_num da função MID.

2. FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1: Esta parte é reconhecida como o argumento num_chars na função MID.

  • FIND (".", A2, FIND (".", A2) +1) = FIND (".", A2,4): Esta função FIND retornará a posição do segundo ponto. E você obterá o número 6.
  • FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1=6-3-1: Subtrair a posição do primeiro ponto da posição do segundo ponto e, em seguida, subtrair 1 do resultado significa remover um ponto inicial. E o resultado é 2.

3. MID(A2,FIND(".",A2)+1,FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1)=MID(A2, 4, 2): Finalmente, esta função MID é usada para extrair 2 caracteres que começam no quarto caractere da célula A2.


Divida o terceiro octeto dos endereços IP:

Para extrair o terceiro octeto dos endereços IP, as funções MID e FIND também podem fazer um favor, insira ou copie a seguinte fórmula em uma célula em branco:

=MID(A2,FIND(".",A2,FIND(".",A2)+1)+1,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1))

Em seguida, arraste a alça de preenchimento para baixo para obter os resultados que você precisa, e apenas o terceiro octeto dos endereços IP foi dividido, veja a captura de tela:

Explicação da fórmula:

1. FIND(".",A2,FIND(".",A2)+1)+1: Esta função FIND aninhada é usada para obter a posição do segundo ponto na célula A2, adicionando 1 meio à extração do próximo caractere, e você obterá o número 7. Esta parte é reconhecida como o argumento start_num da função MID.

2. FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1): Esta parte da fórmula é reconhecida como o argumento num_chars da função MID.

  • FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)=FIND(".",A2, 7): Esta função FIND aninhada é usada para obter a posição do terceiro ponto na célula A2, ela retorna o número 8.
  • FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1)=8-7: Subtraia a posição do segundo ponto da posição do terceiro ponto, e o resultado é 1.

3.MID(A2,FIND(".",A2,FIND(".",A2)+1)+1,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1))=MID(A2, 7, 1): Esta função MID receberá 1 caractere que começa no sétimo caractere da célula A2.


Divida o quarto octeto dos endereços IP:

A fórmula abaixo pode ajudar a extrair o último octeto do endereço IP, copie ou insira a fórmula em uma célula em branco:

=MID(A2,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)+1,LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1))

E então, arraste a alça de preenchimento para preencher esta fórmula para outras células de que você precisa, você obterá o resultado conforme a captura de tela abaixo:

Explicação da fórmula:

1. FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)+1: Esta função FIND aninhada é usada para obter a posição do terceiro ponto na célula A2, adicionando 1 meio à extração do próximo caractere, e você obterá o número 9. Esta parte é reconhecida como o argumento start_num da função MID.

2. LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1):

  • LEN (A2): A função LEN retorna o número total de caracteres na célula A2. Ele receberá o número 11.
  • LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)=11-8: O comprimento total da célula A2 subtrai a posição do terceiro ponto para obter o número do caractere restante. Isso obterá o número 3.

3. MID(A2,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)+1,LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1))=MID(A2, 9, 3): Por fim, esta função MID terá 3 caracteres que começam no nono caractere da célula A2.


Funções relativas usadas:

  • LEFT:
  • A função LEFT extrai o número fornecido de caracteres do lado esquerdo de uma string fornecida.
  • MID:
  • A função MID é usada para encontrar e retornar um número específico de caracteres do meio de uma determinada sequência de texto.
  • FIND:
  • A função FIND é usada para encontrar uma string dentro de outra string e retorna a posição inicial da string dentro de outra.
  • LEN:
  • A função LEN retorna o número de caracteres em uma string de texto.

Mais artigos:

  • Divida o texto e os números em uma célula no Excel
  • Supondo que os dados de uma célula sejam misturados com texto e números, como você pode dividi-los em células de colunas separadas? Este tutorial vai mostrar as etapas detalhadas para obtê-lo com fórmulas.

As melhores ferramentas de produtividade para escritório

Kutools para Excel - ajuda você a se destacar na multidão

🤖 Assistente de IA do Kutools: Revolucionar a análise de dados com base em: Execução Inteligente   |  Gerar Código  |  Crie fórmulas personalizadas  |  Analise dados e gere gráficos  |  Invocar funções do Kutools...
Recursos mais comuns: Encontre, destaque ou identifique duplicatas  |  Excluir linhas em branco  |  Combine colunas ou células sem perder dados  |  Rodada sem Fórmula ...
Super VLookup: Vários critérios  |  Valor múltiplo  |  Em várias folhas  |  Pesquisa Difusa...
Av. Lista suspensa: Lista suspensa fácil  |  Lista suspensa de dependentes  |  Lista suspensa de seleção múltipla...
Gerenciador de colunas: Adicione um número específico de colunas  |  Mover colunas  |  Alternar status de visibilidade de colunas ocultas  Comparar colunas com Selecionar células iguais e diferentes ...
Recursos em destaque: Foco da Grade  |  Vista de Design  |  Grande Barra de Fórmula  |  Gerenciador de pastas de trabalho e planilhas | Biblioteca (Auto texto)  |  Data Picker  |  Combinar planilhas  |  Criptografar/Descriptografar Células  |  Enviar e-mails por lista  |  Super Filtro  |  Filtro Especial (filtro negrito/itálico/tachado...) ...
15 principais conjuntos de ferramentas12 Texto Ferramentas (Adicionar texto, Remover Personagens ...)  |  50+ de cores Tipos (Gráfico de Gantt ...)  |  Mais de 40 práticos Fórmulas (Calcule a idade com base no aniversário ...)  |  19 Inclusão Ferramentas (Insira o código QR, Inserir imagem do caminho ...)  |  12 Conversão Ferramentas (Números para Palavras, Conversão de moedas ...)  |  7 Unir e dividir Ferramentas (Combinar linhas avançadas, Dividir células do Excel ...)  |  ... e mais

Kutools para Excel possui mais de 300 recursos, Garantindo que o que você precisa está a apenas um clique de distância...

Descrição


Guia Office - Habilite leitura e edição com guias no Microsoft Office (inclui Excel)

  • Um segundo para alternar entre dezenas de documentos abertos!
  • Reduza centenas de cliques do mouse para você todos os dias, diga adeus à mão do mouse.
  • Aumenta sua produtividade em 50% ao visualizar e editar vários documentos.
  • Traz guias eficientes para o Office (inclui Excel), assim como Chrome, Edge e Firefox.
Comments (1)
Rated 5 out of 5 · 1 ratings
This comment was minimized by the moderator on the site
This worked beautifully, thank you for this information!!
Rated 5 out of 5
There are no comments posted here yet
Please leave your comments in English
Posting as Guest
×
Rate this post:
0   Characters
Suggested Locations