Dividir dimensões em comprimento, altura e largura individuais

Este artigo explica como dividir as dimensões contidas numa célula em três partes distintas: comprimento, altura e largura.

Como dividir dimensões em três partes?

Para dividir dimensões em comprimento, altura e largura individuais, terá de aplicar três fórmulas distintas separadamente.

Fórmula genérica para extrair a primeira dimensão

=LEFT(text,FIND("char",text)-1)

Fórmula genérica para extrair a segunda dimensão

=MID(text,FIND("char",text)+1,FIND("@",SUBSTITUTE(text,"char","@",2))-(FIND("char",text)+1))

Fórmula genérica para extrair a terceira dimensão

=RIGHT(text,LEN(text)-FIND("@",SUBSTITUTE(text,"char","@",2)))

Argumentos das fórmulas acima

Como utilizar estas fórmulas?

Em primeiro lugar, precisamos de obter a primeira dimensão.

1. Selecione uma célula vazia para exibir a primeira dimensão.

2. Introduza a seguinte fórmula na célula e prima a tecla EnterEm seguida, selecione a célula com o resultado e arraste a pega de preenchimento para aplicar a fórmula às restantes células, conforme necessário.

=LEFT(B5,FIND("x",B5)-1)

De seguida, iremos dividir a segunda dimensão da seguinte forma:

1. Selecione uma célula vazia para exibir a segunda dimensão.

2. Introduza a fórmula seguinte nela e prima a Entertecla. Selecione a célula com o resultado e arraste a pega de preenchimento para aplicar a fórmula a outras células conforme necessário.

=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))

Por fim, obtenha a última dimensão

1. Selecione uma célula vazia para exibir a última dimensão.

2. Introduza a seguinte fórmula e prima a EnterTecla. Selecione a célula com o resultado e arraste a alça de preenchimento para aplicar a fórmula a outras células, conforme necessário.

=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))

Como funcionam estas fórmulas?

=LEFT(B5,FIND("x",B5)-1)

1. FIND("x",B5)-1: A função PROCURAR obtém a posição do primeiro «x» em B5. Para extrair a primeira dimensão sem incluir o «x», subtrai-se 1. O resultado é, portanto, 4−1=3.
2. LEFT(B5,3): A função ESQUERDA extrai os primeiros 3 caracteres do lado esquerdo de B5, devolvendo assim 100.

=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))

1. FIND("x",B5)+1A função PROCURAR localiza a primeira ocorrência de «x» em B5. Como é necessário obter a posição imediatamente após esse primeiro «x», adiciona-se 1 ao resultado. Assim, obtém-se 4 + 1 = 5.
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):

• SUBSTITUTE(B5,"x","@",2): A função SUBSTITUIR substitui a segunda ocorrência de «x» em B5 por «@» e devolve o resultado como 100x50@300;
• FIND("@",100x50@300)A função PROCURAR obtém aqui a posição do carácter «@» no texto «100x50@300» e devolve o resultado 7.

3. (FIND("x",B5)+1): Tal como referido no passo 1, a função PROCURAR localiza o primeiro «x» em B5 e adiciona 1, devolvendo o resultado 5.
4. MID(B5,5,7-(5)): A função EXT.TEXTO extrai dois caracteres (7 − 5 = 2) a partir do quinto carácter do texto em B5, devolvendo o resultado final 50.

=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))

1. LEN(B5): A função NÚM.CARACT calcula o número total de Filtrar por Comprimento do Texto em B5 e devolve o resultado como 10;
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):

• SUBSTITUTE(B5,"x","@",2): A função SUBSTITUIR substitui o segundo «x» em B5 por «@» e devolve o resultado como 100x50@300;
• FIND("@",100x50@300)A função PROCURAR localiza o «@» no texto «100x50@300» e devolve 7 como resultado.

3. LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)): (10-7) O comprimento total da cadeia de texto na célula B5 subtrai os primeiros 7 caracteres, devolvendo o resultado 3.
4. RIGHT(B5,3): Em seguida, a função DIREITA extrai os 3 caracteres mais à direita de B5, devolvendo a terceira dimensão como 300.

Funções relacionadas

Fórmulas relacionadas