Remover a primeira ou a última palavra de uma cadeia

Este tutorial explica como remover apenas a primeira ou a última palavra de uma cadeia de texto numa célula utilizando fórmulas no Excel.

Remover a primeira palavra da cadeia numa célula
Remover a última palavra da cadeia numa célula

Remover a primeira palavra da cadeia numa célula

Nesta secção, aprenderá a utilizar uma combinação das funções DIREITA, NÚM.CARACT e PROCURAR para remover a primeira palavra de uma cadeia numa célula.

Fórmula genérica

=RIGHT(A1,LEN(A1)-FIND(" ",A1))

Argumentos

Como utilizar esta fórmula?

1. Selecione uma célula vazia para exibir o resultado.

2. Introduza a fórmula abaixo na mesma célula e prima a tecla Enter. Em seguida, arraste a pega de preenchimento para baixo para aplicar a fórmula às restantes células.

=RIGHT(B3,LEN(B3)-FIND(" ",B3))

Nota: Nesta fórmula, B3 é a célula que contém a cadeia de texto da qual pretende remover a primeira palavra. Ajuste-a conforme necessário.

Como funciona esta fórmula?

=RIGHT(B3,LEN(B3)-FIND(" ",B3))

1. LEN(B3): A função NÚM.CARACT calcula o comprimento total da cadeia de texto «Mr ana varela (Home)» e devolve o resultado como 20;

2. FIND(" ",B3): Como as palavras são separadas por espaços, aqui a função PROCURAR localiza a posição do primeiro espaço na cadeia de texto «Mr ana varela (Home)» e devolve o resultado como 3;

3. RIGHT(B3,20-3)A função DIREITA extrai 17 caracteres (20 − 3 = 17) do lado direito da cadeia de texto «Mr ana varela (Home)», resultando em «ana varela (Home)».

Remover a última palavra da cadeia numa célula

Se pretender remover a última palavra da cadeia de texto numa célula, siga estes passos.

Fórmula genérica

=LEFT(TRIM(A1),FIND("~",SUBSTITUTE(A1," ","~",LEN(TRIM(A1))-LEN(SUBSTITUTE(TRIM(A1)," ",""))))-1)

Argumentos

Como utilizar esta fórmula?

1. Selecione uma célula vazia para exibir o resultado — neste caso, escolhi a célula D3.

2. Introduza a fórmula abaixo na mesma e prima a tecla Enter. Em seguida, selecione a célula do resultado e arraste a pega de preenchimento para baixo, de modo a aplicar a fórmula às restantes células.

=LEFT(TRIM(B3),FIND("~",SUBSTITUTE(B3," ","~",LEN(TRIM(B3))-LEN(SUBSTITUTE(TRIM(B3)," ",""))))-1)

Nota: Na fórmula, B3 é a célula que contém a cadeia de texto da qual pretende remover a última palavra. Ajuste-a conforme necessário.

Como funciona esta fórmula?

=LEFT(TRIM(B3),FIND("~",SUBSTITUTE(B3," ","~",LEN(TRIM(B3))-LEN(SUBSTITUTE(TRIM(B3)," ",""))))-1)

1. TRIM(B3): A função COMPACTAR remove todos os espaços extra da cadeia «Mr ana varela (Home)» e mantém apenas um espaço único entre palavras. O resultado é «Mr ana varela (Home)»;

2. FIND("~",SUBSTITUTE(B3," ","~",LEN(TRIM(B3))-LEN(SUBSTITUTE(TRIM(B3)," ",""))))

• LEN(TRIM(B3)): Como a função TRIM devolve o resultado como «Mr ana varela (Home)», a função LEN devolve o número de caracteres na cadeia «Mr ana varela (Home)» e devolve o resultado como 20;
• LEN(SUBSTITUTE(TRIM(B3)," ",""))A função SUBSTITUTE substitui todos os espaços na cadeia de texto «Mr ana varela (Home)» por nada, devolvendo «Mranavarela(Home)». Em seguida, a função LEN calcula o comprimento total dessa cadeia e obtém o resultado 17.
• SUBSTITUTE(B3," ","~",20-17)Aqui, a função SUBSTITUTE substitui o terceiro espaço (20 − 17 = 3) na cadeia de texto «Mr ana varela (Home)» pelo caractere «~», resultando em «Mr ana varela~(Home)».
• FIND("~","Mr ana varela~(Home)")A função FIND devolve a posição do caractere «~» na cadeia de texto «Mr ana varela (Home)», sendo o resultado 14.

3. LEFT("Mr ana varela (Home)",14-1): A função ESQUERDA extrai 13 caracteres a partir do início da cadeia de texto «Mr ana varela (Home)», resultando em «Mr ana varela».

Funções relacionadas

Fórmulas relacionadas