Extrair o nome do ficheiro de um caminho no Excel

Este tutorial explica como aplicar fórmulas para extrair o nome do ficheiro — com ou sem extensão — a partir de um caminho de ficheiro numa célula específica no Excel.

Extrair o nome do ficheiro com extensão de um caminho
Extrair o nome do ficheiro sem extensão de um caminho

Extrair o nome do ficheiro com extensão de um caminho

Conforme ilustrado na imagem seguinte, existe uma lista com diferentes caminhos de ficheiros, e pretende extrair apenas os nomes dos ficheiros, incluindo as respetivas extensões. A fórmula abaixo ajudá-lo-á a resolver este problema.

Fórmula genérica

=MID(A1,FIND("*",SUBSTITUTE(A1,"\","*",LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,LEN(A1))

Argumentos

Como utilizar esta fórmula?

1. Selecione uma célula vazia para exibir o nome do ficheiro — neste caso, escolhi a célula D3.

2. Introduza a fórmula seguinte na célula e prima a tecla Enter. Em seguida, selecione a célula com o resultado e arraste a respetiva alça de preenchimento até ao fim para aplicar a fórmula às restantes células.

=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))

Agora, todos os nomes de ficheiros com extensão nos Caminhos do Ficheiro específicos foram extraídos, conforme ilustrado na imagem anterior.

Notas:

• Nesta fórmula, B3 é a célula que contém o caminho do ficheiro. Ajuste-a conforme necessário.
• Se o nome do ficheiro tiver, no máximo, 99 caracteres, pode também utilizar a fórmula mais curta abaixo para resolver o problema. Veja a imagem seguinte.
  =TRIM(RIGHT(SUBSTITUTE(A2,"\",REPT(" ",100)),99))
  

Como funciona esta fórmula?

=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))

1. FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))

• LEN(B3): A função LEN calcula o comprimento total em «D:\\files\work\Q1\Jan\text.txt» e devolve o resultado como 30;
• LEN(SUBSTITUTE(B3,"\",""))A função SUBSTITUTE substitui o carácter «\» por nada, resultando em «D:filesworkQ1Jantext.txt». Em seguida, a função LEN calcula o comprimento total dessa cadeia e obtém o valor 24.
• SUBSTITUTE(B3,"\","*",30-24)A função SUBSTITUTE substitui o terceiro caráter (30 − 24 = 6) «\» em «D:\\files\work\Q1\Jan\text.txt» por um único caráter «*». Neste caso, o resultado é «D:\\files\work\Q1\Jan*text.txt».
• FIND("*","D:\\files\work\Q1\Jan*text.txt")A função FIND localiza a posição do carácter «*» em «D:\\files\work\Q1\Jan*text.txt» e devolve 22, o que significa que o carácter «*» se encontra na 22.ª posição dessa sequência.

2. =MID(B3,22+1,LEN(B3))

• Conforme explicado acima, LEN(B3) devolve 30, pelo que a função MID pode ser escrita como =MID(«D:\\files\work\Q1\Jan\text.txt»,23,30). Isto significa que a função MID extrai 30 caracteres da cadeia «D:\\files\work\Q1\Jan\text.txt», começando no 23.º carácter — resultando em «text.txt».

Extrair o nome do ficheiro sem extensão de um caminho

Noutra situação, poderá precisar apenas de extrair o nome do ficheiro sem a extensão a partir de um caminho, conforme ilustrado na imagem seguinte. Esta secção apresenta uma fórmula detalhada para o ajudar a realizar esta tarefa com sucesso.

Fórmula genérica

=IFERROR(MID(A1,FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(A1,".",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,".",""))))-FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))-1),"")

Argumentos

Como utilizar esta fórmula?

1. Selecione uma célula vazia para exibir o nome do ficheiro sem a extensão.

2. Introduza a fórmula seguinte na célula e prima Enter. Em seguida, selecione a célula com o resultado e arraste a respetiva alça de preenchimento até ao fim para aplicar a fórmula às restantes células.

=IFERROR(MID(B4,FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(B4,".",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,".",""))))-FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))-1),"")

Nota: Nesta fórmula, B3 é a célula que contém o caminho do ficheiro. Ajuste-a conforme necessário.

Funções relacionadas

Fórmulas relacionadas