Extrair todas as palavras exceto a primeira ou a última de uma célula no Excel

Neste tutorial, vai aprender a usar fórmulas para extrair todas as palavras de uma célula, exceto a primeira ou a última, no Excel.

Extrair todas as palavras exceto a primeira de uma célula no Excel
Extrair todas as palavras exceto a última de uma célula no Excel

Extrair todas as palavras exceto a primeira de uma célula no Excel

Conforme ilustrado na imagem abaixo, pretende extrair todas as palavras de cada célula da coluna B, exceto a primeira. Para o conseguir, pode utilizar uma combinação das funções DIREITA, NÚM.CARACT e PROCURAR. Proceda da seguinte forma:

Fórmula genérica

=RIGHT(text_string,LEN(text_string)-FIND(" ",text_string,1))

Argumentos

Como utilizar esta fórmula?

1. Selecione uma célula vazia para exibir as palavras extraídas — neste caso, escolhi a célula D3.

2. Introduza a fórmula abaixo na célula e prima a tecla Enter. Em seguida, selecione a célula com a fórmula e arraste-a para aplicar às restantes células.

=RIGHT(B3,LEN(B3)-FIND(" ",B3,1))

Agora, todas as palavras nas células específicas foram extraídas, exceto as primeiras.

Nota: Na fórmula acima, B3 é a célula que contém as palavras das quais irá extrair todas, exceto a primeira. Ajuste-a conforme necessário.

Como funciona esta fórmula?

=RIGHT(B3,LEN(B3)-FIND(" ",B3,1))

1. LEN(B3): A função NÚM.CARACT calcula o comprimento total de Excel handy addin e devolve o resultado como 17;

2. FIND(" ",B3,1): Como as palavras estão separadas por espaços, a função PROCURAR localiza a posição do primeiro espaço em Excel handy addin e devolve o resultado como 6;

3. RIGHT(B3,17-6): A função DIREITA extrai 11 caracteres (17 − 6 = 11) do lado direito da cadeia de texto «Excel handy addin», resultando em «handy addin».

Extrair todas as palavras exceto a última de uma célula no Excel

Nesta secção, vamos utilizar uma combinação das funções ESQUERDA, PROCURAR, SUBSTITUIR e NÚM.CARACT para extrair todas as palavras de uma célula específica no Excel, exceto a última.

Fórmula genérica

=LEFT(text_string,FIND("[",SUBSTITUTE(text_string," ","[",LEN(text_string)-LEN(SUBSTITUTE(text_string," ",""))))-1)

Argumentos

Como utilizar esta fórmula?

1. Selecione uma célula vazia (como D3, neste caso) para exibir as palavras extraídas.

2. Introduza a fórmula abaixo na célula e prima a tecla Enter. Depois, arraste a célula com a fórmula para aplicá-la às restantes células.

=LEFT(B3,FIND("[",SUBSTITUTE(B3," ","[",LEN(B3)-LEN(SUBSTITUTE(B3," ",""))))-1)

Agora, todas as palavras nas células específicas foram extraídas, exceto as últimas.

Nota: Na fórmula acima, B3 é a célula que contém as palavras das quais irá extrair tudo, exceto a última. Ajuste-a conforme necessário.

Como funciona esta fórmula?

=LEFT(B3,FIND("[",SUBSTITUTE(B3," ","[",LEN(B3)-LEN(SUBSTITUTE(B3," ",""))))-1)

1. SUBSTITUTE(B3," ","[",LEN(B3)-LEN(SUBSTITUTE(B3," ","")))

• LEN(B3): A função NÚM.CARACT calcula o comprimento total do texto «Excel handy addin» e devolve o resultado como 17;
• LEN(SUBSTITUTE(B3," ",""))A função SUBSTITUIR remove todos os espaços em «Excel handy addin», resultando em «Excelhandyaddin», e de seguida a função NÚM.CARACT calcula o comprimento total desse texto. O resultado final é 15.
• SUBSTITUTE(B3," ","[",17-15))A função SUBSTITUIR substitui o segundo espaço em «Excel handy addin» pelo caractere «[», devolvendo «Excel handy[addin».

2. FIND("[","Excel handy[addin")

• A função PROCURAR identifica a posição do caractere «[» na cadeia de texto «Excel handy[addin». Neste caso, o caractere «[» encontra-se na 12.ª posição da cadeia, pelo que a função devolve o valor 12.

3. =LEFT(B3,12-1)

• A função ESQUERDA extrai 11 caracteres (12 − 1 = 11) do início da cadeia de texto «Excel handy addin», resultando em «Excel handy».

Funções relacionadas

Fórmulas relacionadas