Contar palavras específicas num intervalo no Excel

Este artigo apresenta uma fórmula para contar quantas vezes uma palavra específica aparece num intervalo de células no Excel.

Como contar palavras específicas num intervalo de células no Excel?

Fórmula genérica

=SUMPRODUCT((LEN(rng)-LEN(SUBSTITUTE(rng,txt,"")))/LEN(txt))

Argumentos

Como utilizar esta fórmula?

Suponha que pretende contar o número de ocorrências da palavra «tool» no intervalo B5:B8. Pode fazê-lo da seguinte forma:

Selecione uma célula vazia, introduza a fórmula abaixo e, em seguida, prima a tecla Enter.

Dicas:Pode copiar e colar diretamente a fórmula na célula selecionada.

=SUMPRODUCT((LEN(B5:B8)-LEN(SUBSTITUTE(B5:B8,"tool","")))/LEN("tool"))

Notas:

• 1. Por favor, ajuste o intervalo B5:B8 e a palavra «tool» de acordo com as suas necessidades;
• 2. Se a palavra não for encontrada, é devolvido 0;
• 3. A fórmula diferencia maiúsculas de minúsculas;
• 4. Para contar uma palavra específica num intervalo de células, ignorando maiúsculas e minúsculas, utilize a função UPPER dentro da função SUBSTITUTE, conforme demonstrado na fórmula abaixo:
• =SUMPRODUCT((LEN(B5:B8)-LEN(SUBSTITUTE(UPPER(B5:B8),UPPER("tool"),"")))/LEN("tool"))
• 

Como funciona esta fórmula?

=SUMPRODUCT((LEN(B5:B8)-LEN(SUBSTITUTE(B5:B8,"tool","")))/LEN("tool"))

• 1. LEN(B5:B8): A função LEN calcula o total de Filtrar por Comprimento do Texto para cada célula no intervalo B5:B8, devolvendo um conjunto de números {47;23;23;15};
• 2. LEN(SUBSTITUTE(B5:B8,"tool","")): Aqui, a função SUBSTITUTE remove a palavra «tool» de cada célula no intervalo B5:B8 e, de seguida, a função LEN calcula o comprimento do conteúdo de cada célula desse intervalo sem a palavra «tool», devolvendo o conjunto de números {35;19;19;15}.
• 3. (LEN(B5:B8)-LEN(SUBSTITUTE(B5:B8,"tool","")): Esta parte da fórmula transforma-se agora em {47;23;23;15}–{35;19;19;15}. Após a subtração, o resultado é {12;4;4;0};
• 4. LEN("tool"): A função LEN aqui calcula o comprimento de «tool» e devolve o resultado 4;
• 5. LEN(B5:B8)-LEN(SUBSTITUTE(B5:B8,"tool","")))/LEN("tool"): Tal como referido acima, esta parte resulta em {12;4;4;0}/4. Ao dividir cada número do conjunto por 4, obtém-se o resultado {3;1;1;0};
• 6. SUMPRODUCT({3;1;1;0}): A função SUMPRODUCT soma os números do conjunto e devolve o total de ocorrências de «tool» no intervalo B5:B8.

Funções relacionadas

Fórmulas relacionadas