Adicionar espaço entre número e texto em uma célula no Excel
Neste artigo, aprenderemos como adicionar espaço entre número e texto com fórmulas no Excel.
Caso 1: adicione espaço entre o número e o texto - o texto sempre vem primeiro
Caso 2: adicione espaço entre o número e o texto - o número sempre vem primeiro
Adicione espaço entre o número e o texto - o texto sempre vem primeiro
Supondo que haja uma lista de string de texto que contém número e texto em que o texto sempre vem primeiro como a imagem abaixo mostrada, você pode adicionar espaço entre o número e o texto com a fórmula abaixo.
Fórmula genérica
=TRIM(REPLACE(text_string,MIN(FIND({1,2,3,4,5,6,7,8,9,0},text_string&”1234567890”)),0,” “))
Argumentos
Texto_string: A sequência de texto que você adicionará ao espaço entre o texto e o número. Pode ser:
- A sequência de texto entre aspas;
- Ou uma referência a uma célula que contém a string de texto.
Como usar essa fórmula?
1. Selecione uma célula em branco para produzir o resultado. Nesse caso, seleciono D3.
2. Insira a fórmula abaixo e pressione o botão Entrar chave. Em seguida, arraste esta célula de resultado totalmente para baixo para aplicar a fórmula a outras células.
=TRIM(REPLACE(B3,MIN(FIND({1,2,3,4,5,6,7,8,9,0},B3&"1234567890")),0," "))
Notas:
- Na fórmula, B3 é a célula da string de texto à qual você adicionará um espaço entre o texto e o número;
- Esta fórmula só pode adicionar um espaço antes do primeiro número. Por exemplo, esta fórmula mudará B34C12G45 para B 34C12G45.
Como funciona essa fórmula?
=TRIM(REPLACE(B3,MIN(FIND({1,2,3,4,5,6,7,8,9,0},B3&"1234567890")),0," "))
1. FIND({1,2,3,4,5,6,7,8,9,0},B3&"1234567890")
- B3&"1234567890": retorna o resultado como: "KutoolsforExcel634211234567890";
- FIND({1,2,3,4,5,6,7,8,9,0}, "KutoolsforExcel634211234567890"): A função FIND encontra a posição dos dígitos "1-0" em KutoolsforExcel634211234567890 e retorna o resultado como {20,19,17,18,25,16,27,28,29,30}.
Note: O resultado {20,19,17,18,25,16,27,28,29,30} significa que o número 1 está na 20ª posição em KutoolsforExcel634211234567890, o número 2 está na 19ª posição em KutoolsforExcel634211234567890…
2. MIN({20,19,17,18,25,16,27,28,29,30})
- A função MIN obtém o valor mínimo da matriz. Aqui, o resultado é 16.
3. REPLACE(KutoolsforExcel63421,16,0," ")
- Aqui, use a função REPLACE para adicionar um espaço à 16ª posição no KutoolsforExcel63421 e retornar o resultado como KutoolsforExcel 63421.
4. =TRIM("KutoolsforExcel 63421")
- A função TRIM remove todos os espaços do texto, exceto espaços simples entre as palavras. E não mantém espaços à esquerda e à direita do texto.
Adicione espaço entre o número e o texto - o número sempre vem primeiro
Outro caso como a imagem abaixo mostrada, há uma lista de string de texto que contém número e texto onde o número sempre vem primeiro, você pode aplicar a fórmula de matriz abaixo para adicionar um espaço entre o número e o texto.
Fórmula genérica
=TRIM(REPLACE(text_string,MAX(IFERROR(FIND({0,1,2,3,4,5,6,7,8,9},text_string,ROW(INDIRECT("1:"&LEN(text_string)))),0))+1,0," ")) + Ctrl + Shift + Entrar
Argumentos
Texto_string: A sequência de texto que você adicionará ao espaço entre o texto e o número. Pode ser:
- A sequência de texto entre aspas;
- Ou uma referência a uma célula que contém a string de texto.
Como usar essa fórmula?
1. Selecione uma célula em branco (D3 neste caso) para produzir o resultado.
2. Insira a fórmula abaixo e pressione o botão Ctrl + Shift + Entrar chaves simultaneamente.
=TRIM(REPLACE(B3,MAX(IFERROR(FIND({0,1,2,3,4,5,6,7,8,9},B3,ROW(INDIRECT("1:"&LEN(B3)))),0))+1,0," "))
3. Selecione a célula de resultado e arraste-a totalmente para baixo para aplicar a fórmula a outras células, conforme mostrado na captura de tela abaixo.
Notas:
- Na fórmula, B3 é a célula da string de texto à qual você adicionará um espaço entre o texto e o número;
- Esta fórmula de matriz só pode adicionar um espaço após o último número. Por exemplo, esta fórmula mudará 34C12GHH para 34C12 GHH.
Funções relacionadas
Função Excel TRIM
A função TRIM do Excel remove todos os espaços extras da sequência de texto e mantém apenas espaços simples entre as palavras.
Função REPLACE do Excel
A função REPLACE do Excel localiza e substitui caracteres com base em um determinado local da string de texto por um novo texto.
Função Excel MIN
A função Excel MIN retorna o menor número em um conjunto de valores.
Função FIND do Excel
A função FIND do Excel é usada para localizar uma string dentro de outra string e retorna a posição inicial da string dentro de outra.
Função Excel MAX
A função Excel MAX retorna o maior número em um conjunto de valores.
Função Excel IFERROR
A função IFERROR é usada para retornar um resultado personalizado quando uma fórmula avalia um erro e retornar um resultado normal quando nenhum erro ocorre.
Função Excel ROW
A função ROW do Excel retorna o número da linha de uma referência.
Função INDIRETA do Excel
A função INDIRETO do Excel converte uma string de texto em uma referência válida.
Função LEN do Excel
A função LEN do Excel retorna o número de caracteres em uma string de texto.
Fórmulas Relacionadas
Adicionar vírgula após a primeira palavra em uma célula no Excel
Para adicionar uma vírgula após a primeira palavra apenas em uma célula, a fórmula neste tutorial pode fazer um favor.
Adicione um caractere específico antes de cada palavra em uma célula
Este artigo explica como adicionar um caractere específico antes de cada palavra em uma célula com fórmula no Excel.
Adicionar travessões ao número de telefone
Este artigo explica como adicionar travessões a um número de telefone em uma determinada célula com fórmula no Excel.
Adicionar vírgula entre os nomes
Para adicionar vírgulas entre nomes em uma célula, a fórmula neste tutorial pode fazer um favor.
As melhores ferramentas de produtividade para escritório
Kutools para Excel - ajuda você a se destacar na multidão
Kutools para Excel possui mais de 300 recursos, Garantindo que o que você precisa está a apenas um clique de distância...
Guia Office - Habilite leitura e edição com guias no Microsoft Office (inclui Excel)
- Um segundo para alternar entre dezenas de documentos abertos!
- Reduza centenas de cliques do mouse para você todos os dias, diga adeus à mão do mouse.
- Aumenta sua produtividade em 50% ao visualizar e editar vários documentos.
- Traz guias eficientes para o Office (inclui Excel), assim como Chrome, Edge e Firefox.
