Como importar aniversários do Excel para o calendário do Outlook?

Se tiver uma longa lista de aniversários numa folha de cálculo e quiser importá-los rapidamente para o seu calendário do Outlook como eventos, como pode fazer isso com métodos ágeis?

---

Importar aniversários do Excel para o calendário do Outlook com código VBA

Normalmente, não há uma forma direta de importar aniversários para o calendário do Outlook. Para resolver esse problema, criei um código VBA especialmente para si. Siga os passos seguintes:

1. Abra a folha de cálculo que contém os aniversários que pretende importar para o Outlook e, em seguida, mantenha premidas as teclas ALT + F11 para abrir a janela do Microsoft Visual Basic for Applications.

2. Clique em Inserir > Módulo e cole o seguinte código na janela do módulo.

Código VBA: Importar aniversários para o calendário do Outlook

Sub ImportBirthdaysToCalendar()
'Updateby ExtendOffice
Dim xWs As Excel.Worksheet
Dim xRng As Range
Dim xOlApp As Outlook.Application
Dim xCalendarFld As Outlook.Folder
Dim xAppointmentItem As Outlook.AppointmentItem
Dim xRecurrencePattern As Outlook.RecurrencePattern
Dim xRow As Integer
On Error Resume Next
Set xWs = ThisWorkbook.ActiveSheet
Set xRng = Application.InputBox("Please select the data range (only two columns):", "Kutools for Excel", , , , , , 8)
If xRng Is Nothing Then Exit Sub
If xRng.Columns.Count <> 2 Then
  MsgBox "You can only select two columns", vbOKOnly + vbCritical, "Kutools for Excel"
  Exit Sub
End If
Set xOlApp = CreateObject("Outlook.Application")
Set xCalendarFld = xOlApp.Session.GetDefaultFolder(olFolderCalendar)
For xRow = 1 To xRng.Rows.Count
  Set xAppointmentItem = xCalendarFld.Items.Add("IPM.Appointment")
  With xAppointmentItem
    .Subject = xRng.Cells(xRow, 1) & Chr(39) & "s Birthday"
    .AllDayEvent = True
    .Start = xRng.Cells(xRow, 2)
    Set xRecurrencePattern = .GetRecurrencePattern
    xRecurrencePattern.RecurrenceType = olRecursYearly
    .Save
  End With
Next
Set xWs = Nothing
Set xCalendarFld = Nothing
Set xOlApp = Nothing
End Sub

3. Ainda na janela do Microsoft Visual Basic for Applications, clique em Ferramentas > Referências. Na caixa de diálogo que surge, Referências – VBAProject, assinale a opção Microsoft Outlook 16,0 Object Library na lista de Referências Disponíveis, conforme ilustrado na imagem:

4. Em seguida, clique em OK para fechar esta caixa de diálogo. De seguida, prima a tecla F5 para executar este código e surgirá uma caixa de aviso a solicitar que selecione as colunas de nome e data de aniversário, conforme ilustrado na imagem:

5. De seguida, clique no botão OK e os aniversários serão imediatamente importados para o calendário do Outlook. Pode abrir o Outlook para visualizar o resultado, conforme ilustrado na imagem: