Outlook: Como reenviar automaticamente um e-mail se não houver resposta

Quando enviar um e-mail ao seu colega, parceiro colaborador ou outra pessoa e precisar de uma resposta com urgência, pode configurar um reenvio automático caso a resposta não chegue até um determinado momento.

Utilizar lembrete e VBA para configurar o reenvio automático caso não haja resposta

---

Utilizar lembrete e VBA para configurar o reenvio automático caso não haja resposta

Parte 1: definir um lembrete para notificar num momento específico

1. Clique com o botão direito do rato num e-mail da pasta «Itens Enviados» que pretenda reenviar caso não receba resposta e, no menu de contexto apresentado, selecione «Seguir» > «Adicionar lembrete».

2. Na caixa de diálogo «Personalizado» que surge, mantenha a caixa de verificação «Lembrete» assinalada e, nas caixas pendentes abaixo, selecione a data e a hora até às quais pretende receber a resposta. Também pode introduzir diretamente a data e a hora nas respetivas caixas. Clique em «OK».

Parte 2: Inserir um código VBA para reenviar e-mails se não houver resposta dentro do tempo especificado

3. Prima as teclas «Alt» + «F11» para abrir a janela do Microsoft Visual Basic for Applications.

4. Faça duplo clique em «ThisOutlookSession» no painel «Projeto – Projeto1» para criar um script em branco e copie e cole o seguinte código VBA nesse script.

VBA: Reenviar e-mail se não houver resposta

Public WithEvents GInboxItems As Outlook.Items
'UpdatebyExtendoffice20220413
Private Sub Application_Startup()
  Dim xInboxFld As Folder
  Set xInboxFld = Application.Session.GetDefaultFolder(olFolderInbox)
  Set GInboxItems = xInboxFld.Items
End Sub

'Judge
Private Sub GInboxItems_ItemAdd(ByVal Item As Object)
  Dim xSentItems As Outlook.Items
  Dim xMail As MailItem
  Dim i As Long
  Dim xSubject As String
  Dim xItemSubject As String
  Dim xSendTime As String
  On Error Resume Next
  Set xSentItems = Application.Session.GetDefaultFolder(olFolderSentMail).Items
  If Item.Class <> olMail Then Exit Sub
  For i = xSentItems.Count To 1 Step -1
    If xSentItems.Item(i).Class = olMail Then
      Set xMail = xSentItems.Item(i)
      xSubject = LCase(xMail.Subject)
      xSendTime = xMail.SentOn
      xItemSubject = LCase(Item.Subject)
      If (xItemSubject = "re: " & xSubject) Or (InStr(xItemSubject, xSubject) > 0) Then
        If Item.SentOn > xSendTime Then
           With xMail
             .ClearTaskFlag
             .ReminderSet = False
             .Save
           End With
        End If
      End If
    End If
  Next i
End Sub

'Reminder
Private Sub Application_Reminder(ByVal Item As Object)
  Dim xPrompt As String
  Dim xResponse As Integer
  Dim xFollowUpMail As Outlook.MailItem
  Dim xRcp As Recipient
  On Error Resume Next
  'Resend
  If (Item.Class <> olMail) Then Exit Sub
  xPrompt = "You haven't yet received the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
  xResponse = MsgBox(xPrompt, vbYesNo + vbQuestion, "Kutools for Outlook")
  If xResponse = vbNo Then Exit Sub
  Set xFollowUpMail = Application.CreateItem(olMailItem)
  With xFollowUpMail
    For Each xRcp In Item.Recipients
      .Recipients.Add (xRcp.Address)
    Next
    .Recipients.ResolveAll
    .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
    .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & " as soon as possible"
    .Attachments.Add Item
    .Display
  End With
End Sub

5. Guarde o código e regresse à interface principal. Clique em «Ficheiro» > «Opções»; na janela «Opções do Outlook», selecione «Centro de Confiança» no painel esquerdo e, de seguida, clique em «Definições do Centro de Confiança» para abrir a respetiva janela. Escolha «Definições de Macros» e certifique-se de que a opção «Ativar todas as macros (não recomendado; poderá executar código potencialmente perigoso)» está selecionada na secção da direita. Clique em «OK» > «OK».

6. Agora, se o e-mail enviado — ao qual foi atribuído um lembrete — não receber resposta na hora especificada, surgirá uma caixa de diálogo a perguntar se pretende reenviá-lo como notificação.

7. Clique em «Sim» e abrir-se-á uma janela de mensagem com o e-mail anterior anexado, permitindo-lhe editar novamente o corpo da mensagem e clicar em «Enviar» para reenviá-lo.

8. Clique em «Não» e o lembrete será eliminado.

Nota: Se o e-mail tiver sido respondido antes da hora especificada, o lembrete será automaticamente removido pelo VBA.