Como limpar todas as categorias do Outlook?

Suponha que tenha muitos itens com categorias de cor aplicadas no seu Outlook. Como pode remover rapidamente e facilmente todas essas categorias dos itens?

Limpar todas as categorias de uma pasta específica com a funcionalidade Limpar Todas as Categorias

Limpar todas as categorias de uma conta específica com código VBA

---

Limpar todas as categorias de uma pasta específica com a funcionalidade Limpar Todas as Categorias

Se pretender apenas limpar as categorias numa pasta específica, proceda da seguinte forma:

1. Clique na pasta da qual deseja remover as Categorias de Cor e, em seguida, prima Ctrl + A para selecionar todos os itens.

2. Em seguida, clique com o botão direito do rato e escolha Categorizar > Limpar Todas as Categorias no menu de contexto, conforme ilustrado na captura de ecrã:

3. E, assim, todas as categorias de cor nesta pasta específica foram removidas de uma só vez.

---

Limpar todas as categorias de uma conta específica com código VBA

Para limpar todas as categorias de todos os itens — como mensagens de correio eletrónico, tarefas, contactos, notas, entre outros — de uma conta, o código VBA abaixo pode ajudá-lo:

1. Clique numa conta de correio eletrónico da qual pretende remover todas as categorias e, em seguida, mantenha premidas as teclas ALT + F11 para abrir a janela do Microsoft Visual Basic for Applications.

2. Clique em Inserir > Módulo e cole a seguinte macro na janela do Módulo.

Código VBA: Limpar todas as categorias de uma conta específica:

Sub BatchClearAllCategories_AllOutlookItems()
    Dim xCurrentFolder As Outlook.Folder
    Dim xFolder As Folder, xCurFolder As Folder
    Dim xPos As Integer
    Dim xRootFldName As String
    Set xCurFolder = Outlook.ActiveExplorer.CurrentFolder
    xPos = InStr(3, xCurFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = Mid(xCurFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = Mid(xCurFolder.FolderPath, 3, Len(xCurFolder.FolderPath) - 2)
    End If
    Set xCurrentFolder = Outlook.Application.Session.Folders(xRootFldName)
    For Each xFolder In xCurrentFolder.Folders
        Call ProcessFolders(xFolder)
    Next
    MsgBox "Clear completed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub
Sub ProcessFolders(ByVal CurFld As Outlook.Folder)
    Dim xItem As Object
    Dim i As Integer
    Dim xSubfolder As Outlook.Folder
    If CurFld.Items.Count > 0 Then
        For i = CurFld.Items.Count To 1 Step -1
            Set xItem = CurFld.Items.Item(i)
            xItem.Categories = ""
            xItem.Save
        Next
    End If
    If CurFld.Folders.Count = 0 Then Exit Sub
    For Each xSubfolder In CurFld.Folders
        Call ProcessFolders(xSubfolder)
    Next
End Sub

3. Em seguida, prima a tecla F5 para executar o código. Será apresentada uma caixa de aviso a informar que todas as categorias da conta selecionada foram removidas, conforme ilustrado na captura de ecrã: