Como manter a categoria ao responder ou reencaminhar um e-mail no Outlook?

Normalmente, quando responde ou reencaminha um e-mail que categorizou, a categoria é automaticamente removida na mensagem enviada. Se pretender manter a categoria nas mensagens enviadas ao responder ou reencaminhar, este artigo apresenta um método para resolver esta situação.

Manter a categoria ao responder ou reencaminhar um e-mail com código VBA

---

Manter a categoria ao responder ou reencaminhar um e-mail com código VBA

1. Mantenha premidas as teclas ALT + F11 para abrir a janela do Microsoft Visual Basic for Applications.

2. Na janela do Microsoft Visual Basic for Applications, faça duplo clique em ThisOutlookSession no painel Project1 (VbaProject.OTM) para abrir o módulo e, em seguida, copie e cole o seguinte código no módulo vazio.

Código VBA: Manter a categoria ao responder ou reencaminhar um e-mail:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

3. Em seguida, guarde e feche esta janela de código, saia do Outlook e reinicie-o. Agora, ao responder ou reencaminhar um e-mail com categoria, esta será mantida na mensagem enviada na pasta Itens Enviados, conforme ilustrado na imagem: