Como imprimir tarefas por categoria no Outlook?

Suponha que tenha várias Categorias de Cor atribuídas às suas tarefas no Outlook e que, neste momento, pretenda imprimir listas de tarefas organizadas por categoria, cada uma numa página separada. Como pode realizar esta tarefa no Outlook?

Imprimir tarefas com base nas categorias em páginas diferentes manualmente, uma a uma

Imprimir tarefas com base nas categorias em páginas diferentes com código VBA

---

Imprimir tarefas com base nas categorias em páginas diferentes manualmente, uma a uma

No Outlook, pode imprimir manualmente as tarefas por categoria, com cada categoria a aparecer numa página separada. Siga estes passos:

1. Inicie o Outlook, aceda ao painel Tarefas e selecione a pasta de tarefas que pretende imprimir. Em seguida, prima Ctrl + E para ativar a caixa de Pesquisa, clique no ícone Categorizadas e escolha uma categoria por cor que pretenda imprimir, conforme ilustrado na captura de ecrã:

2. De seguida, todas as tarefas com essa categoria específica por cor serão listadas imediatamente, tal como ilustrado na captura de ecrã:

3. Em seguida, clique em Ficheiro > Imprimir para imprimir esta lista de tarefas, conforme mostrado na seguinte captura de ecrã:

4. Repita os passos acima para imprimir manualmente, uma a uma, as listas de tarefas com as restantes Categoria de Cor.

---

Imprimir tarefas com base nas categorias em páginas diferentes com código VBA

Aqui está um código VBA que lhe permite imprimir tarefas por categoria, cada uma numa página diferente, tudo de uma só vez. Siga os passos abaixo:

1. Aceda ao painel Tarefas e selecione a pasta de tarefas que pretende imprimir.

2. Em seguida, mantenha premidas as teclas ALT + F11 para abrir a janela do Microsoft Visual Basic for Applications.

3. Em seguida, clique em Inserir > Módulo e copie e cole o código abaixo no módulo em branco aberto:

Código VBA: Imprimir tarefas com base nas categorias em páginas diferentes:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. Em seguida, clique em Ferramentas > Referências na janela do Microsoft Visual Basic for Applications. Na caixa de diálogo Referências – Project1 que surge, marque as opções Microsoft Excel Object Library e Microsoft Scripting Runtime na lista Referências disponíveis, conforme ilustrado na captura de ecrã:

5. Em seguida, clique no botão OK. Agora, prima a tecla F5 para executar este código. Após a conclusão, as listas de tarefas com categorias diferentes serão impressas em páginas distintas.