Como exportar a estrutura de pastas do Outlook para o Excel?

Neste artigo, mostro-lhe como exportar a estrutura de pastas de uma conta do Outlook para um ficheiro do Excel. Siga os passos descritos para o conseguir facilmente.

Exportar Estrutura de Pasta de uma conta do Outlook para o Excel utilizando código VBA

---

Exportar Estrutura de Pasta de uma conta do Outlook para o Excel utilizando código VBA

O seguinte código VBA poderá ajudá-lo; siga os passos abaixo:

1. Ative o Excel e mantenha premidas as teclas ALT + F11 para abrir a janela do Microsoft Visual Basic for Applications.

2. Clique em Inserir > Módulo e cole o seguinte código na janela do Módulo.

Código VBA: Exportar Estrutura de Pasta de uma conta do Outlook para o Excel:

Dim xExcelApp As Excel.Application
Dim xWb As Excel.Workbook
Dim xWs As Excel.Worksheet
Dim xMainFolderCount As Long
Sub OutlookExportFolderStructureToExcel()
    Dim xFolder As Folder
    Dim xExcelFile As String
    Dim xFileDialog As FileDialog
    On Error Resume Next
    Set xFolder = Outlook.Application.Session.PickFolder
    If xFolder Is Nothing Then Exit Sub
    Set xExcelApp = New Excel.Application
    Set xWb = xExcelApp.Workbooks.Add
    Set xWs = xWb.Sheets(1)
    With xWs.Range("A1", "A1")
         .Value = "Folder Structure"
         .Font.Size = 14
         .Font.Bold = True
    End With
    xMainFolderCount = Len(xFolder.FolderPath) - Len(Replace(xFolder.FolderPath, "\", "")) + 1
    Call ExportToExcel(xFolder.FolderPath, xFolder.Name)
    Call ProcessFolders(xFolder.Folders)
    xWs.Columns("A").AutoFit
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogSaveAs)
    With xFileDialog
        .AllowMultiSelect = False
        .FilterIndex = 1
        If .Show = 0 Then
            xWb.Close False
            xExcelApp.Quit
            Set xExcelApp = Nothing
            Exit Sub
        End If
        xExcelFile = .SelectedItems.Item(1)
    End With
    xWb.Close True, xExcelFile
    MsgBox "Export complete!", vbExclamation, "Kutools for Outlook"
End Sub

Sub ProcessFolders(ByVal xFlds As Folders)
    Dim xSubFolder As Folder
    For Each xSubFolder In xFlds
        If xSubFolder.Name <> "Conversation Action Settings" And xSubFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(xSubFolder.FolderPath, xSubFolder.Name)
           Call ProcessFolders(xSubFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef xFolderPath As String, xFolderName As String)
    Dim i, n As Long
    Dim xPrefix As String
    Dim xLastRow As Integer
    i = Len(xFolderPath) - Len(Replace(xFolderPath, "\", "")) - xMainFolderCount
    For n = 0 To i
        xPrefix = xPrefix & "-"
    Next
    xFolderName = xPrefix & xFolderName
    xLastRow = xWs.UsedRange.Rows.Count + 1
    xWs.Range("A" & xLastRow) = xFolderName
End Sub

3.Ainda na janela do Microsoft Visual Basic for Applications, clique em Ferramentas>Referênciaspara aceder à caixa de diálogo Referências – Projeto1, e assinale a opção Microsoft Excel Object Libraryna lista de Referências Disponíveis, conforme ilustrado na captura de ecrã:

4. Em seguida, clique no botão OK e prima a tecla F5 para executar este código. Surge uma caixa de diálogo Selecionar Pasta; selecione a conta de correio eletrónico da qual pretende exportar a sua estrutura de pastas, conforme ilustrado na captura de ecrã:

5. De seguida, clique no botão OK e surge uma janela Guardar Ficheiro; especifique uma localização e um nome para este ficheiro exportado, conforme ilustrado na captura de ecrã:

6. Por fim, clique no botão Guardar e poderá aceder à pasta de trabalho do Excel especificada, onde guardou a estrutura de pasta exportada, conforme ilustrado na captura de ecrã: