Como remover automaticamente determinados caracteres especiais da linha de assunto ao enviar e-mails?

Poderá inserir acidentalmente alguns caracteres especiais ao digitar o assunto na linha de assunto ao enviar um e-mail no Outlook, pelo que terá de os remover um a um. Neste artigo, explico como remover automaticamente todos esses caracteres especiais do assunto ao enviar e-mails.

Remover automaticamente todos os caracteres especiais da linha de assunto ao enviar e-mails com código VBA

---

Remover automaticamente todos os caracteres especiais da linha de assunto ao enviar e-mails com código VBA

Para remover automaticamente os caracteres especiais da linha de assunto ao enviar e-mails, utilize o seguinte código VBA. Siga estes passos:

1. Mantenha premidas as teclas ALT + F11 para abrir a janela Microsoft Visual Basic for Applications.

2. Na janela Microsoft Visual Basic for Applications, clique duas vezes em ThisOutlookSession no painel Project1 (VbaProject.OTM) para abrir o módulo e, em seguida, copie e cole o seguinte código no módulo em branco.

Código VBA: Remover automaticamente caracteres especiais da linha de assunto

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim xMailItem As Outlook.MailItem
    Dim xRegExp As RegExp
    Dim xSubject As String
    On Error Resume Next
    If Item.Class <> olMail Then Exit Sub
    Set xMailItem = Item
    xSubject = xMailItem.Subject
    Set xRegExp = CreateObject("VBScript.RegExp")
    With xRegExp
        .Global = True
        .IgnoreCase = True
        .Pattern = "[^a-zA-Z0-9\u4e00-\u9fa5]"
    End With
    If xRegExp.test(xSubject) = False Then Exit Sub
    xSubject = xRegExp.Replace(xSubject, "-")
    xMailItem.Subject = GetTargetStr(xSubject)
    Set RegExp = Nothing
End Sub
Function GetTargetStr(Str As String)
    Dim xS, xStr As String
    Dim i As Integer
    Dim xIsFirst As Boolean
    xIsFirst = True
    xStr = ""
    For i = 1 To Len(Str)
        xS = Mid(Str, i, 1)
        If xS = "-" Then
            If xIsFirst Then
                xS = " "
                xIsFirst = False
            Else
                xS = ""
            End If
        Else
            xIsFirst = True
        End If
        xStr = xStr + xS
    Next i
    GetTargetStr = xStr
End Function

3. Ainda na janela Microsoft Visual Basic for Applications, clique em Ferramentas > Referências para aceder à caixa de diálogo Referências - Project1 e marque a opção Microsoft VBAScript Regular Expressions 1,0 na lista Referências Disponíveis, conforme ilustrado na captura de ecrã:

4. Em seguida, clique em OK para fechar a caixa de diálogo. A partir de agora, sempre que enviar uma mensagem com caracteres especiais na linha de assunto, estes serão removidos automaticamente após o envio. Veja a captura de ecrã: