Como copiar pastas da estrutura de pastas do Outlook para o ambiente de trabalho (Explorador do Windows)?

Como sabe, podemos utilizar a funcionalidade **Arquivar** para copiar a estrutura de pastas do Outlook para outro perfil do Outlook, mas será que sabe como copiar essa mesma estrutura diretamente para uma pasta específica do Windows, como o Ambiente de Trabalho? Este artigo apresenta um código VBA que permite copiar facilmente as pastas da estrutura do Outlook para o Explorador do Windows.

Copiar pastas do Outlook Estrutura de Pasta para o ambiente de trabalho (Explorador do Windows)

---

Copiar pastas do Outlook Estrutura de Pasta para o ambiente de trabalho (Explorador do Windows)

Siga os passos abaixo para copiar pastas da Estrutura de Pastas do Outlook para o ambiente de trabalho ou para o Explorador do Windows.

1. No Navegador, clique para destacar a pasta específica cuja estrutura de pastas pretende copiar e prima as teclas «Alt» + "F11" para abrir a janela do Microsoft Visual Basic for Applications.

2. Clique em «Ferramentas» > «Referências» para abrir a caixa de diálogo Referências. Marque a opção «Microsoft Scripting Runtime» e clique em «OK». Veja a imagem:

3. Clique em «Inserir» > «Módulo» e copie e cole o seguinte código VBA na nova janela do módulo.

VBA: Copiar pastas do Outlook Estrutura de Pasta para o Explorador do Windows

Dim xFSO As Scripting.FileSystemObject
Sub CopyOutlookFldStructureToWinExplorer()
    ExportAction "Copy"
End Sub
  
Sub ExportAction(xAction As String)
Dim xFolder As Outlook.Folder
Dim xFldPath As String
xFldPath = SelectAFolder()
If xFldPath = "" Then
    MsgBox "You did not select a folder. Export cancelled.", vbInformation + vbOKOnly, "Kutools for Outlook"
Else
    Set xFSO = New Scripting.FileSystemObject
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    ExportOutlookFolder xFolder, xFldPath
End If
Set xFolder = Nothing
Set xFSO = Nothing
End Sub

Sub ExportOutlookFolder(ByVal OutlookFolder As Outlook.Folder, xFldPath As String)
Dim xSubFld As Outlook.Folder
Dim xItem As Object
Dim xPath As String
Dim xFilePath As String
Dim xSubject As String
Dim xCount As Integer
Dim xFilename As String
On Error Resume Next
xPath = xFldPath & "\" & OutlookFolder.Name
'?????????,??????
If Dir(xPath, 16) = Empty Then MkDir xPath
For Each xItem In OutlookFolder.Items
    xSubject = ReplaceInvalidCharacters(xItem.Subject)
    xFilename = xSubject & ".msg"
    xCount = 0
    xFilePath = xPath & "\" & xFilename
    If xFSO.FileExists(xFilePath) Then
        xCount = xCount + 1
        xFilename = xSubject & " (" & xCount & ").msg"
        xFilePath = xPath & "\" & xFilename
    End If
    xItem.SaveAs xFilePath, olMSG
Next
For Each xSubFld In OutlookFolder.Folders
    ExportOutlookFolder xSubFld, xPath
Next
Set OutlookFolder = Nothing
Set xItem = Nothing
End Sub

Function SelectAFolder() As String
Dim xSelFolder As Object
Dim xShell As Object
On Error Resume Next
Set xShell = CreateObject("Shell.Application")
Set xSelFolder = xShell.BrowseForFolder(0, "Select a folder", 0, 0)
If Not TypeName(xSelFolder) = "Nothing" Then
    SelectAFolder = xSelFolder.self.Path
End If
Set xSelFolder = Nothing
Set xShell = Nothing
End Function
  
Function ReplaceInvalidCharacters(Str As String) As String
Dim xRegEx
Set xRegEx = CreateObject("vbscript.regexp")
xRegEx.Global = True
xRegEx.IgnoreCase = False
xRegEx.Pattern = "\||\/|\<|\>|""|:|\*|\\|\?"
ReplaceInvalidCharacters = xRegEx.Replace(Str, "")
End Function

4. Prima a tecla "F5" ou clique no botão «Executar» para rodar este código VBA.

5. Na caixa de diálogo «Procurar Pasta» que surge, selecione a pasta específica onde deseja colocar a estrutura de pastas copiada e clique no botão «OK». Veja a imagem:

Agora, aceda à pasta especificada e verá que a estrutura de pastas foi copiada para o disco rígido indicado. Veja a imagem:

Nota: os itens da pasta, como mensagens de correio eletrónico, compromissos, tarefas, entre outros, também são copiados para as respetivas pastas no disco rígido.

---

Artigos Relacionados

Como copiar a estrutura de pastas para um novo ficheiro de dados PST no Outlook?