Como inserir todos os nomes dos destinatários diretamente no corpo do e-mail no Outlook?

Por vezes, poderá precisar de inserir os nomes de todos os destinatários diretamente no corpo da mensagem ao compor um e-mail no Outlook. É claro que pode copiar e colar os nomes um a um — mas imagine ter de repetir esse processo dezenas de vezes! Torna-se rapidamente uma tarefa cansativa. Neste artigo, mostro-lhe uma forma simples e eficaz de resolver este desafio no Outlook.

Inserir todos os nomes dos destinatários no corpo do e-mail com código VBA no Outlook

---

Inserir todos os nomes dos destinatários no corpo do e-mail com código VBA no Outlook

O seguinte código VBA permite inserir todos os nomes dos destinatários do campo «Para» diretamente no corpo da mensagem. Siga estes passos:

1. Inicie o Outlook e, em seguida, mantenha premidas as teclas ALT + F11 para abrir a janela do Microsoft Visual Basic for Applications.

2. Clique em Inserir > Módulo e cole o seguinte código na janela do Módulo.

Código VBA: Inserir nomes dos destinatários no corpo da mensagem:

Sub InsertRecipientNamesToBody()
Dim xMailItem As Outlook.MailItem
Dim xRecipient As Outlook.Recipient
Dim xRecipAddress, xRecipNames, xRecipName, xFilterAddr As String
Dim xItems As Outlook.Items
Dim i As Integer
Dim xFoundContact As Outlook.ContactItem
Dim xDoc As Word.Document
On Error Resume Next
Set xMailItem = Outlook.ActiveInspector.CurrentItem
xMailItem.Recipients.ResolveAll
For Each xRecipient In xMailItem.Recipients
    xRecipAddress = xRecipient.Address
    Set xItems = Application.Session.GetDefaultFolder(olFolderContacts).Items
    For i = 1 To 3
        xFilterAddr = "[Email" & i & "Address] = " & xRecipAddress
        Set xFoundContact = xItems.Find(xFilterAddr)
        If Not (xFoundContact Is Nothing) Then
           xRecipNames = xRecipNames & xFoundContact.FullName & Chr(10)
           Exit For
        End If
    Next
    If (xFoundContact Is Nothing) Then
       xRecipName = Split(xRecipAddress, "@")(0)
       xRecipNames = xRecipNames & xRecipName & Chr(10)
    End If
Next
Set xDoc = xMailItem.GetInspector.WordEditor
xDoc.Content.InsertAfter xRecipNames
Set xMailItem = Nothing
Set xRecipient = Nothing
Set xItems = Nothing
Set xFoundContact = Nothing
End Sub

3. Ainda na janela do Microsoft Visual Basic for Applications, clique em Ferramentas > Referências para aceder à caixa de diálogo Referências – Projecto1 e marque a opção Microsoft Word Object Library na lista de Referências Disponíveis, conforme ilustrado na imagem:

4. Em seguida, clique em OK para fechar a caixa de diálogo. Agora, deverá adicionar este código à Barra de Ferramentas de Acesso Rápido.

5. Crie uma nova mensagem clicando em Novo Email. Na janela da Mensagem, clique no ícone Personalizar Barra de Ferramentas de Acesso Rápido e selecione Mais Comandos, conforme ilustrado na imagem:

6. Na caixa de diálogo Opções do Outlook:

(1.) Selecione Macrosna lista pendente Escolher comandos a partir de;

(2.) Em seguida, escolha o nome da macro VBA que acabou de inserir;

(3.) Clique no botão Adicionar para incluir a macro na lista da Personalizar Barra de Ferramentas de Acesso Rápido.

7. Assim, um ícone da macro será exibido na Barra de Ferramentas de Acesso Rápido, conforme ilustrado na imagem seguinte:

8. Agora, ao clicar no ícone da macro, os nomes dos destinatários do campo Para são inseridos no corpo da mensagem, conforme ilustrado na imagem seguinte: