Como salvar mensagem de e-mail como formato de imagem (jpg / tiff) no Outlook?

Você já tentou salvar uma mensagem de e-mail como uma imagem, como jpg ou tiff no Outlook? Este artigo mostrará um método para resolver esse problema.

Salve a mensagem de e-mail como formato de imagem com código VBA

Salve a mensagem de e-mail como formato de imagem com código VBA

Faça o seguinte para salvar uma mensagem de e-mail como formato de imagem no Outlook.

1. Selecione um e-mail que você salvará como imagem e pressione o botão outro + F11 simultaneamente para abrir o Microsoft Visual Basic para Aplicações janela.

2. No Microsoft Visual Basic para Aplicações janela, por favor clique inserção > UserForm. Veja a imagem:

3. Crie um Formulário de usuário como a imagem abaixo mostrada.

4. Selecione a Opção jpg botão e mude seu nome para opbJPG no lado esquerdo Propriedades painel.

5. Repita a etapa 4 acima para renomear o outro botão de opções como opbTIFF. E renomear o OK botão de comando e o Cancelar botão de comando como cdbOk e cdbCancelar separadamente.

Note: Se o Propriedades painel não mostra no Microsoft Visual Basic para Aplicações janela, por favor clique no F4 para abrir o painel.

6. Clique duas vezes em qualquer espaço em branco no formulário do usuário para abrir o Code janela. Substitua todo o código pelo seguinte script VBA. E feche a janela de código.

Código VBA 1: Salvar mensagem de e-mail como imagem

Option Explicit
'Update by Extendoffice 2018/3/5
Public xRet As Boolean
Private Sub cdbCancel_Click()
  xRet = False
  FrmPicType.Hide
End Sub
Private Sub cdbOk_Click()
  xRet = True
  FrmPicType.Hide
End Sub

7. Selecione a UserForm1 e mude seu nome para FrmPicType no Propriedades painel como a imagem abaixo mostrada.

8. Clique inserção > Móduloe copie o código VBA abaixo para a janela Módulo.

Código VBA 2: Salvar mensagem de e-mail como imagem

Public Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
'Update by Extendoffice 2018/3/5
Sub ExportEmailAsImage()
Dim xMail As Outlook.MailItem
Dim xFileName, xFilePath, xWdDocPath As String
Dim xPPTApp As PowerPoint.Application
Dim xPresentation As PowerPoint.Presentation
Dim xPPTShape As PowerPoint.Shape
Dim xPicType As String
Dim xFileFormat As PpSaveAsFileType
On Error Resume Next
FrmPicType.Show
If FrmPicType.xRet Then
  If FrmPicType.opbJPG.Value = True Then
    xPicType = ".jpg"
    xFileFormat = ppSaveAsJPG
  ElseIf FrmPicType.opbTIFF.Value = True Then
    xPicType = ".tiff"
    xFileFormat = ppSaveAsTIF
  End If
Else
  Exit Sub
End If
Set xShell = CreateObject("Shell.Application")
Set xFolder = xShell.BrowseForFolder(0, "Select a folder:", 0, 0)
If Not TypeName(xFolder) = "Nothing" Then
    Set xFolderItem = xFolder.self
    xFilePath = xFolderItem.Path & "\"
Else
    xFilePath = ""
    Exit Sub
End If
'ShellExecute 0, "Open", "POWERPNT.exe", "", "", 0
Set xPPTApp = New PowerPoint.Application
xPPTApp.Height = 0
xPPTApp.Width = 0
xPPTApp.WindowState = ppWindowMinimized
xPPTApp.Visible = msoFalse
For Each xMail In Outlook.Application.ActiveExplorer.Selection
    xFileName = Replace(xMail.Subject, "/", " ")
    xFileName = Replace(xFileName, "\", " ")
    xFileName = Replace(xFileName, ":", "")
    xFileName = Replace(xFileName, "?", " ")
    xFileName = Replace(xFileName, Chr(34), " ")
    xWdDocPath = Environ("Temp") & "\" & xFileName & ".doc"
    xMail.SaveAs xWdDocPath, olDoc
    
    Set xPresentation = xPPTApp.Presentations.Add
    xPresentation.Application.WindowState = ppWindowMinimized
    xPresentation.Application.Visible = msoFalse
    With xPresentation
        .PageSetup.SlideHeight = 900 '792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
    xPPTApp.WindowState = ppWindowMinimized
    With xPresentation.Slides(1)
         .Application.Visible = msoFalse
         Set xPPTShape = .Shapes.AddOLEObject(0, 0, 612, 900, , xWdDocPath)
         xPresentation.SaveAs xFilePath & xFileName & xPicType, xFileFormat, msoTrue
    End With
    xPresentation.Close
Next
xPPTApp.Quit
MsgBox "Mails has been successfully saved as picture", vbInformation + vbOKOnly
End Sub

9. Clique Ferramentas > Referências, Verifica a Biblioteca de objetos do Microsoft PowerPoint caixa e, em seguida, clique no botão OK botão. Veja a imagem:

10. aperte o F5 chave para executar o código. Então o UserForm1 caixa de diálogo aparece, selecione um tipo de imagem e clique no botão OK botão. Veja a imagem:

11. No Procurar pasta caixa de diálogo, especifique uma pasta para salvar a imagem e clique no OK botão.

12. Finalmente, um Microsoft Outlook A caixa de diálogo será exibida para informá-lo sobre a conclusão do salvamento. Por favor clique no OK botão.