Como localizar uma pasta (com o caminho completo do arquivo) pelo nome da pasta no Outlook?

Siga os passos abaixo para pesquisar pastas pelo nome da pasta com VBA no Outlook.

1. Prima simultaneamente as teclas «Alt» + "F11" para abrir a janela do Microsoft Visual Basic for Applications.

2. Clique em «Inserir» > «Módulo» e cole o seguinte código VBA na nova janela do Módulo.

VBA: Pesquisar e Abrir Pasta por Nome da Pasta no Outlook

Private m_Folder As MAPIFolder
Private m_Find As String
Private m_Wildcard As Boolean

Private Const SpeedUp As Boolean = True
Private Const StopAtFirstMatch As Boolean = True

Public Sub FindFolder()
Dim sName As String
Dim oFolders As Folders

  Set m_Folder = Nothing
m_Find = ""
m_Wildcard = False

  sName = InputBox("Find:", "Search folder")
If Len(Trim(sName)) = 0 Then Exit Sub
m_Find = sName

  m_Find = LCase(m_Find)
m_Find = Replace(m_Find, "%", "*")
m_Wildcard = (InStr(m_Find, "*"))

  Set oFolders = Application.Session.Folders
LoopFolders oFolders

  If Not m_Folder Is Nothing Then
If MsgBox("Activate folder: " & vbCrLf & m_Folder.FolderPath, vbQuestion Or vbYesNo) = vbYes Then
Set Application.ActiveExplorer.CurrentFolder = m_Folder
End If
Else
MsgBox "Not found", vbInformation
End If
End Sub

Private Sub LoopFolders(Folders As Outlook.Folders)
Dim oFolder As MAPIFolder
Dim bFound As Boolean

If SpeedUp = False Then DoEvents

  For Each oFolder In Folders
If m_Wildcard Then
bFound = (LCase(oFolder.Name) Like m_Find)
Else
bFound = (LCase(oFolder.Name) = m_Find)
End If

    If bFound Then
If StopAtFirstMatch = False Then
If MsgBox("Found: " & vbCrLf & oFolder.FolderPath & vbCrLf & vbCrLf & "Continue?", vbQuestion Or vbYesNo) = vbYes Then
bFound = False
End If
End If
End If
If bFound Then
Set m_Folder = oFolder
Exit For
Else
LoopFolders oFolder.Folders
If Not m_Folder Is Nothing Then Exit For
End If
Next
End Sub

3. Prima a tecla "F5" ou clique no botão «Executar» para rodar este código VBA.

4. Na caixa de diálogo «Pesquisar pasta» que surge, introduza o nome da pasta específica que pretende encontrar e clique no botão «OK».

Nota: Este código VBA suporta o caráter universal asterisco (*). Por exemplo, pode escrever tes* para localizar todas as pastas cujo nome comece por «tes».

5. Surge agora uma caixa de diálogo com o Caminho do Arquivo da pasta encontrada. Caso deseje abrir essa pasta, clique no botão «Sim».

E agora a pasta encontrada está a ser aberta no Navegação, conforme ilustrado na captura de ecrã seguinte:

Nota: Se existirem várias pastas com o nome especificado, este código VBA apenas conseguirá encontrar e abrir uma delas.

Se tiver o «Kutools para Outlook» instalado, pode usar a funcionalidade «Ir Para» para localizar rapidamente todas as pastas com um determinado nome e abrir facilmente qualquer uma das pastas encontradas.

1. Clique em «KUTOOLS PLUS» > «Ir Para» para ativar esta funcionalidade.

2. Na caixa de diálogo «Ir Para», introduza o nome da pasta pretendida na caixa «Pesquisar», selecione «Selecionar uma pasta» nos resultados da pesquisa e clique no botão «OK».

Agora, a pasta especificada com o nome indicado é localizada e aberta imediatamente.