Como obter uma lista de pastas no Outlook?

Por vezes, a estrutura em árvore de todas as pastas de correio — incluindo as pastas pessoais que criou — pode revelar-se extremamente útil para os utilizadores do Outlook no seu dia a dia. Com um simples código VBA, é possível listar rapidamente toda essa estrutura hierárquica. Neste tutorial, vai aprender como obter facilmente uma lista completa das suas pastas recorrendo a VBA.

Obter lista de pastas no Outlook com código VBA

---

Obter lista de pastas no Outlook com código VBA

Para obter uma lista de pastas no Outlook com código VBA, siga estes passos.

1. Prima as teclas «Alt» + "F11" no seu teclado para abrir a janela do Microsoft Visual Basic for Applications.

2. Em seguida, clique duas vezes em "Project1" > «Microsoft Outlook Object» > «ThisOutlookSession» para abrir a janela «Project1 – ThisOutlookSession». Veja a captura de ecrã:

3. Depois, copie e cole o código VBA abaixo na janela «Project1 – ThisOutlookSession».

VBA: obter lista de pastas no Outlook

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4. Prima a tecla "F5" no seu teclado para executar o código VBA.

5. Agora, surge uma caixa de diálogo «Macro»; clique no botão «Executar».

6. Aguarde a execução da macro. Em seguida, a lista de todas as suas pastas de correio é apresentada imediatamente numa nova janela de mensagem criada, pronta para ser impressa com facilidade. Veja a captura de ecrã:

Nota: Este código VBA é compatível com o Outlook 2007, 2010 e 2013.