Como desativar ou desligar o aviso de assunto em branco no Outlook?

Ao utilizar o Outlook 2010 e 2013, sempre que enviar mensagens de correio eletrónico sem assunto, uma caixa de aviso “sem assunto” aparece como lembrete. Caso não pretenda mesmo incluir um assunto, este aviso pode tornar-se bastante incómodo. Para ajudar os utilizadores do Outlook a eliminarem este alerta, apresentamos uma solução no tutorial seguinte.

Desativar ou desligar o aviso de assunto em branco no Outlook

---

Desativar ou desligar o aviso de assunto em branco no Outlook

No Outlook 2007, não existe qualquer aviso ao enviar uma mensagem de correio eletrónico sem assunto. Esta funcionalidade está ativada no Outlook 2010 e 2013. Contudo, não há uma opção direta para desativar este alerta de assunto em branco. Neste tutorial, mostramos-lhe um código VBA para alcançar este objetivo.

1. Prima as teclas «Alt» + "F11" para abrir a caixa de diálogo «Microsoft Visual Basic for Applications».

2. Expanda "Project1" > «Microsoft Outlook Objects» clicando duas vezes em cada um. Em seguida, clique duas vezes em «ThisOutlookSession» para abrir a janela «VbaProject.OTM».

3. Copie e cole o código VBA abaixo na janela.

VBA: Desativar ou desligar o aviso de assunto em branco

Option Explicit
Private WithEvents oInspectors As Outlook.Inspectors

Private Sub Application_Startup()
    Set oInspectors = Outlook.Inspectors
End Sub

Private Sub oInspectors_NewInspector(ByVal Inspector As Inspector)
    Dim oItem As Object
    On Error GoTo ExitProc
    Set oItem = Inspector.CurrentItem
    If oItem.Sent = False Then
        If oItem.Subject = "" Then oItem.Subject = " "
    End If
ExitProc:
    Set oItem = Nothing
    Set Inspector = Nothing
End Sub

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    On Error Resume Next
    Item.Subject = Trim(Item.Subject)
End Sub

Private Sub Application_Quit()
    Set oInspectors = Nothing
End Sub

4. Clique no botão «Guardar» para salvar o código VBA.

5. Reinicie a aplicação Outlook.

O código VBA entrará então em vigor: ao enviar uma mensagem sem assunto, a caixa de aviso «sem assunto» já não será apresentada.

Nota: Certifique-se de que a opção «Ativar todas as macros» está selecionada. Para o verificar, aceda a «Ficheiro» > «Opções» > «Centro de Confiança» > «Definições do Centro de Confiança», e, na caixa de diálogo «Centro de Confiança», selecione «Definições de Macros» > «Ativar todas as macros». Veja a captura de ecrã: