Criar várias pastas e subpastas a partir de uma lista de dados no Excel

Suponha que você tenha uma lista de nomes de funcionários em um intervalo de células de uma planilha e deseja criar pastas individuais para cada um, a fim de armazenar suas informações. Criar cada pasta manualmente pode ser demorado. No entanto, existem métodos eficientes para acelerar esse processo. Neste guia, compartilharei várias abordagens para gerar rapidamente pastas com base nos valores das células especificadas.

Criar pastas com base nos valores das células

• Usando o comando MD e o Bloco de Notas
• Usando um recurso poderoso – Kutools para Excel
• Usando código VBA

Criar pastas e subpastas com base nos valores das células com código VBA

Criar pastas com base nos valores das células

Nesta seção, exploraremos vários métodos em detalhes, oferecendo instruções passo a passo abrangentes para criar rapidamente e sem esforço pastas com base em uma lista de valores de células.

Criar pastas a partir de uma lista usando o comando MD e o Bloco de Notas

Transformar uma lista do Excel em pastas usando o comando MD e o Bloco de Notas é um truque inteligente que combina scripts em lote simples com a habilidade do Excel de manter as coisas organizadas. Esse método é excelente para criar muitas pastas rapidamente, sem precisar fazer tudo manualmente. Aqui está um guia passo a passo para realizar essa tarefa:

Passo 1: Use o comando MD para criar fórmulas

Copie ou insira a seguinte fórmula em uma célula em branco ao lado do seu primeiro valor de célula (B1, por exemplo), e depois arraste a alça de preenchimento para baixo para aplicar a fórmula a todos os itens da sua lista.

="MD "&A1

Passo 2: Copie e cole as fórmulas em um arquivo do Bloco de Notas

1. Pressione "Ctrl + C" para copiar as células com a fórmula do comando MD.
2. Abra o Bloco de Notas e pressione "Ctrl + V" para colar os comandos em um novo arquivo.
   

Passo 3: Salve o arquivo do Bloco de Notas como um arquivo .bat

Clique em "Salvar como" na aba "Arquivo" no Bloco de Notas, na caixa de diálogo "Salvar como", escolha um diretório onde deseja criar várias pastas e dê um nome para este arquivo com a extensão .bat. Finalmente, clique no botão "Salvar". Veja a captura de tela:

Passo 4: Dê um duplo clique no arquivo .bat para gerar várias pastas

1. Feche o arquivo do Bloco de Notas, navegue até a pasta onde você salvou anteriormente o arquivo .bat.
2. Agora, veja a mágica: dê um duplo clique no arquivo e você verá várias pastas sendo criadas de uma só vez. Veja a demonstração abaixo:
   

Criar pastas a partir de uma lista usando uma ferramenta poderosa – Kutools para Excel

Com o poderoso recurso "Criar Pastas com Base no Intervalo" do Kutools para Excel, agora você pode criar facilmente e rapidamente pastas a partir de uma lista do Excel. Mas isso não para em pastas básicas; o Kutools também permite criar estruturas complexas com várias subpastas de nível em uma única operação. Apenas alguns passos simples podem transformar dados do Excel em um sistema de pastas organizado, aumentando significativamente sua produtividade.

Após instalar o Kutools para Excel, clique em "Kutools Plus" > "Importar / Exportar" > "Criar Pastas com Base no Intervalo" para abrir a caixa de diálogo Criar Pastas com Base no Intervalo:

1. Selecione os valores das células que deseja usar para criar pastas;
2. Então, clique no botão para especificar a pasta de destino onde deseja salvar as pastas;
3. Finalmente, clique no botão OK.
   

Resultado:

O Kutools processará a lista da sua planilha e criará uma pasta para cada entrada no destino especificado. Navegue até a pasta de destino para ver o resultado. Veja a captura de tela:

Criar pastas a partir de uma lista usando código VBA

Usar código VBA no Excel pode transformar a tarefa tediosa de criar pastas a partir de uma lista em um processo rápido e automatizado. Esta seção mostrará como aplicar o código VBA para gerar pastas.

Passo 1: Abra o editor de módulo VBA e copie o código

1. Mantenha pressionadas as teclas "ALT + F11" no Excel, e isso abrirá a janela "Microsoft Visual Basic for Applications".
2. Clique em "Inserir" > "Módulo", e cole o seguinte código na Janela do Módulo.
   Código VBA: Criar pastas com base em uma lista de valores de células

   Sub CreateFoldersFromSelection()
   'Updateby Extendoffice
       Dim FolderPath As String
       Dim Cell As Range
       Dim SelectedRange As Range
       Dim FolderName As String
       On Error Resume Next
       Set SelectedRange = Application.InputBox("Select the range with folder names", "Kutools for Excel", Type:=8)
       If SelectedRange Is Nothing Then Exit Sub
       On Error GoTo 0
       
       With Application.FileDialog(msoFileDialogFolderPicker)
           .Title = "Select the destination Folder"
           .AllowMultiSelect = False
           If .Show <> -1 Then Exit Sub
           FolderPath = .SelectedItems(1) & "\"
       End With
       
       For Each Cell In SelectedRange
           FolderName = FolderPath & Cell.Value
           If Cell.Value <> "" And Not FolderExists(FolderName) Then
               MkDir FolderName
           End If
       Next Cell
   End Sub
   
   Function FolderExists(ByVal Path As String) As Boolean
       On Error Resume Next
       FolderExists = (GetAttr(Path) And vbDirectory) = vbDirectory
       On Error GoTo 0
   End Function
   

Passo 2: Execute o código

1. Após colar este código, pressione a tecla F5 para executar este código. Na caixa de prompt, selecione os valores das células dos quais deseja criar pastas. E então, clique em OK.
   
2. Em seguida, na janela "Selecionar a Pasta de Destino" que aparece, especifique o caminho de destino para saída das pastas criadas. E então, clique no botão OK, veja a captura de tela:
   

Resultado:

Após executar o código VBA, vá até o diretório de destino para visualizar o resultado. Lá, você encontrará as pastas recém-criadas, cada uma correspondendo a um item da sua lista do Excel. Veja a captura de tela:

Criar pastas e subpastas com base nos valores das células com código VBA

Ocasionalmente, você pode se encontrar em uma situação onde precisa gerar não apenas pastas, mas também suas respectivas subpastas, todas com base nos dados dentro das células do Excel. Para alcançar essa tarefa, aqui eu apresentarei um código VBA.

Passo 1: Prepare os dados

Primeiro, você deve inserir os dados conforme mostrado na captura de tela a seguir, colocando os nomes das pastas principais na primeira coluna e os nomes das subpastas na segunda coluna.

Passo 2: Abra o editor de módulo VBA e copie o código

1. Mantenha pressionadas as teclas "ALT + F11" no Excel, e isso abrirá a janela "Microsoft Visual Basic for Applications".
2. Clique em "Inserir" > "Módulo", e cole o seguinte código na Janela do Módulo.
   Código VBA: Criar pastas e subpastas com base nos valores das células

   Sub CreateFoldersAndSubfoldersWithUserInput()
   'Updateby Extendoffice
       Dim Rng As Range
       Dim Cell As Range
       Dim basePath As String
       Dim fldrPicker As FileDialog
       Dim FolderPath As String, subfolderPath As String
       On Error Resume Next
       Set Rng = Application.InputBox("Select the range of cells (two columns: one is folder column, another s subfolder column):", "Kutools for Excel", Type:=8)
       If Rng Is Nothing Then Exit Sub
       On Error GoTo 0
       Set fldrPicker = Application.FileDialog(msoFileDialogFolderPicker)
       With fldrPicker
           .Title = "Select the Base Folder Path"
           .AllowMultiSelect = False
           If .Show <> -1 Then Exit Sub
           basePath = .SelectedItems(1)
       End With
       If Right(basePath, 1) <> "\" Then basePath = basePath & "\"
       For Each Cell In Rng.Columns(1).Cells
           If Not Cell.Value = "" Then
               FolderPath = basePath & Cell.Value
               If Not FolderExists(FolderPath) Then MkDir FolderPath
               If Not Cell.Offset(0, 1).Value = "" Then
                   subfolderPath = FolderPath & "\" & Cell.Offset(0, 1).Value
                   If Not FolderExists(subfolderPath) Then MkDir subfolderPath
               End If
           End If
       Next Cell
   End Sub
   
   Function FolderExists(FolderPath As String) As Boolean
       On Error Resume Next
       FolderExists = (GetAttr(FolderPath) And vbDirectory) = vbDirectory
       On Error GoTo 0
   End Function
   

Passo 3: Execute o código

1. Após colar este código, pressione a tecla F5 para executar este código. Na caixa de prompt, selecione os valores das células dos quais deseja criar pastas. E então, clique em OK.
   
2. Na janela pop-up que aparece, especifique o caminho de destino para saída das pastas criadas. E então, clique no botão OK, veja a captura de tela:
   

Resultado:

Após executar o código VBA, vá até o diretório de destino para visualizar o resultado. Você verá que as pastas e suas respectivas subpastas, conforme ditado pelos valores das células, foram criadas com sucesso, como mostrado na captura de tela a seguir:

Artigos Relacionados: