No Excel, embora a função SE seja essencial para testes lógicos básicos, condições complexas geralmente exigem instruções IF aninhadas para processamento aprimorado de dados. Neste guia abrangente, abordaremos detalhadamente os fundamentos do IF aninhado, desde a sintaxe até aplicações práticas, incluindo combinações de IF aninhado com condições AND/OR. Além disso, compartilharemos como melhorar a legibilidade de funções IF aninhadas, bem como algumas dicas sobre IF aninhados e exploraremos alternativas poderosas, como VLOOKUP, IFS e muito mais, para tornar operações lógicas complexas mais fáceis de usar e mais eficientes.

• Sintaxe de IF aninhado
• Exemplos práticos de IF aninhados
• Aninhado se com condição AND/OR

• Tornando o IF aninhado fácil de ler
• A ordem das funções IF aninhadas
• Números e texto devem ser tratados de forma diferente
• Limitações do IF aninhado

• Usando PROCV
• Usando IFS
• Usando ESCOLHER e COMBINAR

Função IF do Excel vs. instruções IF aninhadas

A função IF e as instruções IF aninhadas no Excel servem a propósitos semelhantes, mas diferem significativamente em sua complexidade e aplicação.

Uso de IF aninhado

Esta seção demonstra o uso básico de instruções IF aninhadas no Excel, incluindo sintaxe, exemplos práticos e como usá-las com condições AND ou OR.

Sintaxe de IF aninhado

Compreender a sintaxe de uma função é a base para sua aplicação correta e eficaz no Excel. Vamos começar com a sintaxe das instruções if aninhadas.

Sintaxe:

=IF(condition1, result1, IF(condition2, result2, IF(condition3, result3, result4)))

Argumentos:

• Condition1, Condition2, Condition3: These are the conditions you want to test. Each condition is evaluated in order, starting with Condition1.
• Result1: This is the value returned if Condition1 is TRUE.
• Result2: This value is returned if Condition1 is FALSE and Condition2 is TRUE. It's important to note that Result2 is only evaluated if Condition1 is FALSE.
• Result3: This value is returned if both Condition1 and Condition2 are FALSE, and Condition3 is TRUE. Essentially, for Result3 to be evaluated, the previous conditions (Condition1 and Condition2) must both be FALSE.
• Result4: This result is returned if all the conditions (Condition1, Condition2, and Condition3) are FALSE.
  
  In short, this expression can be interpreted as follows:
  Test condition1, if TRUE, return result1, if FALSE,
  test condition2, if TRUE, return result2, if FALSE,
  test condition3, if TRUE, return result3, if FALSE,
  return result4

Lembre-se, em uma estrutura IF aninhada, cada condição subsequente só será avaliada se todas as condições anteriores forem FALSAS. Essa verificação sequencial é crítica para entender como funcionam os IFs aninhados.

Exemplos práticos de IF aninhados

Agora, vamos mergulhar no uso do IF aninhado com dois exemplos práticos.

Exemplo 1: Sistema de Classificação

Conforme mostrado na captura de tela abaixo, suponha que você tenha uma lista de notas dos alunos e queira atribuir notas com base nessas notas. Você pode usar IF aninhado para realizar esta tarefa.

Selecione uma célula em branco (C2 neste caso), insira a seguinte fórmula e pressione Entrar para obter o resultado. Em seguida, arraste o Pega de enchimento para baixo para obter o resto dos resultados.

=IF(B2>=90,$F$2,IF(B2>=80,$F$3,IF(B2>=70,$F$4,IF(B2>=60,$F$5,$F$6))))

Exemplo 2: Cálculo da Comissão de Vendas

Imagine um cenário em que os representantes de vendas recebam taxas de comissão diferentes com base em suas conquistas de vendas. Conforme mostrado na captura de tela abaixo, você deseja calcular a comissão de um vendedor com base nesses diferentes limites de vendas, e as declarações IF aninhadas podem ajudá-lo com isso.

Selecione uma célula em branco (C2 neste caso), insira a seguinte fórmula e pressione Entrar para obter o resultado. Em seguida, arraste o Pega de enchimento para baixo para obter o resto dos resultados.

=B2*IF(B2>20000,$F$2,IF(B2>=10000,$F$3,$F$4))

Aninhado se com condição AND/OR

Nesta seção, modifico o primeiro exemplo acima "o sistema de classificação" para demonstrar como combinar a condição IF aninhada com AND ou OR no Excel. No exemplo de classificação revisado, introduzi uma condição adicional baseada na “Taxa de frequência”.

Usando if aninhado com condição AND

Se um aluno atender aos critérios de pontuação e frequência, ele receberá um aumento de nota. Por exemplo, um aluno cuja pontuação seja 60 ou superior e cuja taxa de frequência seja 95% ou superior terá sua nota elevada em um nível, como de A para A+, B para B+ e assim por diante. No entanto, se a taxa de frequência for inferior a 95%, a classificação seguirá os critérios originais baseados na pontuação. Nesses casos, precisamos usar uma instrução IF aninhada com uma condição AND.

Selecione uma célula em branco (D2 neste caso), insira a seguinte fórmula e pressione Entrar para obter o resultado. Em seguida, arraste o Pega de enchimento para baixo para obter o resto dos resultados.

=IF(AND(B2>=60, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

Usando if aninhado com condição OR

Neste caso, a nota do aluno será elevada um nível se a sua pontuação for igual ou superior a 95, ou se a sua taxa de frequência for igual ou superior a 95%. Veja como podemos fazer isso usando condições IF e OR aninhadas.

Selecione uma célula em branco (D2 neste caso), insira a seguinte fórmula e pressione Entrar para obter o resultado. Em seguida, arraste o Pega de enchimento para baixo para obter o resto dos resultados.

=IF(OR(B2>=95, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+")))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

Dicas e truques para IF aninhado

Esta seção cobre quatro dicas e truques úteis para IF aninhados.

Tornando o IF aninhado fácil de ler

Uma instrução IF aninhada típica pode parecer compacta, mas pode ser difícil de decifrar.

Na fórmula a seguir, é um desafio identificar rapidamente onde termina uma condição e começa outra, especialmente à medida que a complexidade aumenta.

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

Solução: Adicionando Quebras de Linha e Recuo

Para facilitar a leitura do IF aninhado, você pode dividir a fórmula em várias linhas, com cada IF aninhado em uma nova linha. Na fórmula, basta colocar o cursor antes do SE e pressionar as teclas Alt + Enter.

Depois de quebrar a fórmula acima, ela será mostrada da seguinte forma:

=IF(A2>=90, "A",
      IF(A2>=80, "B",
          IF(A2>=70, "C",
              IF(A2>=60, "D", "F")))
)

Este formato deixa mais claro onde está cada condição e a saída correspondente, melhorando a legibilidade da fórmula.

A ordem das funções IF aninhadas

A ordem das condições lógicas em uma fórmula IF aninhada é crucial porque determina como o Excel avalia essas condições e, portanto, afeta o resultado final da fórmula.

Fórmula correta

No exemplo do Sistema de notas, usamos a seguinte fórmula para atribuir notas com base nas pontuações.

=IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))))

O Excel avalia as condições em uma fórmula IF aninhada sequencialmente, da primeira à última condição. Esta fórmula verifica primeiro o limite de pontuação mais alto (>=90 para um "A") e depois passa para os limites mais baixos. Ele garante que uma pontuação seja comparada com a nota mais alta para a qual se qualifica. Se a primeira condição for verdadeira (A2>=90), retorna "A" e não avalia nenhuma outra condição.

Fórmula ordenada incorreta

Se a ordem das condições fosse invertida, começando com o limite mais baixo, retornaria resultados incorretos.

=IF(B2>=60, "D", IF(B2>=70, "C", IF(B2>=80, "B", IF(B2>=90, "A", "F"))))

Nesta fórmula incorreta, uma pontuação de 95 atenderia imediatamente à primeira condição B2>=60 e receberia incorretamente a nota “D”.

Números e texto devem ser tratados de forma diferente

Esta seção mostrará como números e texto são tratados de maneira diferente em instruções IF aninhadas.

Números

Os números são usados ​​para comparações e cálculos aritméticos. Em instruções IF aninhadas, você pode comparar números diretamente usando operadores como >, <, =, >= e <=.

Texto

Em instruções IF aninhadas, o texto deve ser entre aspas duplas. Veja A, B, C, D e F na seguinte fórmula:

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

Limitações do IF aninhado

Esta seção lista diversas limitações e desvantagens do IF aninhado.

Complexidade e legibilidade:

Embora o Excel permita aninhar até 64 funções IF diferentes, não é aconselhável fazê-lo. Quanto mais níveis de aninhamento, mais complexa se torna a fórmula. Isso pode levar a fórmulas difíceis de ler, compreender e manter.

Propenso a erros:

Além disso, instruções IF aninhadas complexas podem tornar-se propensas a erros e difíceis de depurar ou modificar.

Difícil de estender ou dimensionar:

Se sua lógica mudar ou você precisar adicionar mais condições, IFs profundamente aninhados poderão ser difíceis de modificar ou estender.

Compreender essas limitações é fundamental para usar instruções IF aninhadas de maneira eficaz no Excel. Freqüentemente, combinar IFs aninhados com outras funções ou buscar abordagens alternativas pode levar a soluções mais eficientes e sustentáveis.

Alternativas para IF aninhado

Esta seção lista várias funções do Excel que podem ser usadas como alternativas às instruções IF aninhadas.

Usando PROCV

Você pode usar a função VLOOKUP em vez de instruções IF aninhadas para realizar os dois exemplos práticos acima. Veja como você pode fazer isso:

Exemplo 1: Sistema de notas com VLOOKUP

Aqui vou mostrar como usar VLOOKUP para atribuir notas com base nas pontuações.

Etapa 1: crie uma tabela de pesquisa para notas

Primeiramente, você precisa criar uma tabela de consulta (como E1:F6 neste caso) para a faixa de pontuação e as notas correspondentes. Note: As pontuações na primeira coluna da tabela devem ser ordenadas em ordem crescente.

Etapa 2: aplique a função VLOOKUP para atribuir notas

Selecione uma célula em branco (C2 neste caso), insira a seguinte fórmula e pressione o botão Entrar chave para obter a primeira série. Selecione esta célula de fórmula e arraste-a Pega de enchimento para baixo para obter o resto das notas.

=VLOOKUP(B2,$E$2:$F$6,2,TRUE)

Exemplo 2: Cálculo de Comissão de Vendas com VLOOKUP

Você também pode usar PROCV para realizar o cálculo da comissão de vendas no Excel. Por favor, faça o seguinte.

Etapa 1: crie uma tabela de pesquisa para notas

Primeiramente, você precisa criar uma tabela de consulta para as vendas e a taxa de comissão correspondente, como E2:F4 neste caso. Note: As vendas na primeira coluna da tabela devem ser ordenadas em ordem crescente.

Etapa 2: aplique a função VLOOKUP para atribuir notas

Selecione uma célula em branco (C2 neste caso), insira a seguinte fórmula e pressione a tecla Enter para obter a primeira comissão. Selecione esta célula de fórmula e arraste sua alça de preenchimento para baixo para obter o restante dos resultados.

=B2*VLOOKUP(B2,$E$2:$F$4,2,TRUE)

Usando IFS

A Função IFS simplifica o processo eliminando a necessidade de aninhamento e torna as fórmulas mais fáceis de ler e gerenciar. Ele melhora a legibilidade e simplifica o tratamento de múltiplas verificações condicionais. Para utilizar a função IFS, verifique se você está usando o Excel 2019 ou posterior ou se possui uma assinatura do Office 365. Vamos ver como isso pode ser aplicado em exemplos práticos.

Exemplo 1: Sistema de Classificação com IFS

Assumindo os mesmos critérios de classificação anteriores, a função IFS pode ser usada da seguinte forma:

Selecione uma célula em branco, como C2, insira a seguinte fórmula e pressione Entrar para obter o primeiro resultado. Selecione esta célula de resultado e arraste-a Pega de enchimento para baixo para obter o resto dos resultados.

=IFS(B2>=90,"A",B2>=80,"B",B2>=70,"C",B2>=60,"D",B2<60,"F")

Exemplo 2: Cálculo de Comissão de Vendas com IFS

Para o cenário de cálculo de comissão de vendas, a função IFS é aplicada da seguinte forma:

Selecione uma célula em branco, como C2, insira a seguinte fórmula e pressione Entrar para obter o primeiro resultado. Selecione esta célula de resultado e arraste-a Pega de enchimento para baixo para obter o resto dos resultados.

=B2*IFS(B2>20000,20%,B2>=10000,15%,TRUE,10%)

Usando ESCOLHER e COMBINAR

A abordagem CHOOSE e MATCH pode ser mais eficiente e fácil de gerenciar em comparação com instruções IF aninhadas. Este método simplifica a fórmula e torna as atualizações ou alterações mais diretas. A seguir demonstrarei como usar uma combinação das funções CHOOSE e MATCH para lidar com os dois exemplos práticos deste artigo.

Exemplo 1: Sistema de classificação com CHOOSE e MATCH

Você pode usar a combinação das funções CHOOSE e MATCH para atribuir notas com base em pontuações diferentes.

Etapa 1: crie uma matriz de pesquisa com valores de pesquisa

Em primeiro lugar, você precisa criar um intervalo de células contendo os valores limite que MATCH irá pesquisar, como $E$2:$E$6 neste caso. Note: Os números neste intervalo devem ser classificados em ordem crescente para que a função MATCH funcione corretamente ao usar um tipo de correspondência aproximado.

Etapa 2: aplique CHOOSE e MATCH para atribuir notas

Selecione uma célula em branco (C2 neste caso), insira a seguinte fórmula e pressione o botão Entrar chave para obter a primeira série. Selecione esta célula de fórmula e arraste-a Pega de enchimento para baixo para obter o resto dos resultados.

=CHOOSE(MATCH(B2, $E$2:$E$6, 1), "F", "D", "C", "B", "A")

Exemplo 2: Cálculo de Comissão de Vendas com IFS

Usar a combinação CHOOSE e MATCH para um cálculo de comissão de vendas também pode ser eficaz, especialmente quando as taxas de comissão são baseadas em limites de vendas especificados. Vamos ver como podemos fazer.

Etapa 1: crie uma matriz de pesquisa com valores de pesquisa

Em primeiro lugar, você precisa criar um intervalo de células contendo os valores limite que MATCH irá pesquisar, como $E$2:$E$4 neste caso. Note: Os números neste intervalo devem ser classificados em ordem crescente para que a função MATCH funcione corretamente ao usar um tipo de correspondência aproximado.

Etapa 2: aplique CHOOSE e MATCH para obter os resultados

Selecione uma célula em branco (C2 neste caso), insira a seguinte fórmula e pressione o botão Entrar chave para obter a primeira série. Selecione esta célula de fórmula e arraste-a Pega de enchimento para baixo para obter o resto dos resultados.

=B2*CHOOSE(MATCH(B2, $E$2:$E$4, 1), 10%, 15%, 20%)

Concluindo, dominar as instruções IF aninhadas no Excel é uma habilidade valiosa que aprimora sua capacidade de lidar com cenários lógicos complexos em análise de dados e processos de tomada de decisão. Embora os IFs aninhados sejam poderosos para operações lógicas complexas, é importante estar atento às suas limitações. Alternativas mais simples como VLOOKUP, IFS e CHOOSE com MATCH podem fornecer soluções mais simplificadas em determinados cenários. Armado com esses insights, agora você pode aplicar com segurança as técnicas de Excel mais adequadas às suas tarefas de análise de dados, garantindo clareza, precisão e eficiência em suas planilhas. Para aqueles ansiosos por se aprofundar nos recursos do Excel, nosso site possui diversos tutoriais. Descubra mais dicas e truques do Excel aqui.

Artigos Relacionados