KutoolsforOffice — Uma solução, cinco ferramentas poderosas.Fazer mais com menos esforço.

Contar facilmente valores únicos e distintos – 7 exemplos

AutorXiaoyang Data de Modificação

Normalmente, no Excel, os valores únicos são aqueles que aparecem apenas uma vez numa lista, sem repetições, enquanto os valores distintos incluem todos os valores diferentes — ou seja, os valores únicos mais a primeira ocorrência de cada valor duplicado. Ao trabalhar com grandes conjuntos de dados, poderá precisar de contar o número de valores únicos e distintos num intervalo de células, tal como ilustrado na imagem abaixo. Este tutorial apresenta alguns truques rápidos para contar valores únicos e distintos no Excel.

Contar valores únicos ou valores distintos numa lista

Contar o número de valores únicos em um intervalo no Excel

Contagem única valores (únicos e primeira ocorrência de duplicados) no Excel

Transferir ficheiro de exemplo

Contar valores únicos distintos

Contar o número de valores únicos em um intervalo no Excel

Esta secção apresenta alguns exemplos de fórmulas para contar o número de valores únicos, incluindo a divisão por texto e número numa lista.

Contar o número de valores únicos em um intervalo com fórmulas

Suponhamos que tenho uma lista de nomes que contém alguns nomes duplicados. Agora, preciso obter apenas o número de nomes únicos (destacados a amarelo), tal como mostrado na imagem abaixo:

dados de exemplo

Para resolver este problema, a seguinte fórmula matricial pode ajudá-lo:

Passo 1: Introduza a fórmula

Introduza ou copie a fórmula abaixo para uma célula vazia onde pretende apresentar o resultado:

=SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))
Nota: Na fórmula acima, "A2:A12" é a lista de dados cujos valores únicos pretende contar.

Passo 2: Prima as teclas Ctrl + Shift + Enter para obter o resultado correto:

Contar valores únicos com fórmula

Notas:

  1. Se a sua lista de células contiver outros tipos de dados — como números, valores lógicos, valores de erro, entre outros —, ao aplicar a fórmula acima, obterá o número de valores únicos, independentemente do tipo de dado.
  2. Quando a lista de dados contém células vazias, esta fórmula exclui-as automaticamente.
  3. Para contar apenas os valores de texto únicos caso existam outros tipos de dados, aplique a seguinte fórmula matricial e, em seguida, prima as teclas «Ctrl» + «Shift» + «Enter» para obter o resultado:
    =SUM(IF(ISTEXT(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))
  4. Para contar apenas números únicos numa lista de células que contenha qualquer tipo de dado, utilize a seguinte fórmula matricial e, em seguida, prima as teclas «Ctrl» + «Shift» + «Enter» para obter o resultado:
    =SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

Contar o número de valores únicos em um intervalo com poucos cliques através de Kutools para Excel

Pode ser difícil lembrar-se das fórmulas quando precisar de as aplicar novamente. No entanto, com o  «Kutools para Excel» e a opção «Contar o número de valores únicos num intervalo», disponível no «Assistente de Fórmulas», obtém o resultado em apenas alguns cliques. Veja a demonstração abaixo:

  1. Clique numa célula para apresentar o resultado;
  2. Ative esta funcionalidade clicando em «Kutools» > «Assistente de Fórmulas» > «Assistente de Fórmulas» > «Estatísticas» > «Contar o número de valores únicos em um intervalo»;
  3. Selecione a lista de dados e clique em «OK».
    Contar valores únicos com Kutools
Dicas:
  1. Para utilizar esta funcionalidade, tem de transferir e instalar o Kutools para Excel.
  2. A funcionalidade «Assistente de Fórmulas» reúne as fórmulas mais utilizadas, como «Extrair valores únicos», «Extrair células com valores únicos de um intervalo (incluindo os primeiros duplicados)», «Contar o número de valores separados por vírgula numa célula», «Somar com base no mesmo texto» e muito mais...

Contar o número de valores únicos em um intervalo no Excel 365/2021 com fórmulas

Se estiver a utilizar o Excel 365 ou o Excel 2021, pode contar com a nova função UNIQUE para criar fórmulas mais simples e contar facilmente o número de valores únicos num intervalo do seu conjunto de dados.

Por exemplo, para contar o número de nomes únicos no intervalo A2:A12, introduza a seguinte fórmula：

Passo 1: Copie ou introduza a fórmula abaixo

=IFERROR(ROWS(UNIQUE(A2:A12,,TRUE)), 0)
Nota: Nesta fórmula, "A2:A12" é a lista de dados que pretende Contar o número de valores únicos em um intervalo.

Passo 2: Prima a tecla Enter para obter o resultado:

Contar valores únicos no Excel 365/2021 com fórmula

Dicas:

  1. Se a lista de dados incluir outros tipos de dados — como texto, números, valores lógicos, valores de erro, entre outros —, esta fórmula devolve o número de valores únicos, independentemente do tipo de dado.
  2. A fórmula acima conta o número de valores únicos num intervalo, incluindo células vazias. Se pretender excluí-las, aplique a fórmula abaixo e prima simplesmente a tecla «Enter»:
    =SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))

Contagem única valores (únicos e primeira ocorrência de duplicados) no Excel

Para contar os valores diferentes (valores únicos e a primeira ocorrência de duplicados) numa lista de células, apresento outras fórmulas para realizar esta tarefa.

Contagem única valores com fórmulas

No Excel, pode utilizar qualquer uma das fórmulas abaixo para obter o número de valores distintos.

Passo 1: Introduza qualquer uma das fórmulas abaixo

Fórmula 1: Após introduzir a fórmula, prima a tecla Enter.

=SUMPRODUCT(1/COUNTIF(A2:A12,A2:A12))

Fórmula 2: Após introduzir a fórmula, prima as teclas «Ctrl» + «Shift» + «Enter».

=SUM(1/COUNTIF(A2:A12,A2:A12))
Nota: Nestas fórmulas, "A2:A12" é a lista de dados cujos valores pretende contar Valor diferente.

Resultado:

Contar valores distintos com fórmula

Dicas:

  1. Se a lista de dados incluir outros tipos de dados, como números, valores lógicos, valores de erro, entre outros, esta fórmula obtém os valores distintos independentemente do tipo de dado.
  2. Ao utilizar a fórmula acima, obterá o valor de erro #DIV/0 se a lista de dados contiver células vazias. Para corrigir e ignorar as células vazias, deve aplicar uma das fórmulas seguintes:
    Fórmula 1: Após introduzir a fórmula, prima a tecla «Enter».
    =SUMPRODUCT((A2:A12<>"")/COUNTIF(A2:A12,A2:A12&""))
    Fórmula 2: Após introduzir a fórmula, prima as teclas «Ctrl» + «Shift» + «Enter».
    =SUM(IF(A2:A12<>"",1/COUNTIF(A2:A12, A2:A12), 0))

    Contar valores distintos excluindo células vazias com fórmula

  3. Para obter apenas o número de valores de texto distintos numa lista de dados, aplique a seguinte fórmula matricial e prima as teclas «Ctrl» + «Shift» + «Enter» para obter o resultado:
    =SUM(IF(ISTEXT(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))
  4. Para contar apenas valores numéricos distintos, utilize a seguinte fórmula matricial e prima as teclas «Ctrl» + «Shift» + «Enter» para obter o resultado:
    =SUM(IF(ISNUMBER(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))

Contagem única valores com alguns cliques através de Kutools para Excel

Se precisar de aplicar fórmulas frequentemente na sua pasta de trabalho, pode ser difícil lembrar-se delas sempre que necessário. No entanto, com o **Kutools para Excel** e a opção **“Contar células com valores únicos (inclui a primeira ocorrência duplicada)”** do **Assistente de Fórmulas**, obtém o resultado em apenas alguns cliques. Veja a demonstração abaixo:

  1. Clique numa célula para apresentar o resultado;
  2. Ative esta funcionalidade clicando em «Kutools» > «Assistente de Fórmulas» > «Estatísticas» > «Contar células únicas com valores únicos (inclui a primeira ocorrência duplicada)»;
  3. Selecione a lista de dados e clique em «OK».
    Contar valores distintos com Kutools
Dicas:
  1. Para utilizar esta funcionalidade, tem de transferir e instalar o Kutools para Excel.
  2. A funcionalidade «Assistente de Fórmulas» reúne as fórmulas mais utilizadas, como «Extrair valores únicos», «Extrair células com valores únicos de um intervalo (incluindo os primeiros duplicados)», «Contar o número de valores separados por vírgula numa célula», «Somar com base no mesmo texto» e muito mais...

Contagem única valores com Tabela Dinâmica

No Excel, a Tabela Dinâmica também permite obter o número de valores distintos a partir de uma lista de dados. Siga os passos abaixo:

Passo 1: Crie uma Tabela Dinâmica

  1. Selecione a lista de dados e, em seguida, clique em «Inserir» > «Tabela Dinâmica» na Friso, veja a imagem:
    criar uma Tabela Dinâmica para os dados selecionados
  2. Na caixa de diálogo «Tabela Dinâmica a partir de tabela ou intervalo» que surge:
    (1). Escolha uma nova folha de cálculo ou uma folha existente onde pretende inserir a Tabela Dinâmica;
    (2). Em seguida, marque a caixa de seleção «Adicionar estes dados ao Modelo de Dados»;
    (3). Depois, clique no botão «OK».
    definir opções na caixa de diálogo Tabela Dinâmica a partir de tabela ou intervalo

Passo 2: Organize o campo e selecione a opção Contagem Distinta

  1. É apresentado um painel «Campos da Tabela Dinâmica»; arraste o campo «Nomes» para a área «Valores», veja a demonstração abaixo:
    Organizar o campo para a Tabela Dinâmica
  2. Em seguida, clique na seta suspensa «Contagem de Nomes» e escolha «Configurações de Campo de Valor», veja a imagem:
    clicar na opção Configurações do Campo de Valores
  3. Depois, abrir-se-á uma caixa de diálogo «Configurações de Campo de Valor»; selecione «Contagem Distinta» na lista sob o separador «Resumir Valores Por» e clique no botão «OK», veja a imagem:
    selecionar a opção Contagem Distinta

Resultado:

Agora, a Tabela Dinâmica criada apresentará a contagem distinta da lista de dados, tal como mostrado na imagem abaixo:

Resultado da Tabela Dinâmica para contar valores distintos

Dicas:

  1. Se atualizar os seus Dados de Origem, basta clicar com o botão direito do rato na Tabela Dinâmica e selecionar a opção «Atualizar» para obter a contagem mais recente.
  2. A opção «Contagem Distinta» está disponível apenas a partir do Excel 2013.

Contagem única valores no Excel 365/2021 com fórmulas

No Excel 365 ou no Excel 2021, pode combinar a nova função UNIQUE com a função COUNTA para criar uma fórmula simples e eficaz.

Copie ou introduza a fórmula abaixo numa célula vazia e prima a tecla «Enter» para obter o resultado:

=COUNTA(UNIQUE(A2:A12))
Nota: Nesta fórmula, "A2:A12" é a lista de dados cujos valores pretende Contagem única.

Contar valores distintos no Excel 365/2021 com fórmula

Dicas:

  1. Se a lista de dados incluir outros tipos de dados — como texto, números, valores lógicos, valores de erro, entre outros —, esta fórmula contará o número de valores distintos, independentemente do tipo de dado.
  2. A fórmula acima conta valores únicos, incluindo células vazias. Se pretender excluí-las, aplique a fórmula abaixo e prima a tecla «Enter» para obter o resultado:
    =COUNTA(UNIQUE(FILTER(A2:A12, A2:A12<>"")))

    Contar valores distintos no Excel 365/2021 com fórmula excluindo células vazias

Artigos relacionados:

  • Contar o número de valores únicos em um intervalo no Tabela Dinâmica
  • Por predefinição, ao criar uma Tabela Dinâmica com base num intervalo de dados que contém alguns Valores Duplicados, todos os registos são igualmente contabilizados. Contudo, por vezes, pretendemos apenas contar os valores únicos com base numa coluna para obter o resultado correto. Neste artigo, explicarei como contar os valores únicos no Tabela Dinâmica.
  • Contar o número de valores únicos em um intervalo com múltiplos critérios
  • Aqui está um conjunto de dados com vários nomes, projetos e localizações. O que precisa fazer é identificar os nomes que correspondem aos critérios que listei e contar cada nome correspondente apenas uma vez, tal como mostrado na imagem abaixo. Conhece algum truque para resolver esta tarefa? Neste artigo, apresento-lhe esses truques.
  • Concatenar valores únicos
  • Se tiver uma lista longa de valores com dados duplicados e quiser identificar rapidamente os valores únicos e concatená-los numa única célula, como pode resolver este problema de forma rápida e fácil no Excel?