Como encontrar e substituir vários textos no Word usando o Excel?

No Microsoft Word, o recurso Localizar e Substituir é uma maneira eficiente de procurar e substituir rapidamente um texto específico. No entanto, quando você precisa substituir vários termos diferentes, inserir cada um manualmente pode ser demorado.

Para simplificar esse processo, você pode usar o Excel para criar uma lista dos textos que deseja encontrar e substituir e, em seguida, automatizar a tarefa com um código VBA simples. Este tutorial irá guiá-lo no uso do Excel e do VBA para localizar e substituir múltiplos textos dentro de um único documento do Word. Além disso, mostrarei como estender isso para vários documentos e apresentarei um poderoso recurso do Kutools para substituição de texto em lote.

Encontre e substitua múltiplos textos em um documento do Word a partir do Excel com código VBA

Encontre e substitua múltiplos textos em vários documentos do Word a partir do Excel com código VBA

Encontre e substitua múltiplos textos em vários documentos do Word com um recurso poderoso

Encontre e substitua múltiplos textos em um documento do Word a partir do Excel com código VBA

Se você quiser encontrar e substituir alguns textos em apenas um arquivo do Word, o seguinte código VBA pode ajudá-lo.

1. Na planilha do Excel, crie uma coluna contendo os textos que deseja encontrar e substituir e outra coluna com os textos pelos quais deseja substituir, conforme mostrado na captura de tela abaixo. Em seguida, pressione simultaneamente as teclas Alt + F11 para abrir a janela Microsoft Visual Basic for Applications.

2. Depois, clique em Inserir > Módulo, copie e cole o código VBA abaixo na janela.

Código VBA: Encontrar e substituir múltiplos textos em um arquivo do Word

Sub replace_texts_range_of_cells()
'Updateby ExtendOffice
Dim xWordApp As Word.Application
Dim xDoc As Word.Document
Dim xRng As Range
Dim I As Integer
Dim xFileDlg As FileDialog
On Error GoTo ExitSub
Set xFileDlg = Application.FileDialog(msoFileDialogFilePicker)
xFileDlg.AllowMultiSelect = False
xFileDlg.Filters.Add "Word Document", "*.docx; *.doc; *.docm"
xFileDlg.FilterIndex = 2
If xFileDlg.Show <> -1 Then GoTo ExitSub
Set xRng = Application.InputBox("Please select the lists of find and replace texts (Press Ctrl key to select two same size ranges):", "Kutools for Excel", , , , , , 8)
If xRng.Areas.Count <> 2 Then
  MsgBox "Please select two columns (press Ctrl key), the two ranges have the same size.", vbInformation + vbOKOnly, "Kutools for Excel"
  GoTo ExitSub
End If
If (xRng.Areas.Item(1).Rows.Count <> xRng.Areas.Item(2).Rows.Count) Or _
  (xRng.Areas.Item(1).Columns.Count <> xRng.Areas.Item(2).Columns.Count) Then
  MsgBox "Please select two columns (press Ctrl key), the two ranges have the same size.", vbInformation + vbOKOnly, "Kutools for Excel"
  GoTo ExitSub
End If
Set xWordApp = CreateObject("Word.application")
xWordApp.Visible = True
Set xDoc = xWordApp.Documents.Open(xFileDlg.SelectedItems.Item(1))
For I = 1 To xRng.Areas.Item(1).Cells.Count
  With xDoc.Application.Selection.Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = xRng.Areas.Item(1).Cells.Item(I).Value
    .Replacement.Text = xRng.Areas.Item(2).Cells.Item(I).Value
    .Forward = True
    .Wrap = wdFindContinue
    .Format = False
    .MatchCase = False
    .MatchWholeWord = False
    .MatchByte = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
  End With
  xDoc.Application.Selection.Find.Execute Replace:=wdReplaceAll
Next
ExitSub:
  Set xRng = Nothing
  Set xFileDlg = Nothing
  Set xWordApp = Nothing
  Set xDoc = Nothing
End Sub

3. Após colar o código, ainda na janela Microsoft Visual Basic for Applications, clique em Ferramentas > Referências, veja a captura de tela:

4. Na caixa de diálogo Referências – VBAProject que apareceu, selecione a Biblioteca de Objetos do Microsoft Word 16.0 na caixa de listagem, veja a captura de tela:

5. Clique no botão OK para fechar a caixa de diálogo e agora pressione a tecla F5 para executar este código; na janela Procurar que aparecerá, selecione o Arquivo do Word no qual deseja substituir os textos, veja a captura de tela:

6. Em seguida, clique em OK, na próxima caixa de diálogo, pressione a tecla Ctrl para selecionar separadamente as células de texto original e novo texto que deseja usar, veja a captura de tela:

7. E então, clique no botão OK; agora, os textos foram encontrados e substituídos pelos novos textos no seu documento especificado, e o arquivo também será aberto, você deve salvá-lo para manter as alterações.

Encontre e substitua múltiplos textos em vários documentos do Word a partir do Excel com código VBA

Também criei um código VBA para ajudá-lo a encontrar e substituir múltiplos textos em vários documentos do Word. Siga estas etapas:

1. Abra o arquivo do Excel que contém duas colunas de valores para substituir e substituir por, conforme mostrado na captura de tela abaixo, e depois pressione simultaneamente as teclas Alt + F11 para abrir a janela Microsoft Visual Basic for Applications.

2. Depois, clique em Inserir > Módulo, copie e cole o código VBA abaixo na janela.

Código VBA: Encontrar e substituir múltiplos textos em vários arquivos do Word

Sub FindReplaceAcrossMultipleWordDocuments()
'Updateby ExtendOffice
Dim xWordApp As Word.Application
Dim xDoc As Word.Document
Dim xRng As Range
Dim I As Integer
Dim xFolderDlg As FileDialog
Dim xFSO As Scripting.FileSystemObject
Dim xFile As File
On Error GoTo ExitSub
Set xFolderDlg = Application.FileDialog(msoFileDialogFolderPicker)
If xFolderDlg.Show <> -1 Then GoTo ExitSub
Set xRng = Application.InputBox("Please select the lists of find and replace texts (Press Ctrl key to select two same size ranges", "Kutools for Excel", , , , , , 8)
If xRng.Areas.Count <> 2 Then
  MsgBox "Please select two columns (press Ctrl key), the two ranges have the same size", vbInformation + vbOKOnly, "Kutools for Excel"
  GoTo ExitSub
End If
If (xRng.Areas.Item(1).Rows.Count <> xRng.Areas.Item(2).Rows.Count) Or _
  (xRng.Areas.Item(1).Columns.Count <> xRng.Areas.Item(2).Columns.Count) Then
  MsgBox "Please select two columns (press Ctrl key), the two ranges have the same size.", vbInformation + vbOKOnly, "Kutools for Excel"
  GoTo ExitSub
End If
Set xFSO = New Scripting.FileSystemObject
Set xWordApp = CreateObject("Word.application")
xWordApp.Visible = True
For Each xFile In xFSO.GetFolder(xFolderDlg.SelectedItems(1)).Files
  If VBA.InStr(xFile.Type, "Microsoft Word") > 0 Then
    Set xDoc = xWordApp.Documents.Open(xFile.Path)
    For I = 1 To xRng.Areas.Item(1).Cells.Count
      With xDoc.Application.Selection.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Text = xRng.Areas.Item(1).Cells.Item(I).Value
        .Replacement.Text = xRng.Areas.Item(2).Cells.Item(I).Value
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchByte = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
      End With
      xDoc.Application.Selection.Find.Execute Replace:=wdReplaceAll
    Next
    xDoc.Close wdSaveChanges
  End If
Next
xWordApp.Quit
MsgBox "The Find and Replace has been completed", vbInformation + vbOKOnly, "Kutools for Excel"
ExitSub:
  Set xRng = Nothing
  Set xFolderDlg = Nothing
  Set xWordApp = Nothing
  Set xDoc = Nothing
End Sub

3. Ainda na janela Microsoft Visual Basic for Applications, clique em Ferramentas > Referências, na caixa de diálogo Referências – VBAProject, selecione as opções Biblioteca de Objetos do Microsoft Word 16.0 e Microsoft Scripting Runtime na caixa de listagem, veja a captura de tela:

4. Após marcar as duas opções, clique em OK para fechar a caixa de diálogo e, em seguida, continue pressionando a tecla F5 para executar este código; na janela Procurar que se abrirá, escolha uma pasta que contenha os documentos do Word nos quais deseja realizar a busca e substituição, veja a captura de tela:

5. Clique no botão OK, na caixa de diálogo que apareceu, pressione a tecla Ctrl para selecionar separadamente as colunas de texto original e novo texto que deseja usar, veja a captura de tela:

6. Por fim, clique em OK, e os textos originais serão substituídos pelos novos em todos esses arquivos. Após a conclusão, uma caixa de diálogo aparecerá conforme mostrado na captura de tela abaixo:

7. Clique em OK para fechar a caixa de diálogo. E você pode acessar os arquivos para verificar os resultados convertidos.

Encontre e substitua múltiplos textos em vários documentos do Word com um recurso poderoso

Nesta seção, explicarei como fazer uma busca e substituição em lote de texto em vários documentos do Word usando o próprio Word, em vez do Excel. Ao usar o poderoso Kutools para Word, você pode pesquisar eficientemente textos específicos e substituí-los por novos no corpo principal, cabeçalhos, rodapés, comentários e mais, enquanto também destaca os resultados conforme necessário.

1. Abra um arquivo do Word e, em seguida, clique em Kutools Plus > Localizar e Substituir em Lote, veja a captura de tela:

2. Na caixa de diálogo Localizar e Substituir em Lote aberta, realize as seguintes operações:

• Clique no botão Adicionar para adicionar os arquivos do Word onde deseja encontrar e substituir textos;
• No painel esquerdo, clique em Adicionar linha na faixa de opções superior;
• No campo inserido, insira o texto original e o novo texto nas colunas Localizar e Substituir separadamente que deseja encontrar e substituir. Além disso, você pode especificar uma cor para destacar os textos substituídos conforme necessário.

3. Após criar os critérios de pesquisa, clique no botão Substituir para ir à guia Visualização de Resultados e ver os resultados da busca e substituição. Veja a captura de tela:

4. Depois, clique no botão Fechar, e uma caixa de prompt aparecerá para lembrá-lo se deseja salvar este cenário, clique em Sim para salvá-lo e em Não para ignorá-lo, veja a captura de tela:

Faça Mais em Menos Tempo com o Kutools para Word Aprimorado por IA

O Kutools para Word não é apenas um conjunto de ferramentas - é uma solução inteligente desenvolvida para aumentar sua produtividade. Com recursos impulsionados por IA e os recursos mais essenciais, o Kutools ajuda você a realizar mais em menos tempo:

• Resuma, reescreva, componha e traduza conteúdo instantaneamente.
• Corrija o texto em tempo real com sugestões de gramática, pontuação e estilo enquanto você escreve.
• Reformule e traduza o conteúdo mantendo o layout, estilo e estrutura intactos.
• Traduza seu conteúdo para mais de 40 idiomas facilmente, expandindo seu alcance globalmente.
• Receba ajuda instantânea e insights inteligentes com base no conteúdo do documento atual.
• Pergunte como concluir uma tarefa - como remover quebras de seção - e a IA irá guiá-lo ou fazer isso por você.
• Censure informações sensíveis ou confidenciais em segundos para garantir privacidade total.
• Todas as ferramentas funcionam perfeitamente dentro do Word, sempre ao alcance.

• Crie, refine, traduza, resuma e proteja documentos sem esforço.
• Melhore a gramática, clareza e tom enquanto escreve em tempo real.
• Reformule e traduza o conteúdo sem alterações no layout ou formatação.
• Pergunte como concluir uma tarefa - como remover quebras de seção - e a IA irá guiá-lo ou fazer isso por você.
• Todas as ferramentas funcionam perfeitamente dentro do Word, sempre ao alcance.

Saiba mais sobre o Kutools para Word Baixar Agora