Tutorial do Excel – Extrair Texto ou número por posição específica

Em muitos casos, basta extrair conteúdo útil de uma frase ou sequência de texto numa célula — como a província de um endereço, o endereço de e-mail de uma frase ou o número da guia de transporte de uma conversa, entre outros. Este tutorial foca-se na extração com base numa posição específica na célula e reúne diferentes métodos para o ajudar a extrair texto ou números de uma célula por posição específica no Excel.

Extrair Texto por posição

Esta secção reúne as posições mais comuns de onde se pode extrair texto de uma célula e apresenta os respetivos métodos para os tratar, passo a passo. Explore para obter mais detalhes.

1. Extrair números de caracteres a partir da esquerda ou da direita

Para extrair números dos caracteres do lado esquerdo ou direito de uma cadeia, experimente um dos métodos abaixo.

1,1 Extrair os primeiros ou últimos N caracteres com fórmulas

Imagine que tem uma lista de cadeias de texto na coluna B, como ilustrado na imagem seguinte. Para extrair os dois primeiros e os dois últimos caracteres de cada cadeia, basta aplicar as fórmulas seguintes.

Extrair Primeiros N Caracteres de uma cadeia de texto

A função ESQUERDA permite extrair facilmente os primeiros N caracteres de uma cadeia de texto no Excel.

Fórmula genérica

=LEFT(text_string,[num_chars])

Argumentos

Agora pode aplicar esta fórmula para extrair os dois primeiros caracteres das células na coluna B.

1. Selecione uma célula vazia, copie ou introduza a fórmula abaixo e prima Enter para obter o primeiro resultado. Em seguida, selecione a célula com o resultado e arraste a Alça de Preenchimento Automático para baixo, aplicando assim a fórmula às restantes células.

=LEFT(B5,2)

Agora já extraiu os dois primeiros caracteres de cada célula do intervalo indicado.

Extrair Últimos N Caracteres de uma cadeia de texto

Aqui utilizamos a função DIREITA para extrair os últimos N caracteres de uma cadeia de texto no Excel.

Fórmula genérica

=RIGHT(text_string,[num_chars])

Argumentos

Selecione uma célula vazia, copie ou introduza a fórmula abaixo e prima Enter para obter o resultado. Em seguida, selecione essa célula de resultado e arraste a Alça de Preenchimento Automático para baixo para obter os restantes resultados.

=RIGHT(B5,2)

1,2 Extrair os primeiros ou últimos N caracteres com uma ferramenta incrível

Embora as fórmulas acima sejam simples, para extrair os primeiros ou últimos N caracteres de uma longa lista de cadeias de texto, ainda terá de arrastar a Alça de Preenchimento Automático de cima para baixo — o que pode ser um pouco demorado. Aqui, recomendamos o utilitário Kutools para Excel«Extrair Texto» para extrair em massa os primeiros ou últimos N caracteres de uma lista de cadeias de texto.

1. Selecione previamente a lista de cadeias de texto da qual pretende extrair texto e clique em «Kutools» > «Texto» > «Extrair Texto».

2. Na caixa de diálogo «Extrair Texto» que surge, configure-a da seguinte forma:

Nota: Para tornar o resultado dinâmico sempre que a cadeia de texto for alterada, marque a caixa «Inserir como Fórmula».

3. Na caixa de diálogo seguinte, “Extrair Texto”, selecione uma célula para exibir os caracteres extraídos e clique em “OK”.

Os primeiros N ou últimos N caracteres são extraídos em massa das células selecionadas.

Clique para descobrir mais sobre esta funcionalidade.

2. Extraia texto antes ou depois de um determinado caractere ou palavra.

Para extrair texto antes ou depois de um determinado caractere ou palavra, os cenários nesta secção satisfazem as suas necessidades.

2,1 Extrair Texto antes ou depois do primeiro delimitador (um caractere)

Conforme ilustrado na imagem seguinte, para extrair o texto antes ou depois do primeiro delimitador em cada célula do intervalo B4:B10, pode utilizar um dos métodos abaixo.

2,1.1 Extrair Texto antes do primeiro delimitador com fórmula

Aplicar uma fórmula com base nas funções ESQUERDA e PROCURAR permite extrair o texto antes do primeiro delimitador de uma célula. Siga os passos abaixo para concluir esta tarefa.

Fórmula genérica

=LEFT(text_string,FIND(«delimiter»,text_string,1)-1)

Argumentos

Selecione uma célula vazia, copie ou introduza a fórmula abaixo e prima Enter para obter o primeiro resultado. Em seguida, selecione essa célula de resultado e arraste a Alça de Preenchimento Automático para baixo, de modo a extrair os textos anteriores ao primeiro delimitador das restantes células.

=LEFT(B5,FIND("-",B5,1)-1)

2,1.2 Extrair Texto depois do primeiro delimitador com fórmula

A fórmula abaixo ajuda a extrair o texto após o primeiro delimitador de uma célula no Excel.

Fórmula genérica

=MID(text_string,FIND(«delimiter»,text_string)+1,LEN(text_string))

Argumentos

=MID(B5,FIND("-",B5)+1,LEN(B5))

2,1.3 Extrair Texto antes ou depois do primeiro delimitador com uma ferramenta incrível

Aqui, recomendamos vivamente a funcionalidade «Extrair Texto» do Kutools para Excel. Com ela, pode extrair facilmente texto antes ou depois do primeiro delimitador num intervalo de células em massa.

1. Selecione o intervalo de células do qual pretende extrair texto e, em seguida, clique em «Kutools» > «Texto» > «Extrair Texto».

2. Na caixa de diálogo «Extrair Texto», configure-a conforme indicado a seguir.

Nota: Para tornar o resultado dinâmico sempre que a cadeia de texto for alterada, marque a caixa Inserir como Fórmula.

3. Surge, então, outra caixa de diálogo «Extrair Texto»; escolha uma célula para apresentar os resultados e clique em «OK».

Os textos antes ou depois do primeiro delimitador são extraídos, de uma só vez, das células selecionadas.

Para saber mais sobre esta funcionalidade, visite:Extrair Rapidamente Determinado Texto de Células no Excel.

2,2 Extrair Texto antes ou depois do último delimitador (um caractere)

Nos passos anteriores, aprendemos os métodos para extrair texto antes ou depois do primeiro delimitador de uma célula. Como ilustrado na imagem seguinte, esta secção apresenta-lhe duas fórmulas para extrair texto antes ou depois do último delimitador de uma célula. Basta seguir os passos abaixo para concluir a tarefa.

2,2.1 Extrair Texto antes do último delimitador com fórmula

Para extrair o texto antes do último delimitador de uma célula, utilize as funções PROCURAR, NÚM.CARACT e SUBSTITUIR dentro da função ESQUERDA.

Fórmula genérica

=LEFT(text_string,SEARCH(«#»,SUBSTITUTE(text_string,«delimiter»,«#»,LEN(text_string)-LEN(SUBSTITUTE(text_string,«delimiter»,«»))))-1)

Argumentos

Selecione uma célula, insira a fórmula abaixo e prima Enter para obter o resultado. Em seguida, selecione essa célula com o resultado e arraste a Alça de Preenchimento Automático para baixo, de modo a extrair os textos das restantes cadeias na mesma coluna.

=LEFT(B5,SEARCH("#",SUBSTITUTE(B5,"-","#",LEN(B5)-LEN(SUBSTITUTE(B5,"-",""))))-1)

2,2.2 Extrair Texto depois do último delimitador com fórmula

Depois de extrair o texto antes do último delimitador de uma célula, pode aplicar a fórmula abaixo para obter o texto após esse mesmo delimitador, conforme necessário.

Fórmula genérica

=RIGHT(text_string,LEN(text_string)-SEARCH(«#»,SUBSTITUTE(text_string,«delimiter»,«#»,LEN(text_string)-LEN(SUBSTITUTE(text_string,«delimiter»,«»)))))

Argumentos

Selecione uma célula, insira a fórmula abaixo e prima Enter para obter o resultado. Em seguida, selecione essa célula com o resultado e arraste a Alça de Preenchimento Automático para baixo, de modo a extrair os textos das restantes cadeias na mesma coluna.

=RIGHT(B5,LEN(B5)-SEARCH("#",SUBSTITUTE(B5,"-","#",LEN(B5)-LEN(SUBSTITUTE(B5,"-","")))))

2,3 Extrair Texto após o enésimo caractere

Veja o exemplo abaixo: há uma lista de cadeias de texto no intervalo B4:B10. Para extrair o texto após o terceiro caractere de cada célula, pode utilizar uma fórmula com base nas funções EXT.TEXTO e NÚM.CARACT.

Fórmula genérica

=MID(text_string,nth_char+1,LEN(text_string))

Argumentos

Selecione uma célula vazia, copie ou introduza a fórmula abaixo e prima Enter para obter o resultado. Em seguida, selecione essa célula de resultado e arraste a Alça de Preenchimento Automático para baixo para obter os restantes resultados.

=MID(B5,3+1,LEN(B5))

2,4 Extrair a enésima palavra de uma cadeia de texto

Suponha que tem uma lista de cadeias de texto, como a apresentada na imagem abaixo, e pretende extrair apenas a enésima palavra de cada cadeia. Esta secção mostra-lhe três métodos para o fazer.

2,4.1 Extrair a enésima palavra com fórmula

Combine as funções TRIM, MID, SUBSTITUTE, REPT e LEN para extrair a enésima palavra de uma cadeia de texto numa célula.

Fórmula genérica

=TRIM(MID(SUBSTITUTE(text_string,« »,REPT(« »,LEN((text_string))), (N-1)*LEN((text_string)+1, LEN((text_string)))

Argumentos

Neste caso, o intervalo B5:B10 contém as cadeias de texto e D5:D10 contém os números que indicam a enésima palavra. Vamos aplicar esta fórmula para extrair a enésima palavra de cada cadeia de texto.

Selecione uma célula vazia, copie ou introduza a fórmula abaixo nela e prima «Enter» para obter o primeiro resultado. Em seguida, selecione essa célula de resultado e arraste a sua Alça de Preenchimento Automático para baixo, de modo a extrair a enésima palavra das restantes células.

=TRIM(MID(SUBSTITUTE(B5," ",REPT(" ",LEN(B5))), (D5-1)*LEN(B5)+1, LEN(B5)))

Nota: Pode introduzir diretamente o número enésimo na fórmula, conforme indicado a seguir.

=TRIM(MID(SUBSTITUTE(B5," ",REPT(" ",LEN(B5))), (2-1)*LEN(B5)+1, LEN(B5)))

2,4.2 Extrair a enésima palavra com uma função definida pelo utilizador

Além da fórmula acima, pode também utilizar uma função definida pelo utilizador para extrair a enésima palavra de uma célula no Excel.

1. Prima as teclas «Alt» + «F11» para abrir a janela do Microsoft Visual Basic for Applications.

2. Na janela «Microsoft Visual Basic for Applications», clique em «Inserir» > «Módulo» e, de seguida, copie o código VBA abaixo para a janela de código.

Código VBA: Extrair a enésima palavra de uma cadeia de texto numa célula

Function ExtractTheNthWord(Source As String, Position As Integer)
'Update by Extendoffice 20211202
Dim arr() As String
arr = VBA.Split(Source, " ")
xCount = UBound(arr)
If xCount < 1 Or (Position - 1) > xCount Or Position < 0 Then
    FindWord = ""
Else
    FindWord = arr(Position - 1)
End If
End Function

3. Prima as teclas «Alt» + «Q» para fechar a janela do Microsoft Visual Basic for Applications.

4. Regresse à folha de cálculo que contém as cadeias de texto das quais pretende extrair a enésima palavra. Selecione uma célula vazia, copie ou introduza a fórmula abaixo e prima «Enter» para obter a enésima palavra.

=FindWord(B5,D5)

Ou

=FindWord(B5,2)

Nota: na fórmula, D5 é a célula que contém o número correspondente à enésima palavra. Como alternativa, pode substituir diretamente a referência da célula por um número.

5. Selecione a célula de resultado e arraste a sua Alça de Preenchimento Automático para baixo, de modo a extrair a enésima palavra das cadeias de texto contidas nas restantes células.

2,4.3 Extrair a enésima palavra com uma ferramenta incrível

Se não pretender aplicar manualmente a fórmula ou a função definida pelo utilizador indicada acima, recomendamos a funcionalidade «Extrair a enésima palavra de uma célula» do Kutools para Excel. Com ela, extrai facilmente a enésima palavra de uma cadeia de texto numa célula com apenas alguns cliques.

1. Selecione uma célula para inserir o resultado e clique em «Kutools» > «Assistente de Fórmulas» > «Texto» > «Extrair a enésima palavra de uma célula». Veja a imagem:

2. Na caixa de diálogo «Assistente de Fórmulas», configure da seguinte forma:

3. Assim, a enésima (segunda) palavra é extraída da cadeia de texto na célula B5, e pode observar que, simultaneamente, é criada uma fórmula. Selecione essa célula de resultado e arraste a sua Alça de Preenchimento Automático para baixo, a fim de obter a enésima palavra das restantes cadeias de texto.

Clique para descobrir mais sobre esta funcionalidade.

2,5 Extrair Texto antes ou depois da Ocorrência de um delimitador

Suponha que tem uma lista de cadeias de texto, como se mostra na imagem abaixo. Para extrair o texto antes ou depois da segunda ocorrência de um espaço, esta secção apresenta duas fórmulas que o ajudam a realizar essa tarefa com facilidade.

2,5.1 Extrair Texto antes da Ocorrência de um delimitador

Pode utilizar a função LEFT em conjunto com as funções SUBSTITUTE e FIND para extrair o texto antes da ocorrência de um delimitador numa célula do Excel.

Fórmula genérica

=LEFT(SUBSTITUTE(text_string,«delimiter»,CHAR(9),n),FIND(CHAR(9),SUBSTITUTE(text_string,«delimiter»,CHAR(9),n),1)-1)

Argumentos

Selecione uma célula, copie ou introduza a fórmula abaixo e prima «Enter» para obter o resultado. Em seguida, selecione essa célula de resultado e arraste a sua Alça de Preenchimento Automático para baixo, de modo a obter os restantes resultados na lista.

=LEFT(SUBSTITUTE(B5," ",CHAR(9),2),FIND(CHAR(9),SUBSTITUTE(B5," ",CHAR(9),2),1)-1)

Nota: Na fórmula, B5 é a célula que contém a cadeia de texto da qual pretende extrair o conteúdo; « » representa um espaço e o número 2 indica a segunda ocorrência desse espaço. Pode ajustar estes elementos conforme as suas necessidades.

2,5.2 Extrair Texto depois da Ocorrência de um delimitador

Para extrair texto após a ocorrência de um delimitador, pode utilizar a função RIGHT em combinação com as funções SUBSTITUTE, LEN e FIND.

Fórmula genérica

=RIGHT(SUBSTITUTE(text_string, «delimiter», CHAR(9), n), LEN(text_string)- FIND(CHAR(9), SUBSTITUTE(text_string, «delimiter», CHAR(9), n), 1) + 1)

Argumentos

Agora pode aplicar esta fórmula para extrair o texto após a segunda ocorrência do espaço em cada célula do intervalo B5:B10, conforme indicado a seguir.

Selecione uma célula, introduza a fórmula abaixo e prima «Enter» para obter o resultado. Em seguida, selecione essa célula de resultado e arraste a respetiva Alça de Preenchimento Automático para baixo, de modo a obter os restantes resultados.

=RIGHT(SUBSTITUTE(B5, " ", CHAR(9), 2), LEN(B5)- FIND(CHAR(9), SUBSTITUTE(B5, " ", CHAR(9), 2), 1) + 1)

2,6 Extrair Texto antes ou depois de uma quebra de linha

Suponha que tem uma lista de encomendas na coluna B e pretende extrair apenas a parte da data e o número do produto de cada célula. Utilize as fórmulas do Excel abaixo para o conseguir.

2,6.1 Extrair Texto antes da primeira quebra de linha com fórmula

Como pode ver na imagem acima, a parte da data aparece antes da primeira quebra de linha dentro da célula. Esta secção irá mostrar-lhe como utilizar a função LEFT em conjunto com a função SEARCH para extrair facilmente o texto situado antes dessa primeira quebra de linha.

Fórmula genérica

=LEFT(cell, SEARCH(CHAR(10), cell)-1)

Argumentos

Selecione uma célula vazia, cole ou introduza a fórmula abaixo nela e prima Enter para obter o resultado. Em seguida, selecione essa célula com o resultado e arraste a respetiva alça de preenchimento automático para baixo, de modo a aplicar a fórmula às restantes células.

=LEFT(B5, SEARCH(CHAR(10), B5)-1)

Assim, pode ver que o texto antes da primeira quebra de linha em cada célula do intervalo B5:B8 é extraído, conforme ilustrado na imagem abaixo.

Nota: Na fórmula, CHAR(10) representa uma quebra de linha no Windows.

2,6.2 Extrair Texto depois da última quebra de linha com fórmula

No passo anterior, abordámos como extrair o texto antes da primeira quebra de linha numa célula. Agora, vamos mostrar-lhe como extrair o texto após a última quebra de linha na mesma célula, utilizando uma fórmula diferente.

Fórmula genérica

=TRIM(RIGHT(SUBSTITUTE(cell,CHAR(10),REPT(« »,200)),200))

Argumentos

Selecione uma célula vazia, insira a fórmula abaixo e prima Enter para obter o resultado. Em seguida, selecione essa célula de resultado e arraste a sua Alça de Preenchimento Automático para baixo, aplicando a fórmula às demais células.

=TRIM(RIGHT(SUBSTITUTE(B5,CHAR(10),REPT(" ",200)),200))

Assim, a parte correspondente ao número do produto de cada célula na lista é extraída, conforme ilustrado na imagem acima.

Nota: Na fórmula, CHAR(10) representa uma quebra de linha no Windows.

2,7 Extrair Texto antes ou depois de uma palavra

Nas partes anteriores, aprendemos como extrair texto antes ou depois de um carácter ou delimitador. Mas e se precisar de extrair texto antes ou depois de uma palavra inteira? Esta secção apresenta-lhe três métodos para o ajudar a concretizar essa tarefa.

2,7.1 Extrair Texto antes de uma determinada palavra com fórmula

A fórmula seguinte ajuda-o a extrair o texto antes de uma determinada palavra numa célula do Excel.

Fórmula genérica

=IFERROR(LEFT(cell,FIND(word,cell)-1),cell)

Argumentos

Selecione uma célula vazia, insira a fórmula abaixo e prima Enter para obter o resultado. Em seguida, selecione essa célula de resultado e arraste a sua Alça de Preenchimento Automático para baixo, aplicando a fórmula às demais células.

Neste exemplo, vamos extrair todo o texto antes da palavra «Excel», pelo que introduzimos diretamente essa palavra na fórmula, colocando-a entre aspas — ou, alternativamente, pode fazer referência a uma célula que contenha a palavra «Excel».

=IFERROR(LEFT(B5,FIND("Excel",B5)-1),B5)

Notas:

2,7.2 Extrair Texto depois de uma determinada palavra com fórmula

Para extrair texto após uma determinada palavra, aplique a seguinte fórmula.

Fórmula genérica

=TRIM(MID(cell,SEARCH(word,cell)+LEN(word),255))

Argumentos

Selecione uma célula, insira a fórmula abaixo e prima «Enter» para obter o resultado. Em seguida, selecione a célula com o resultado e arraste a sua Alça de Preenchimento Automático para baixo, aplicando assim a fórmula às demais células.

=TRIM(MID(B5,SEARCH("Excel",B5)+LEN("Excel"),255))

Assim, pode ver que todo o texto após a palavra «Excel» em cada célula é extraído, conforme ilustrado na imagem abaixo.

Notas:

2,7.3 Extrair Texto antes ou depois de uma determinada palavra com uma ferramenta incrível

Se achar que usar fórmulas pode trazer muitos inconvenientes, recomendamos vivamente a funcionalidade «Extrair Texto» do «Kutools para Excel». Com apenas alguns cliques, ela automatiza toda a tarefa de extração no Excel.

1. Clique em «Kutools» > «Texto» > «Extrair Texto» para ativar esta funcionalidade.

2. Na caixa de diálogo «Extrair Texto», configure as seguintes definições.

2,1) Certifique-se de que está no separador «Extrair por Posição»;

2,2) Na caixa «Intervalo», clique no botão para selecionar o intervalo de células onde pretende Extrair Texto;

2,3) Na secção «Opções»:

Para extrair todo o texto antes de uma palavra, escolha a opção «antes do texto» Botão de Rádio e, em seguida, introduza a palavra na caixa de texto;

Para extrair todo o texto após uma palavra, escolha a opção «após o texto» Botão de Rádio e, em seguida, introduza a palavra na caixa de texto.

2,4) Clique no botão «OK». Veja a captura de ecrã:

Notas: Para obter resultados dinâmicos, marque a caixa «Inserir como Fórmula». Dessa forma, os resultados serão atualizados automaticamente sempre que os dados no intervalo forem modificados.

3. Em seguida, surge a caixa de diálogo «Extrair Texto». Basta selecionar uma célula para exibir o resultado e clicar no botão «OK».

Assim, os textos antes ou depois de uma determinada palavra, dentro de cada célula do intervalo selecionado, são extraídos imediatamente.

Nota: Esta funcionalidade diferencia maiúsculas de minúsculas.

Clique para descobrir tudo sobre esta funcionalidade.

3. Extrair entre caracteres ou palavras

Se pretender extrair texto entre determinados caracteres ou palavras, experimente os métodos seguintes.

3,1 Extrair Texto entre dois caracteres

Para extrair texto entre dois caracteres — que podem ser iguais ou diferentes — esta secção apresenta vários métodos, permitindo-lhe escolher o que melhor se adapta às suas necessidades.

3,1.1 Extrair Texto entre dois caracteres iguais com fórmula

Conforme ilustrado na imagem abaixo, a coluna B contém uma lista de cadeias de texto das quais pretende extrair os números situados entre os caracteres «/» em cada célula do intervalo. A fórmula seguinte pode ajudá-lo.

Selecione uma célula vazia, copie ou introduza a fórmula abaixo e prima Enter para obter o resultado. Em seguida, selecione a célula com o resultado e arraste a Alça de Preenchimento Automático para baixo, de modo a preencher as restantes células da lista.

=SUBSTITUTE(MID(SUBSTITUTE("/" & B5&REPT(" ",6),"/",REPT(",",255)),2*255,255),",","")

Assim, o texto entre os dois caracteres «/» é extraído de cada célula do intervalo. Veja a imagem:

Nota:

 3,1.2 Extrair Texto entre dois caracteres diferentes com fórmula

Depois de aprender como extrair texto entre dois caracteres iguais numa célula, mostramos agora uma fórmula para extrair texto entre dois caracteres diferentes. Conforme ilustrado na imagem abaixo, para obter apenas o endereço de e-mail entre as aspas de cada célula na coluna B, siga os passos indicados.

Fórmula genérica

=MID(LEFT(cel,FIND(«end_char»,cell)-1),FIND(«start_char»,cell)+1,LEN(cell))

Argumentos

Selecione uma célula vazia, copie ou introduza a fórmula abaixo e prima Enter para obter o resultado. Em seguida, selecione essa célula com o resultado e arraste a sua Alça de Preenchimento Automático para baixo, de modo a aplicar a fórmula às restantes células.

=MID(LEFT(B5,FIND(">",B5)-1),FIND("<",B5)+1,LEN(B5))

Pode confirmar que apenas o texto entre os caracteres especificados foi extraído, tal como ilustrado na imagem acima.

3,1.3 Extrair Texto entre dois caracteres com uma ferramenta incrível

Recomendamos vivamente a funcionalidade «Extrair a sequência entre caracteres especificados» do Kutools para Excel, que lhe permite extrair texto facilmente entre dois caracteres — iguais ou diferentes — dentro de uma célula no Excel.

1. Selecione uma célula vazia para inserir o resultado e clique em «Kutools» > «Assistente de Fórmulas» > «Assistente de Fórmulas».

2. Na caixa de diálogo «Assistente de Fórmulas», proceda às seguintes definições.

3. Assim, apenas o texto entre aspas na célula B5 é extraído. No entanto, como já foi criada uma fórmula, selecione essa célula com o resultado e, em seguida, arraste a sua Alça de Preenchimento Automático para baixo, de modo a extrair o texto das restantes células da mesma lista.

Clique para descobrir mais sobre esta funcionalidade.

3,1.4 Extrair Texto entre dois caracteres (incluindo os próprios caracteres) por regra

Se pretender manter os dois caracteres após a extração, experimente aplicar uma regra na funcionalidade Extrair Texto do Kutools para Excel.

1. Clique em «Kutools» > «Texto» > «Extrair Texto».

2. Na caixa de diálogo «Extrair Texto», configure as seguintes definições.

2,1) Clique no separador «Extrair por Regra»;

2,2) Na secção «Intervalo», clique no botão para selecionar o intervalo de células onde pretende extrair o texto entre caracteres;

2,3) Na caixa «Texto», introduza «»；

Dicas: «» são os caracteres entre os quais pretende Extrair Texto, * é um marcador universal que representa qualquer número de caracteres. Pode introduzir a condição de acordo com as suas necessidades.

2,4) Clique no botão «Adicionar» para adicionar a condição à caixa de lista «Conteúdo da Regra»;

2,5) Clique no botão «Ok». Veja a captura de ecrã:

3. Surge outra caixa de diálogo «Extrair Texto». Selecione uma célula para inserir o resultado e clique no botão «OK».

Assim, o texto entre os caracteres especificados — incluindo os próprios caracteres — é extraído em massa de cada célula no intervalo selecionado.

3,2 Extrair Texto entre duas palavras

Além de extrair texto entre dois caracteres, poderá também precisar de extrair texto entre duas palavras. Por exemplo, extrair todas as cadeias de texto situadas entre as palavras «KTE» e «feature» em cada célula da coluna B, conforme ilustrado na imagem abaixo. Pode experimentar um dos seguintes métodos para realizar esta tarefa.

3,2.1 Extrair Texto entre duas palavras com fórmula

Pode utilizar uma fórmula com as funções MID e SEARCH para extrair todas as cadeias de texto situadas entre duas palavras numa mesma célula.

Fórmula genérica

=MID(cell,SEARCH(«start_word»,cell)+3,SEARCH(«end_word»,cell)-SEARCH(«start_word»,cell)-4)

Argumentos

Selecione uma célula vazia, copie ou introduza a fórmula abaixo e prima Enter para obter o resultado. Em seguida, selecione essa célula com o resultado e arraste a respetiva Alça de Preenchimento Automático para baixo, de modo a aplicar a fórmula às demais células.

=MID(B5,SEARCH("KTE",B5)+3,SEARCH("feature",B5)-SEARCH("KTE",B5)-4)

Nota: Na fórmula, o número 3 representa o comprimento em caracteres da palavra «KTE»; o número 4 corresponde ao comprimento de «KTE» mais 1.

Pode confirmar que todas as cadeias de texto entre as duas palavras especificadas foram extraídas de cada célula da coluna B.

3,2.2 Extrair Texto entre duas palavras com uma ferramenta incrível

Para muitos utilizadores do Excel, as fórmulas podem ser difíceis de memorizar e utilizar. Com a funcionalidade «Extrair a sequência entre caracteres especificados» do Kutools para Excel, pode extrair facilmente texto entre duas palavras com apenas alguns cliques.

1. Selecione uma célula para inserir o resultado e clique em «Kutools» > «Assistente de Fórmulas» > «Assistente de Fórmulas».

2. Na caixa de diálogo «Assistente de Fórmulas», proceda da seguinte forma:

3. Assim, todas as cadeias de texto entre as palavras «KTE» e «feature» na célula B5 são extraídas. Uma fórmula foi criada — selecione a célula com o resultado e arraste a respetiva Alça de Preenchimento Automático para baixo, de modo a extrair o texto das restantes células da mesma lista.

Extrair números por posição

Numa lista de cadeias alfanuméricas, podem ocorrer três situações:

1. O número está no início do texto;
2. O número está no fim do texto;
3. O número pode aparecer em qualquer posição no texto.

Nesta secção, apresentamos diferentes métodos para extrair números em cada um dos casos mencionados acima.

1 Extrair número do início de uma cadeia

Esta secção apresenta uma fórmula que o ajuda a extrair apenas os números que aparecem antes do texto numa célula.

Fórmula genérica

=LEFT(cell, MATCH(FALSE, ISNUMBER(MID(cell, ROW(INDIRECT("1:"&LEN(cell)+1)), 1) *1), 0) -1)

Argumentos

Nota:

Selecione uma célula vazia, insira a fórmula abaixo e prima «Ctrl» + «Shift» + «Enter» ou simplesmente «Enter» para obter o resultado. Em seguida, selecione essa célula com o resultado e arraste a sua Alça de Preenchimento Automático para baixo, de modo a preencher as restantes células com os números correspondentes.

=LEFT(B5, MATCH(FALSE, ISNUMBER(MID(B5, ROW(INDIRECT("1:"&LEN(B5)+1)), 1) *1), 0) -1)

Notas:

2 Extrair número do fim de uma cadeia

Conforme ilustrado na imagem abaixo, para extrair apenas os números que aparecem após o texto numa célula, experimente a seguinte fórmula.

Fórmula genérica

=RIGHT(cell, LEN(cell) - MAX(IF(ISNUMBER(MID(cell, ROW(INDIRECT("1:"&LEN(cell))), 1) *1)=FALSE, ROW(INDIRECT("1:"&LEN(cell))), 0)))

Argumentos

Nota:

Selecione uma célula vazia, insira a fórmula abaixo e prima «Ctrl» + «Shift» + «Enter» ou simplesmente «Enter» para obter o resultado. Em seguida, selecione essa célula com o resultado e arraste a respetiva Alça de Preenchimento Automático para baixo, de modo a preencher as restantes células com os números correspondentes.

=RIGHT(B5, LEN(B5) - MAX(IF(ISNUMBER(MID(B5, ROW(INDIRECT("1:"&LEN(B5))), 1) *1)=FALSE, ROW(INDIRECT("1:"&LEN(B5))), 0)))

Notas:

3. Extrair todos os números, independentemente da sua posição numa cadeia de texto

Os métodos acima permitem extrair números apenas do início ou do fim de uma cadeia de texto. Caso pretenda extrair todos os números, independentemente da sua posição na cadeia, apresentamos aqui três métodos para o conseguir.

3,1 Extrair todos os números de qualquer posição numa cadeia com fórmula

Pode utilizar a seguinte fórmula para extrair todos os números, independentemente da sua posição numa cadeia de texto no Excel.

1. Selecione uma célula vazia, copie ou introduza a fórmula abaixo e prima «Enter» para obter todos os números da célula B5.

=SUMPRODUCT(MID(0&B5, LARGE(INDEX(ISNUMBER(--MID(B5, ROW(INDIRECT("1:"&LEN(B5))), 1)) * ROW(INDIRECT("1:"&LEN(B5))), 0), ROW(INDIRECT("1:"&LEN(B5))))+1, 1) * 10^ROW(INDIRECT("1:"&LEN(B5)))/10)

2. Selecione a célula com o resultado e, em seguida, arraste a sua Alça de Preenchimento Automático para baixo para obter os números nas restantes células.

3,2 Extrair todos os números de qualquer posição numa cadeia com VBA

A fórmula acima é demasiado longa e complexa para muitos utilizadores do Excel. Na verdade, pode automatizar esta tarefa facilmente com um script VBA no Excel. Siga os passos abaixo.

1. Prima as teclas «Alt» + «F11» para abrir a janela do Microsoft Visual Basic for Applications.

2. Na janela «Microsoft Visual Basic for Applications» que se abre, clique em «Inserir» > «Módulo» e, de seguida, copie o código VBA abaixo para a janela do código do módulo.

Código VBA: Extrair todos os números de qualquer posição numa cadeia de texto

Sub ExtrNumbersFromRange()
'Updated by Extendoffice 20220106
    Dim xRg As Range
    Dim xDRg As Range
    Dim xRRg As Range
    Dim nCellLength As Integer
    Dim xNumber As Integer
    Dim strNumber As String
    Dim xTitleId As String
    Dim xI As Integer
    xTitleId = "KutoolsforExcel"
    Set xDRg = Application.InputBox("Please select text strings:", xTitleId, "", Type:=8)
    If TypeName(xDRg) = "Nothing" Then Exit Sub
    Set xRRg = Application.InputBox("Please select output cell:", xTitleId, "", Type:=8)
    If TypeName(xRRg) = "Nothing" Then Exit Sub
    xI = 0
    strNumber = ""
  For Each xRg In xDRg
    xI = xI + 1
    nCellLength = Len(xRg)
    For xNumber = 1 To nCellLength
      If IsNumeric(Mid(xRg, xNumber, 1)) Then
        strNumber = strNumber & Mid(xRg, xNumber, 1)
      End If
    Next xNumber
    xRRg.Item(xI) = strNumber
    strNumber = ""
  Next xRg
End Sub

3. Prima a tecla «F5» para executar o código. Na caixa de diálogo «Kutools for Excel» que surge, selecione o intervalo de células do qual pretende extrair todos os números de cada célula e clique em «OK».

4. Surge, então, outra caixa de diálogo do «Kutools for Excel». Nesta caixa, selecione a célula de destino e clique em «OK».

Assim, todos os números são extraídos em massa de cada célula no intervalo selecionado.

4. Extrair números que aparecem após um texto específico

Conforme ilustrado na imagem abaixo, esta secção apresenta dois métodos para o ajudar a extrair quaisquer números que apareçam após o texto específico «No.».

4,1 Extrair números após um texto específico com fórmula

Pode utilizar a seguinte fórmula para extrair os números que aparecem após um texto específico numa célula do Excel.

Fórmula genérica:

=LOOKUP(10^6,1*MID(cell,MIN(FIND({0,1,2,3,4,5,6,7,8,9},cell&"0123456789",FIND(«text»,« »&cell&« »))),{2,3,4,5,6}))

Argumentos

Selecione uma célula vazia, copie ou introduza a fórmula abaixo e prima Enter para obter o resultado. Em seguida, selecione essa célula com o resultado e arraste a respetiva Alça de Preenchimento Automático para baixo, de modo a aplicar a fórmula às restantes células.

=LOOKUP(10^6,1*MID(B5,MIN(FIND({0,1,2,3,4,5,6,7,8,9},B5&"0123456789",FIND("No."," "&B5&" "))),{2,3,4,5,6}))

Notas:

4,2 Extrair números após um texto específico com função definida pelo utilizador

A seguinte função definida pelo utilizador também pode ajudar a extrair números após um texto específico numa célula. Siga estes passos:

1. Prima as teclas «Alt» + «F11» para abrir a janela do Microsoft Visual Basic for Applications.

2. Na janela «Microsoft Visual Basic for Applications», clique em «Inserir» > «Módulo» e, de seguida, copie o código VBA abaixo para a janela do código do módulo.

Código VBA: extrair números após um texto específico numa célula

Function GetNumberAfterTheChar(Rng As Range, Char As String)
'Updated by Extendoffice 20220106
Dim xValue As String
Dim xRntString As String
Dim xStart As Integer
Dim xC
    xValue = Rng.Text
    xStart = InStr(1, xValue, Char, vbTextCompare)
    If IsEmpty(xStart) Then
            GetNumberAfterTheChar = ""
            Exit Function
    End If
    If xStart < 1 Then
        GetNumberAfterTheChar = ""
        Exit Function
    End If
    xStart = xStart - 1 + Len(Char)
    If xStart < 1 Then
        GetNumberAfterTheChar = ""
        Exit Function
    End If
    xValue = Mid(xValue, xStart + 1)
    xRntString = ""
    For xI = 1 To Len(xValue)
        xC = Mid(xValue, xI, 1)
        Select Case Asc(xC)
        Case 48 To 57
            xRntString = xRntString & xC
       Case Else
            Exit For
        End Select
    Next
   GetNumberAfterTheChar = xRntString
End Function

3. Prima as teclas «Alt» + «Q» para fechar a janela do Microsoft Visual Basic for Applications.

4. Selecione uma célula, insira a fórmula abaixo e prima «Enter». Em seguida, selecione essa célula com o resultado e arraste a respetiva Alça de Preenchimento Automático para baixo, de modo a aplicar a fórmula às restantes células.

=GetNumberAfterTheChar(B5,"No. ")

Notas:

Artigos relacionados:

As Melhores Ferramentas de Produtividade para o Office

🤖	KUTOOLS AI Assistente: Revolucione o Análise de Dados com base em:Execução Inteligente   |  Gerar Código|  Criar fórmulas personalizadas  |  Analisar Dados e Gerar Gráficos|  Invocar Funções Aprimoradas…
	Funcionalidades Populares:Localizar, Destacar ou Marcar Duplicatas   |  Excluir linhas em branco   |  Combinar Colunas ou Células sem Perder Dados   |   Arredondamento sem usar fórmula...
	Super PROC:VLookup com Múltiplos Critérios  |  VLookup com Múltiplos Valores  |   VLookup em Múltiplas Folhas   |   Correspondência Fuzzy....
	Lista Suspensa Avançada:Criar Rapidamente Lista de Seleção   |  Lista de Seleção Dependente   |  Lista de Seleção com Múltipla Escolha....
	Gestor de Colunas:Adicionar um Número Específico de Colunas|Mover Colunas|Alternar Estado de Visibilidade de Colunas Ocultas|Comparar Intervalos e Colunas...
	Funcionalidades em Destaque:Grade de foco   |  Visualização de Design   |Barra de fórmulas aprimorada   | Gestor de Pastas de Trabalho e Folhas   |  Biblioteca de Recursos(Texto Automático)|  Seleção de Data   |  Consolidar Planilhas  |  Encriptar/Descriptografar Células   | Enviar Emails por Lista   |  Super Filtro   |   Filtro Especial(Filtrar Células com Fonte em Negrito/itálico/rasurado...) ...
	Principais Conjuntos de Ferramentas 15:12 Ferramentasde Texto(Adicionar Texto,Excluir Caracteres Específicos, ...)|   50+Tiposde Gráfico(Gráfico de Gantt, ...)|   40+ Fórmulas Práticas(Calcular a idade com base na data de nascimento, ...)|   19 Ferramentasde Inserção(Inserir QR Code,Inserir Imagem a Partir do Caminho, ...)|   12 Ferramentasde Conversão(Converter em Palavras,Conversão de moeda, ...)|   7 Ferramentasde Mesclar e Dividir(Mesclar Linhas Avançado,Dividir Células, ...)|... e muito mais

Utilize o Kutools na sua língua preferida – suporta inglês, espanhol, alemão, francês, chinês e mais 40+ idiomas!

Potencie as suas competências no Excel com Kutools para Excel e experimente uma eficiência como nunca antes.Kutools para Excel Oferece mais de 300 funcionalidades avançadas para impulsionar a produtividade e Economizar Tempo.Clique aqui para obter a funcionalidade de que mais precisa...

Mais detalhes sobre Kutools para Excel...Transferência gratuita...

---

Office Tab Traz uma interface com separadores para o Office e torna o seu trabalho muito mais fácil

• Ative a edição e leitura com separadores no Word, Excel, PowerPoint, Publisher, Access, Visio e Project.
• Abra e crie vários documentos em novos separadores da mesma janela, em vez de em janelas separadas.
• Aumente a sua produtividade em 50 % e elimine centenas de cliques do rato todos os dias!

Mais detalhes sobre Office Tab...Transferência gratuita...

---

Todos os suplementos Kutools — num único instalador.

Kutools for Office reúne suplementos para Excel, Word, Outlook e PowerPoint, além do Office Tab Pro, sendo a solução ideal para equipas que trabalham em várias aplicações do Office.

• Pacote tudo-em-um— suplementos para Excel, Word, Outlook e PowerPoint + Office Tab Pro
• Um instalador, uma licença— configuração em minutos (pronto para MSI)
• Funciona melhor em conjunto— produtividade simplificada em todas as aplicações do Office
• Teste gratuito de 30 dias com todas as funcionalidades— sem registo, sem cartão de crédito
• Melhor relação qualidade-preço— poupe face à compra individual dos suplementos

Mais detalhes sobre Kutools for Office...Transferência gratuita...