Como executar várias macros a partir do menu de clique direito no Excel?

Se houver várias macros VBA em sua pasta de trabalho, você deve abrir a janela VBA e escolher a macro quando precisar executar o código. Neste artigo, gostaria de falar sobre como executar macros a partir do menu de clique direito para tornar seu trabalho mais eficiente, conforme mostrado na captura de tela à esquerda.

Executar várias macros a partir do menu de clique direito com códigos VBA

Executar várias macros a partir do menu de clique direito com códigos VBA

Para executar os códigos de macro dentro de uma pasta de trabalho a partir do menu de clique direito, as seguintes etapas podem ajudá-lo; por favor, faça o seguinte:

1. Pressione e segure as teclas Alt + F11 para abrir a janela Microsoft Visual Basic for Applications.

2. Em seguida, clique duas vezes em ThisWorkbook no painel Projeto à esquerda e copie e cole o seguinte código VBA no módulo em branco.

Private Sub Workbook_Open()
Run "LoadMacro"
End Sub
Private Sub Workbook_Activate()
Run "LoadMacro"
End Sub
Private Sub Workbook_Deactivate()
Run "ClearMacro"
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Run "ClearMacro"
ThisWorkbook.Save
End Sub

3. Ainda na janela Microsoft Visual Basic for Applications, clique em Inserir > Módulo e cole o seguinte código neste módulo.

Private Sub LoadMacro()
Dim xArrMenu As Variant
Dim xStrLine, xSreBtnName As String
Dim xObjCBCF, xObjCntrAll As CommandBarControl
Dim xObjCBCs As CommandBars
Dim xObjCBBtn As CommandBarButton
Dim xIntLine, xFNum As Integer
Dim xObjComponent As Object
Run "ClearMacro"
Set xObjCBCF = Application.CommandBars("Cell").Controls.Add(msoControlPopup, before:=1)
xObjCBCF.Caption = " Run Macro "
xObjCBCF.BeginGroup = False
For Each xObjComponent In ActiveWorkbook.VBProject.VBComponents
    If xObjComponent.Type = 1 Then
        For xIntLine = 1 To xObjComponent.CodeModule.CountOfLines
        xStrLine = xObjComponent.CodeModule.Lines(xIntLine, 1)
        xStrLine = Trim(xStrLine)
            If (InStr(xStrLine, "()") > 0) And (Left(xStrLine, 11) = "Private Sub" Or Left(xStrLine, 3) = "Sub") Then
            xSreBtnName = ""
            If "Private Sub" = Left(xStrLine, 11) Then
                xSreBtnName = Trim(Mid(xStrLine, 12, InStr(xStrLine, "()") - 12))
            ElseIf "Sub" = Left(xStrLine, 3) Then
               xSreBtnName = Trim(Mid(xStrLine, 4, InStr(xStrLine, "()") - 4))
            End If
            If xSreBtnName <> "" And xSreBtnName <> "RightClickReset" And xSreBtnName <> "LoadMacro" And xSreBtnName <> "ActionMacro" Then
                Set xObjCBBtn = xObjCBCF.Controls.Add
                With xObjCBBtn
                    .FaceId = 186
                    .Style = msoButtonIconAndCaption
                    .Caption = xSreBtnName
                    .OnAction = "ActionMacro"
                End With
            End If
            End If
        Next xIntLine
    End If
Next xObjComponent
End Sub
Private Sub ClearMacro()
On Error Resume Next
CommandBars("Cell").Controls(" Run Macro ").Delete
Err.Clear
CommandBars("Cell").Reset
End Sub
Private Sub ActionMacro()
On Error GoTo Err1
With Application
Run .CommandBars("Cell").Controls(1).Controls(.Caller(1)).Caption
End With
Exit Sub
Err1:
    MsgBox "Invalid"
End Sub

4. Após colar os códigos, clique em Ferramentas > Referências, e uma caixa de diálogo Referências-VBAProject será exibida. Em seguida, marque a opção Microsoft Visual Basic for Applications Extensibility 5.3 na caixa de listagem Referências Disponíveis, veja a captura de tela:

5. Clique em OK para sair da caixa de diálogo. Agora, você deve salvar esta pasta de trabalho no formato Pasta de Trabalho Habilitada para Macro do Excel, veja a captura de tela:

6. Por fim, reinicie a pasta de trabalho para que os códigos tenham efeito. Agora, ao clicar com o botão direito em uma célula, uma opção Executar Macro será inserida no menu de clique direito, e todas as macros em sua pasta de trabalho serão listadas no submenu, conforme a captura de tela a seguir:

7. Então, você pode executar o código apenas clicando nele.