Como excluir linhas com base na cor de fundo no Excel?

Como você pode excluir linhas inteiras com base na cor de fundo? Neste exemplo, preciso excluir todas as linhas em que as células estão preenchidas com a cor de fundo azul, conforme mostrado na captura de tela a seguir. Com este artigo, você obterá alguns códigos para realizar essa tarefa no Excel.

Excluir linhas com uma cor de fundo específica com base em cada célula

Excluir linhas com uma cor de fundo específica com base em uma coluna

Excluir linhas com uma cor de fundo específica com base em cada célula

Se você tem um intervalo de dados preenchido aleatoriamente com algumas cores de célula, e precisa excluir as linhas em que a cor da célula é azul, conforme mostrado na captura de tela a seguir:

Para excluir esse tipo de linha, você pode usar o seguinte código VBA, por favor, siga os passos abaixo:

1. Pressione e segure as teclas ALT + F11 para abrir a janela do Microsoft Visual Basic for Applications.

2. Clique em Inserir > Módulo e cole o seguinte código na Janela do Módulo.

Código VBA: Excluir linhas em que as células contêm uma cor de preenchimento específica:

Sub DeleteRows()
'Updateby Extendoffice
    Dim rngCl As Range
    Dim xRows As Long
    Dim xCol As Long
    Dim colorLg As Long
    On Error Resume Next
    Set rngCl = Application.InputBox _
        (Prompt:="Select a cell with the background color to be deleted", _
        Title:="Kutools for Excel", Type:=8)
    On Error GoTo 0
    If rngCl Is Nothing Then
        MsgBox "User cancelled operation." & vbCrLf & _
        "Processing terminated", vbInformation, "Kutools for Excel"
        Exit Sub
    End If
    colorLg = rngCl.Interior.Color
    Application.ScreenUpdating = False
    With ActiveSheet.UsedRange
        For xRows = .Rows.Count To 1 Step -1
            For xCol = 1 To .Columns.Count
                           If .Cells(xRows, xCol).Interior.Color = colorLg Then
                    .Rows(xRows).Delete
                    Exit For
                End If
            Next xCol
        Next xRows
    End With
    Application.ScreenUpdating = True
End Sub

3. Em seguida, pressione a tecla F5 para executar este código, e uma caixa de aviso aparecerá para lembrá-lo de selecionar uma célula com a cor de preenchimento que deseja excluir, veja a captura de tela:

4. Depois clique em OK, e todas as linhas serão excluídas se a célula tiver uma cor de preenchimento específica.

Excluir linhas com uma cor de fundo específica com base em uma coluna

Se você quiser excluir as linhas com uma cor específica com base apenas em uma coluna, por exemplo, excluir as linhas com cor azul na coluna A e obter a captura de tela abaixo, aqui também há um código VBA que pode ajudá-lo.

1. Pressione e segure as teclas ALT + F11 para abrir a janela do Microsoft Visual Basic for Applications.

2. Clique em Inserir > Módulo e cole o seguinte código na Janela do Módulo.

Código VBA: Excluir linhas com base em uma coluna em que as células têm uma cor de preenchimento específica:

Sub deleterow()
'UpdateBY Extendoffice
   Dim xRg As Range, rgDel As Range
    For Each xRg In ThisWorkbook.ActiveSheet.Range("A2:A21")
        If xRg.Interior.ColorIndex = 20 Then
            If rgDel Is Nothing Then
                Set rgDel = xRg
            Else
                Set rgDel = Union(rgDel, xRg)
            End If
        End If
    Next xRg
    If Not rgDel Is Nothing Then rgDel.EntireRow.Delete
End Sub

Observação: No código acima, A2:A21 é a coluna que contém a cor de preenchimento específica com base na qual você deseja excluir as linhas, o número 20 no script ColorIndex = 20 é o índice de cor com base no qual você deseja excluir as linhas. Você pode alterá-los conforme necessário.

3. Em seguida, pressione a tecla F5 para executar este código, e todas as linhas em que as células contêm a cor azul na coluna A serão excluídas imediatamente.