Ir para o conteúdo principal

Como usar a função IF com AND, OR e NOT no Excel?

A função IF do Excel é uma prova do poder e da versatilidade das operações lógicas no tratamento de dados. A essência da função IF é a sua capacidade de avaliar condições e retornar resultados específicos com base nessas avaliações. Opera em uma lógica fundamental:

=IF(condition, value_if_true, value_if_false)

Quando combinada com operadores lógicos como AND, OR e NOT, os recursos da função IF se expandem significativamente. O poder da combinação reside na capacidade de processar múltiplas condições simultaneamente, fornecendo resultados que podem se adaptar a cenários variados e complexos. Neste tutorial, exploraremos como aproveitar de forma eficaz essas funções poderosas do Excel para desbloquear novas dimensões de análise de dados e aprimorar seu processo de tomada de decisão. Vamos mergulhar e descobrir as aplicações práticas dessas formidáveis ​​funções do Excel!

Fórmula SE E OU NÃO aninhada


Fórmula SE E

Para avaliar múltiplas condições e entregar um resultado específico quando todas as condições forem atendidas (VERDADEIRO), e um resultado diferente quando qualquer condição não for atendida (FALSO), você pode incorporar a função AND no teste lógico da instrução IF. A estrutura para isso é:

=IF(AND(condition1, condition2, …), value_if_all_true, value_if_any_false)

Por exemplo, imagine que você é um professor analisando as notas dos alunos. Você deseja determinar se um aluno é aprovado com base em dois critérios: uma pontuação acima de 70 E frequência acima de 80%.

  1. Comece examinando os dados do primeiro aluno, com nota na célula B2 e frequência na célula C2. Para este aluno, aplique a fórmula abaixo em D2:
    =IF(AND(B2>70, C2>80%), "Pass", "Fail")
    Dica: Esta fórmula verifica se a pontuação em B2 está acima de 70 e a assiduidade em C2 está acima de 80%. Se ambas as condições forem atendidas, retorna "Pass"; caso contrário, retornará "Fail".
  2. Arraste a fórmula para baixo na coluna para avaliar a pontuação e a frequência de cada aluno.

    Fórmula SE E


Fórmula SE OU

Para avaliar diversas condições e retornar um resultado específico quando qualquer uma das condições for atendida (VERDADEIRO), e um resultado diferente quando nenhuma das condições for satisfeita (FALSE), a função OR pode ser usada no teste lógico da instrução IF. A fórmula está estruturada da seguinte forma:

=IF(OR(condition1, condition2, …), value_if_any_true, value_if_all_false)

Por exemplo, num contexto educacional, considere um critério mais flexível para aprovação dos alunos. Aqui, um aluno é considerado aprovado se qualquer pontuação acima de 90 OR ter uma taxa de frequência superior a 95%.

  1. Comece avaliando o desempenho do primeiro aluno, com nota na célula B2 e frequência na célula C2. Aplique a fórmula em uma célula adjacente, como D2, para avaliar:
    =IF(OR(B2>90, C2>95%), "Pass", "Fail")
    Dica: Esta fórmula avalia se o aluno pontua acima de 90 em B2 ou tem uma taxa de frequência superior a 95% em C2. Se alguma das condições for atendida, ele retornará "Pass"; se não, "Falha".
  2. Copie esta fórmula na coluna para aplicá-la a cada aluno da sua lista, permitindo uma avaliação rápida da elegibilidade de cada aluno para aprovação com base nesses critérios.

    Fórmula SE OU


SE NÃO Fórmula

Para avaliar uma condição e retornar um resultado específico se a condição NÃO for atendida (FALSO)e um resultado diferente se a condição for atendida (TRUE), a função NOT na instrução IF é a sua solução. A estrutura desta fórmula é:

=IF(NOT(condition), value_if_false, value_if_true)

Para obter um exemplo prático, considere um cenário de local de trabalho onde os bônus dos funcionários são determinados com base no seu registro de frequência. Os funcionários têm direito a um bônus se NÃO esteve ausente por mais de 3 dias.

  1. Para avaliar isso para o primeiro funcionário, cujos dias de ausência estão na célula B2, use a fórmula:
    =IF(NOT(B2>3), "Eligible", "Not Eligible")
    Dica: Esta fórmula verifica o número de dias de ausência em B2. Se NÃO for maior que 3, retornará "Elegível"; caso contrário, "Não elegível".
  2. Copie esta fórmula na coluna para aplicá-la a cada funcionário.

    SE NÃO fórmula


Cenários avançados com IF e funções lógicas

Nesta seção, exploraremos o uso intrincado da função SE do Excel com operadores lógicos como AND, OR e NOT. Esta seção cobre tudo, desde avaliações que diferenciam maiúsculas de minúsculas até instruções IF aninhadas, mostrando a versatilidade do Excel na análise de dados complexos.


Se sua condição for atendida, calcule

Além de fornecer resultados predefinidos, a função SE do Excel, quando combinada com operadores lógicos como AND, OR e NOT, pode executar vários cálculos com base no fato de as condições definidas serem verdadeiras ou falsas. Aqui, usaremos a combinação IF AND como exemplo para mostrar essa funcionalidade.

Imagine que você gerencia uma equipe de vendas e deseja calcular bônus. Você decide que um funcionário recebe um bônus de 10% em suas vendas se eles ultrapassar US$ 100 em vendas E trabalharam mais de 30 horas por semana.

  1. Para a avaliação inicial, observe os dados de Alice com suas vendas na célula B2 e horas trabalhadas na célula C2. Aplique esta fórmula em D2:
    =IF(AND(B2>100, C2>30), B2*0.1, 0)
    Dica: Esta fórmula calcula um bônus de 10% nas vendas de Alice se suas vendas excederem US$ 100 e suas horas trabalhadas forem superiores a 30. Se ambas as condições forem atendidas, ela calcula o bônus; caso contrário, ele retornará 0.
  2. Estenda esta fórmula para o resto da sua equipe, copiando-a na coluna. Esta abordagem garante que o bônus de cada funcionário seja calculado com base nos mesmos critérios.

    SE Então calcule

Nota: Nesta seção, nos concentraremos no uso da função IF com AND para cálculos baseados em condições específicas. Este conceito também pode ser estendido para incluir OR e NOT, bem como funções lógicas aninhadas, permitindo uma variedade de cálculos condicionais no Excel.


Declarações AND, OR e NOT que diferenciam maiúsculas de minúsculas

No Excel, embora funções lógicas como AND, OR e NOT normalmente não diferenciam maiúsculas de minúsculas, há cenários em que a diferenciação de maiúsculas e minúsculas em dados de texto é crucial. Ao integrar o Função EXATA com esses operadores lógicos, você pode lidar efetivamente com essas condições que diferenciam maiúsculas de minúsculas. Nesta seção, demonstramos o uso das funções IF e OR com uma abordagem que diferencia maiúsculas de minúsculas como exemplo.

Imagine um cenário de varejo onde um produto é elegível para promoção se ultrapassa US$ 100 em vendas OR seu código corresponde exatamente a "ABC" em uma verificação que diferencia maiúsculas de minúsculas.

  1. Para o primeiro produto listado na linha 2, com suas vendas na célula B2 e código do produto na célula C2, use esta fórmula em D2:
    =IF(OR(B2>100, EXACT(C2,"ABC")), "Promotion Eligible", "Not Eligible")
    Dica: Esta fórmula avalia se o valor das vendas em B2 excede $ 100 ou se o código do produto em C2 é exatamente “ABC”. O cumprimento de qualquer uma dessas condições torna o produto elegível para promoção; falhar em ambos o torna inelegível.
  2. Replique esta fórmula em toda a coluna para todos os produtos para avaliar uniformemente sua elegibilidade para promoção com base em vendas e critérios de código de produto que diferenciam maiúsculas de minúsculas.

    Fórmula SE OU com distinção entre maiúsculas e minúsculas

Nota: Nesta seção, ilustramos o uso das funções IF e OR com a função EXACT para avaliações que diferenciam maiúsculas de minúsculas. Da mesma forma, você pode aplicar a função EXATO em suas fórmulas IF combinadas com AND, OR, NOT ou funções lógicas aninhadas para atender a diversos requisitos de distinção entre maiúsculas e minúsculas no Excel.


Integrando IF com instruções AND, OR, NOT aninhadas

A função SE do Excel, quando aninhada com AND, OR e NOT, oferece uma abordagem simplificada para lidar com condições mais em camadas. Esta seção fornece um exemplo que mostra a aplicação dessas funções aninhadas em um ambiente de varejo.

Suponha que você esteja supervisionando uma equipe responsável por várias categorias de produtos e queira determinar sua elegibilidade para bônus. Um funcionário tem direito a um bônus se: alcançar vendas acima de US$ 100, E também trabalhar mais de 30 horas por semana OR NÃO estão no departamento de Eletrônica.

  1. Primeiro, avalie o desempenho de Anne, com suas vendas na célula B2, horas trabalhadas na célula C2 e departamento na célula D2. A fórmula em E2 seria:
    =IF(AND(B2>100, OR(C2>30, NOT(D2="Electronics"))), "Eligible", "Not Eligible")
    Dica: Esta fórmula verifica se Anne tem vendas superiores a US$ 100 e trabalha mais de 30 horas ou não trabalha com eletrônicos. Se ela atender a esses critérios, ela será considerada “Elegível”; caso contrário, "Não elegível".
  2. Copie esta fórmula na coluna de cada funcionário para avaliar uniformemente a elegibilidade ao bônus, considerando suas vendas, horas trabalhadas e departamento.

    Fórmula SE E OU NÃO aninhada


Funções IF aninhadas com AND, OR, NOT

Quando a análise de dados envolve múltiplas verificações condicionais, as funções IF aninhadas no Excel oferecem uma solução poderosa. Este método envolve a construção de instruções IF separadas para condições distintas, incluindo lógica AND, OR e NOT, e então integrá-las em uma fórmula simplificada.

Considere um local de trabalho onde o desempenho dos funcionários é classificado como "Excelente", "Bom" ou "Regular" baseado em vendas, horas trabalhadas e adesão à política:

  • “Excelente” para vendas acima de US$ 150 E mais de 35 horas trabalhadas.
  • Caso contrário, "Bom" para vendas acima de US$ 100 OU violação da política NÃO superior a 1.
  • “Justo” se nenhuma dessas condições for atendida.

Para avaliar o desempenho de cada funcionário de acordo com as condições acima, faça o seguinte:

  1. Comece com a avaliação de Anne, cujas vendas estão na célula B2, as horas trabalhadas na célula C2 e as violações de política na célula D2. A fórmula IF aninhada em E2 é:
    =IF(AND(B2>150, C2>35), "Excellent", IF(OR(B2>100, NOT(D2>1)), "Good", "Fair"))
    Dica: Esta fórmula verifica primeiro se as vendas e o horário de funcionamento de Anne atendem aos critérios de "Excelente". Caso contrário, avalia se ela se qualifica para “Bom”. Se nenhuma das condições for atendida, ela será categorizada como “Regular”.
  2. Estenda esta fórmula IF aninhada a cada funcionário para avaliar consistentemente seu desempenho em vários critérios.

    Funções IF aninhadas


Usando IF com AND OR NOT: Perguntas frequentes

Esta seção tem como objetivo responder às perguntas mais frequentes sobre o uso de IF com AND, OR e NOT no Microsoft Excel.

Quantas condições as funções AND, OR e NOT podem suportar?
  • As funções AND e OR podem suportar até 255 condições individuais. No entanto, é aconselhável usar apenas alguns para evitar fórmulas excessivamente complexas e difíceis de manter.
  • A função NOT requer apenas uma condição.
Posso usar operadores como , = nessas funções?

Certamente, nas funções AND, OR e NOT do Excel, você pode utilizar operadores como menor que (), igual (=), maior ou igual a (>=) e mais para estabelecer condições.

Por que ocorre um erro #VALUE nessas funções?

Um erro #VALUE nas funções AND, OR e NOT do Excel geralmente surge se a fórmula não atender a nenhuma condição especificada ou se houver um problema com a forma como a fórmula está estruturada. Indica que o Excel não consegue interpretar corretamente a entrada ou as condições da fórmula.


Acima está todo o conteúdo relevante relacionado ao uso de SE com funções AND, OR e NOT no Excel. Espero que você ache o tutorial útil. Se você deseja explorar mais dicas e truques do Excel, clique aqui para acessar nossa extensa coleção de mais de milhares de tutoriais.

Comments (72)
No ratings yet. Be the first to rate!
This comment was minimized by the moderator on the site
Hey Friends,

Donno if this Forum works now:

I am trying to figure out a formula for the following:
I have 3 Columns : viz : A1,D1, L1 with text contents. And output expected in M1

So if any of the cells A,D,L has Faulty mentioned, then M1 should result "Faulty", Else if all 3 are blank , need "Spare", and if any cell has any data then it shoud show "Mapped"
This comment was minimized by the moderator on the site
Kan iemand mij helpen met onderstaande voor het maken van een formule?
als B2 de tekst factuur staat moet in cel D8 de tekst factuurdatum komen te staan. Als in cel B2 de tekst offerte staat moet in cel D8 offertedatum komen te staan.

Alvast hartelijk dank
This comment was minimized by the moderator on the site
Hi there,

Can you show us the look of the text invoice, text quotation and text quotation date?
This comment was minimized by the moderator on the site
I am trying to write a formula to populate scores based off a range of values. This is what I have so far:

=IF(C2>=104.5%,"5", IF(C2<=104.49%,"4", IF(C2>=95.5%,"4", IF(C2<=95.49%,"3", IF(C2>=79.5%,"3", IF(C2<=79.49%,"2", IF(C2>=59.5%,"2", IF(C2<=59.49%,"1"""))))))))

The formula is working and I am not receiving any error messages. However, it is not populating the lower range values correctly. Here is my range:

>105% = 5
96%-105% = 4
80%-95% = 3
60%-79% = 2
<60% = 1

Any help is greatly appreciated.
This comment was minimized by the moderator on the site
Hi there,

I've fixed the formula as shown below:
=IF(C2>105%,"5",IF(C2>=96%,"4",IF(C2>=80%,"3",IF(C2>=60%,"2","1"))))

Hope this is what you want.

Amanda
This comment was minimized by the moderator on the site
Never mind, I figured it out. Thanks!
This comment was minimized by the moderator on the site
Kan iemand mij helpen aan onderstaande formule?
Alvast bedankt!

als Q groter is dan C dan Q en als Q kleiner is dan H dan H tenzij H 0 is dan is Q
This comment was minimized by the moderator on the site
Hi there,

Suppose, Q=A1, C=A2, H=A3. Please use the formula below: =IF(B1>B2,B1,IF(B1<B3,IF(B3=0,B1,B3),B3))

Hope this is what you want.

Amanda
This comment was minimized by the moderator on the site
I am trying to find a formula when realignment is in column A then add the text conflict when transition begins date (B) is >= the solution start date in column D OR if activation in column A then add the text conflict when transition begins date is <= solution start date in column D OR if deactivation then add the text conflict when transition begins date is >= the solution start date
A B C D E
Transition Type Transition Begins Transition Ends Solution Start Date Solution End Date
Realignment 11/1/2022 11/15/2022 1/15/2022 3/6/2022
Realignment 11/1/2022 11/15/2022 1/15/2022 3/16/2022
Realignment 11/1/2022 11/15/2022 6/1/2022 7/16/2022
Realignment 11/1/2022 11/15/2022 6/1/2022 7/16/2022
Realignment 11/1/2022 11/15/2022 6/1/2022 7/16/2022
Activation 1/1/2022 1/31/2022 1/15/2022 3/6/2022
Deactivation 12/1/2021 12/15/2021 1/15/2022 3/6/2022
Reorganization 2/6/2022 2/12/2022 1/15/2022 3/6/2022
Activation 12/1/2021 12/31/2021 11/1/2029 12/31/2029
Activation 12/1/2021 12/31/2021 2/1/2025 7/31/2025
Activation 12/1/2021 12/31/2021 4/1/2024 6/29/2024
Activation 12/1/2021 12/31/2021 2/1/2028 3/2/2028
Activation 12/1/2021 12/31/2021 2/1/2022 5/20/2025
Activation 12/1/2021 12/31/2021 9/6/2022 3/16/2023
Activation 12/1/2021 12/31/2021 6/1/2024 11/28/2024
Activation 12/1/2021 12/31/2021 9/1/2022 9/7/2022
Deactivation 10/1/2021 10/30/2021 11/1/2029 12/31/2029
Deactivation 10/1/2021 10/30/2021 2/1/2025 7/31/2025
Deactivation 10/1/2021 10/30/2021 4/1/2024 6/29/2024
Deactivation 10/1/2021 10/30/2021 2/1/2028 3/2/2028
Deactivation 10/1/2021 10/30/2021 2/1/2022 5/20/2025
Deactivation 10/1/2021 10/30/2021 9/6/2022 3/16/2023
Deactivation 10/1/2021 10/30/2021 6/1/2024 11/28/2024
Deactivation 10/1/2021 10/30/2021 9/1/2022 9/7/2022
Reorganization 2/1/2022 2/28/2022 11/1/2029 12/31/2029
Reorganization 2/1/2022 2/28/2022 2/1/2025 7/31/2025
This comment was minimized by the moderator on the site
Hi there,

What do you mean by adding the text conflict? Can you show me the result you want?

Amanda
This comment was minimized by the moderator on the site
=IF(AND(AY7>60,AY7>30),"0.02","0.04"),if(and(ay7<=30,ay<az),"0.06"),if(and(ay7<=15,ay<az),"0.08")
This comment was minimized by the moderator on the site
I am trying use If formula for one oridinary file, lets say I have number from 1 to 31 in a perticular cell. I need to show the result in another cell as if number in that perticular cell is less than 26 they it will zero, if the number in that perticular cell is from 26 to 30 then it will show the same number but if the number is abobe 30 then it will show the 30 only....Can anyone advise me how can I formulate this formula?
This comment was minimized by the moderator on the site
Hi there,

Please try the formula below: =IF(A1<26,0,IF(A1<=30,A1,30))

Hope this could help you.

Amanda
This comment was minimized by the moderator on the site
Ciao,
mi potete aiutare perfavore...
ho tre celle:
1-data di pagamento
2-totale
3-totale se pagato

vorrei che quando inserisco la data di pagamento(1), la casella 3(che è vuota) si riempisse automaticamente come la casella 2
come posso fare?
This comment was minimized by the moderator on the site
Hi there,

Do you want to fill the value of the cell 2 in the cell 3?
If so, you can enter this IF formula in the casella 3: =IF(casella 1<>"",casella 2,"")

Amanda
This comment was minimized by the moderator on the site
=IF(D4<=30000, and =>20000,than D4a-5000,and if(d4<=40000, and >30000, than d4-6000) convert into formula
This comment was minimized by the moderator on the site
Try the formula. Since I don't quite understand you, please check and change the part "DA4-5000" and "D4-6000", "FALSE" to the results you want.
=IF(AND(D4<=30000,D4>20000),"DA4-5000",IF(AND(D4<=40000,D4>30000),"D4-6000","FALSE"))
Amanda
This comment was minimized by the moderator on the site
HI EVERY ONE I NEED HELP IN THIS SYNTEX=IF(AND(AJ=1250,AJ*2.5%),IF(AND(AJ>1250,AJ<=2500),AJ*10%,IF(AND(AJ>2500,AJ<=3750),AJ*15%,IF(AND(AJ>3750,AJ<=11666),AJ*20%))))
THIS FOURMAIL GIVE ME #NAME WHERE THE EROO
This comment was minimized by the moderator on the site
Hi ahmed.dba,
Can you send the file to ? And if you have private information in the file, please delete them.
Amanda
There are no comments posted here yet
Load More
Please leave your comments in English
Posting as Guest
×
Rate this post:
0   Characters
Suggested Locations